basis/ui/gadgets/gadgets.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays hashtables kernel models math namespaces
   4 make sequences quotations math.vectors combinators sorting
   5 binary-search vectors dlists deques models threads
   6 concurrency.flags math.order math.rectangles fry ;
   7 IN: ui.gadgets
   8
   9 ! Values for orientation slot
  10 CONSTANT: horizontal { 1 0 }
  11 CONSTANT: vertical { 0 1 }
  12
  13 TUPLE: gadget < rect
  14 pref-dim
  15 parent
  16 children
  17 { orientation initial: { 0 1 } }
  18 focus
  19 { visible? initial: t }
  20 root?
  21 clipped?
  22 layout-state
  23 { graft-state initial: { f f } }
  24 graft-node
  25 interior
  26 boundary
  27 model ;
  28
  29 M: gadget equal? 2drop f ;
  30
  31 M: gadget hashcode* drop gadget hashcode* ;
  32
  33 M: gadget model-changed 2drop ;
  34
  35 : gadget-child ( gadget -- child ) children>> first ;
  36
  37 : nth-gadget ( n gadget -- child ) children>> nth ;
  38
  39 : <gadget> ( -- gadget )
  40     gadget new ;
  41
  42 : control-value ( control -- value )
  43     model>> value>> ;
  44
  45 : set-control-value ( value control -- )
  46     model>> set-model ;
  47
  48 : relative-loc ( fromgadget togadget -- loc )
  49     2dup eq? [
  50         2drop { 0 0 }
  51     ] [
  52         [ [ parent>> ] dip relative-loc ] [ drop loc>> ] 2bi v+
  53     ] if ;
  54
  55 GENERIC: user-input* ( str gadget -- ? )
  56
  57 M: gadget user-input* 2drop t ;
  58
  59 GENERIC: children-on ( rect gadget -- seq )
  60
  61 M: gadget children-on nip children>> ;
  62
  63 <PRIVATE
  64
  65 : ((fast-children-on)) ( gadget dim axis -- <=> )
  66     [ swap loc>> v- ] dip v. 0 <=> ;
  67
  68 : (fast-children-on) ( dim axis children -- i )
  69     -rot '[ _ _ ((fast-children-on)) ] search drop ;
  70
  71 PRIVATE>
  72
  73 : fast-children-on ( rect axis children -- from to )
  74     [ [ loc>> ] 2dip (fast-children-on) 0 or ]
  75     [ [ rect-bounds v+ ] 2dip (fast-children-on) ?1+ ]
  76     3bi ;
  77
  78 M: gadget contains-rect? ( bounds gadget -- ? )
  79     dup visible?>> [ call-next-method ] [ 2drop f ] if ;
  80
  81 M: gadget contains-point? ( loc gadget -- ? )
  82     dup visible?>> [ call-next-method ] [ 2drop f ] if ;
  83
  84 : pick-up ( point gadget -- child/f )
  85     2dup [ dup point>rect ] dip children-on
  86     [ contains-point? ] with find-last nip
  87     [ [ loc>> v- ] keep pick-up ] [ nip ] ?if ;
  88
  89 : max-dim ( dims -- dim ) { 0 0 } [ vmax ] reduce ;
  90
  91 : dim-sum ( seq -- dim ) { 0 0 } [ v+ ] reduce ;
  92
  93 : each-child ( gadget quot -- )
  94     [ children>> ] dip each ; inline
  95
  96 ! Selection protocol
  97 GENERIC: gadget-selection? ( gadget -- ? )
  98
  99 M: gadget gadget-selection? drop f ;
 100
 101 GENERIC: gadget-selection ( gadget -- string/f )
 102
 103 M: gadget gadget-selection drop f ;
 104
 105 ! Text protocol
 106 GENERIC: gadget-text* ( gadget -- )
 107
 108 GENERIC: gadget-text-separator ( gadget -- str )
 109
 110 M: gadget gadget-text-separator
 111     orientation>> vertical = "\n" "" ? ;
 112
 113 : gadget-seq-text ( seq gadget -- )
 114     gadget-text-separator swap
 115     [ dup % ] [ gadget-text* ] interleave drop ;
 116
 117 M: gadget gadget-text*
 118     [ children>> ] keep gadget-seq-text ;
 119
 120 M: array gadget-text*
 121     [ gadget-text* ] each ;
 122
 123 : gadget-text ( gadget -- string ) [ gadget-text* ] "" make ;
 124
 125 DEFER: relayout
 126
 127 <PRIVATE
 128
 129 SYMBOL: ui-notify-flag
 130
 131 : notify-ui-thread ( -- ) ui-notify-flag get-global raise-flag ;
 132
 133 : invalidate ( gadget -- )
 134     \ invalidate >>layout-state drop ;
 135
 136 : forget-pref-dim ( gadget -- ) f >>pref-dim drop ;
 137
 138 : layout-queue ( -- queue ) \ layout-queue get ;
 139
 140 : layout-later ( gadget -- )
 141     #! When unit testing gadgets without the UI running, the
 142     #! invalid queue is not initialized and we simply ignore
 143     #! invalidation requests.
 144     layout-queue [ push-front notify-ui-thread ] [ drop ] if* ;
 145
 146 : invalidate* ( gadget -- )
 147     \ invalidate* >>layout-state
 148     dup forget-pref-dim
 149     dup root?>>
 150     [ layout-later ] [ parent>> [ relayout ] when* ] if ;
 151
 152 PRIVATE>
 153
 154 : relayout ( gadget -- )
 155     dup layout-state>> \ invalidate* eq?
 156     [ drop ] [ invalidate* ] if ;
 157
 158 : relayout-1 ( gadget -- )
 159     dup layout-state>>
 160     [ drop ] [ dup invalidate layout-later ] if ;
 161
 162 : show-gadget ( gadget -- ) t >>visible? drop ;
 163
 164 : hide-gadget ( gadget -- ) f >>visible? drop ;
 165
 166 <PRIVATE
 167
 168 SYMBOL: in-layout?
 169
 170 GENERIC: dim-changed ( gadget -- )
 171
 172 M: gadget dim-changed
 173     in-layout? get [ invalidate ] [ invalidate* ] if ;
 174
 175 PRIVATE>
 176
 177 M: gadget (>>dim) ( dim gadget -- )
 178     2dup dim>> =
 179     [ 2drop ]
 180     [ [ nip ] [ call-next-method ] 2bi dim-changed ] if ;
 181
 182 GENERIC: pref-dim* ( gadget -- dim )
 183
 184 : pref-dim ( gadget -- dim )
 185     dup pref-dim>> [ ] [
 186         [ pref-dim* ] keep dup layout-state>>
 187         [ drop ] [ dupd (>>pref-dim) ] if
 188     ] ?if ;
 189
 190 : pref-dims ( gadgets -- seq ) [ pref-dim ] map ;
 191
 192 M: gadget pref-dim* dim>> ;
 193
 194 GENERIC: layout* ( gadget -- )
 195
 196 M: gadget layout* drop ;
 197
 198 : prefer ( gadget -- ) dup pref-dim >>dim drop ;
 199
 200 : layout ( gadget -- )
 201     dup layout-state>> [
 202         f >>layout-state
 203         dup layout*
 204         dup [ layout ] each-child
 205     ] when drop ;
 206
 207 GENERIC: graft* ( gadget -- )
 208
 209 M: gadget graft* drop ;
 210
 211 GENERIC: ungraft* ( gadget -- )
 212
 213 M: gadget ungraft* drop ;
 214
 215 <PRIVATE
 216
 217 : graft-queue ( -- dlist ) \ graft-queue get ;
 218
 219 : unqueue-graft ( gadget -- )
 220     [ graft-node>> graft-queue delete-node ]
 221     [ [ first { t t } { f f } ? ] change-graft-state drop ] bi ;
 222
 223 : (queue-graft) ( gadget flags -- )
 224     >>graft-state
 225     dup graft-queue push-front* >>graft-node drop
 226     notify-ui-thread ;
 227
 228 : queue-graft ( gadget -- )
 229     { f t } (queue-graft) ;
 230
 231 : queue-ungraft ( gadget -- )
 232     { t f } (queue-graft) ;
 233
 234 : graft-later ( gadget -- )
 235     dup graft-state>> {
 236         { { f t } [ drop ] }
 237         { { t t } [ drop ] }
 238         { { t f } [ unqueue-graft ] }
 239         { { f f } [ queue-graft ] }
 240     } case ;
 241
 242 : graft ( gadget -- )
 243     dup graft-later [ graft ] each-child ;
 244
 245 : ungraft-later ( gadget -- )
 246     dup graft-state>> {
 247         { { f f } [ drop ] }
 248         { { t f } [ drop ] }
 249         { { f t } [ unqueue-graft ] }
 250         { { t t } [ queue-ungraft ] }
 251     } case ;
 252
 253 : ungraft ( gadget -- )
 254     dup [ ungraft ] each-child ungraft-later ;
 255
 256 : activate-control ( gadget -- )
 257     dup model>> dup [
 258         2dup add-connection
 259         swap model-changed
 260     ] [
 261         2drop
 262     ] if ;
 263
 264 : deactivate-control ( gadget -- )
 265     dup model>> dup [ 2dup remove-connection ] when 2drop ;
 266
 267 : notify ( gadget -- )
 268     dup graft-state>>
 269     [ first { f f } { t t } ? >>graft-state ] keep
 270     {
 271         { { f t } [ dup activate-control graft* ] }
 272         { { t f } [ dup deactivate-control ungraft* ] }
 273     } case ;
 274
 275 : notify-queued ( -- )
 276     graft-queue [ notify ] slurp-deque ;
 277
 278 : (unparent) ( gadget -- )
 279     dup ungraft
 280     dup forget-pref-dim
 281     f >>parent drop ;
 282
 283 : (clear-gadget) ( gadget -- )
 284     dup [ (unparent) ] each-child
 285     f >>focus f >>children drop ;
 286
 287 : unfocus-gadget ( child gadget -- )
 288     [ nip ] [ focus>> eq? ] 2bi [ f >>focus ] when drop ;
 289
 290 PRIVATE>
 291
 292 : not-in-layout ( -- )
 293     in-layout? get
 294     [ "Cannot add/remove gadgets in layout*" throw ] when ;
 295
 296 GENERIC: remove-gadget ( gadget parent -- )
 297
 298 M: gadget remove-gadget 2drop ;
 299
 300 : unparent ( gadget -- )
 301     not-in-layout
 302     [
 303         dup parent>> dup
 304         [
 305             [ remove-gadget ] [
 306                 over (unparent)
 307                 [ unfocus-gadget ]
 308                 [ children>> delete ]
 309                 [ nip relayout ]
 310                 2tri
 311             ] 2bi
 312         ] [ 2drop ] if
 313     ] when* ;
 314
 315 : clear-gadget ( gadget -- )
 316     not-in-layout
 317     [ (clear-gadget) ] [ relayout ] bi ;
 318
 319 <PRIVATE
 320
 321 : (add-gadget) ( child parent -- )
 322     {
 323         [ drop unparent ]
 324         [ >>parent drop ]
 325         [ [ ?push ] change-children drop ]
 326         [ graft-state>> second [ graft ] [ drop ] if ]
 327     } 2cleave ;
 328
 329 PRIVATE>
 330
 331 : add-gadget ( parent child -- parent )
 332     not-in-layout
 333     over (add-gadget)
 334     dup relayout ;
 335
 336 : add-gadgets ( parent children -- parent )
 337     not-in-layout
 338     [ over (add-gadget) ] each
 339     dup relayout ;
 340
 341 : parents ( gadget -- seq )
 342     [ parent>> ] follow ;
 343
 344 : each-parent ( gadget quot -- ? )
 345     [ parents ] dip all? ; inline
 346
 347 : find-parent ( gadget quot -- parent )
 348     [ parents ] dip find nip ; inline
 349
 350 : screen-loc ( gadget -- loc )
 351     parents { 0 0 } [ loc>> v+ ] reduce ;
 352
 353 <PRIVATE
 354
 355 : (screen-rect) ( gadget -- loc ext )
 356     dup parent>> [
 357         [ rect-extent ] dip (screen-rect)
 358         [ [ nip ] [ v+ ] 2bi ] dip [ v+ ] [ vmin ] 2bi*
 359     ] [
 360         rect-extent
 361     ] if* ;
 362
 363 PRIVATE>
 364
 365 : screen-rect ( gadget -- rect )
 366     (screen-rect) <extent-rect> ;
 367
 368 : child? ( parent child -- ? )
 369     {
 370         { [ 2dup eq? ] [ 2drop t ] }
 371         { [ dup not ] [ 2drop f ] }
 372         [ parent>> child? ]
 373     } cond ;
 374
 375 GENERIC: focusable-child* ( gadget -- child/t )
 376
 377 M: gadget focusable-child* drop t ;
 378
 379 : focusable-child ( gadget -- child )
 380     dup focusable-child*
 381     dup t eq? [ drop ] [ nip focusable-child ] if ;
 382
 383 GENERIC: request-focus-on ( child gadget -- )
 384
 385 M: gadget request-focus-on parent>> request-focus-on ;
 386
 387 M: f request-focus-on 2drop ;
 388
 389 : request-focus ( gadget -- )
 390     [ focusable-child ] keep request-focus-on ;
 391
 392 : focus-path ( gadget -- seq )
 393     [ focus>> ] follow ;