basis/ui/gadgets/gadgets.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays hashtables kernel math namespaces
   4 make sequences quotations math.vectors combinators sorting
   5 binary-search vectors dlists deques models threads
   6 concurrency.flags math.order math.rectangles fry locals ;
   7 IN: ui.gadgets
   8
   9 ! Values for orientation slot
  10 CONSTANT: horizontal { 1 0 }
  11 CONSTANT: vertical { 0 1 }
  12
  13 TUPLE: gadget < rect
  14 id
  15 pref-dim
  16 parent
  17 children
  18 { orientation initial: { 0 1 } }
  19 focus
  20 { visible? initial: t }
  21 root?
  22 clipped?
  23 layout-state
  24 { graft-state initial: { f f } }
  25 graft-node
  26 interior
  27 boundary
  28 model ;
  29
  30 M: gadget equal? 2drop f ;
  31
  32 M: gadget hashcode* nip [ [ \ gadget counter ] unless* ] change-id id>> ;
  33
  34 M: gadget model-changed 2drop ;
  35
  36 : gadget-child ( gadget -- child ) children>> first ;
  37
  38 : nth-gadget ( n gadget -- child ) children>> nth ;
  39
  40 : <gadget> ( -- gadget )
  41     gadget new ;
  42
  43 : control-value ( control -- value )
  44     model>> value>> ;
  45
  46 : set-control-value ( value control -- )
  47     model>> set-model ;
  48
  49 : relative-loc ( fromgadget togadget -- loc )
  50     2dup eq? [
  51         2drop { 0 0 }
  52     ] [
  53         [ [ parent>> ] dip relative-loc ] [ drop loc>> ] 2bi v+
  54     ] if ;
  55
  56 GENERIC: user-input* ( str gadget -- ? )
  57
  58 M: gadget user-input* 2drop t ;
  59
  60 GENERIC: children-on ( rect gadget -- seq )
  61
  62 M: gadget children-on nip children>> ;
  63
  64 <PRIVATE
  65
  66 : ((fast-children-on)) ( gadget dim axis -- <=> )
  67     [ swap loc>> v- ] dip v. 0 <=> ;
  68
  69 :: (fast-children-on) ( dim axis children -- i )
  70     children [ dim axis ((fast-children-on)) ] search drop ;
  71
  72 PRIVATE>
  73
  74 : fast-children-on ( rect axis children -- from to )
  75     [ [ loc>> ] 2dip (fast-children-on) 0 or ]
  76     [ [ rect-bounds v+ ] 2dip (fast-children-on) ?1+ ]
  77     3bi ;
  78
  79 M: gadget contains-rect? ( bounds gadget -- ? )
  80     dup visible?>> [ call-next-method ] [ 2drop f ] if ;
  81
  82 M: gadget contains-point? ( loc gadget -- ? )
  83     dup visible?>> [ call-next-method ] [ 2drop f ] if ;
  84
  85 : pick-up ( point gadget -- child/f )
  86     2dup [ dup point>rect ] dip children-on
  87     [ contains-point? ] with find-last nip
  88     [ [ loc>> v- ] keep pick-up ] [ nip ] ?if ;
  89
  90 : max-dim ( dims -- dim ) { 0 0 } [ vmax ] reduce ;
  91
  92 : dim-sum ( seq -- dim ) { 0 0 } [ v+ ] reduce ;
  93
  94 : each-child ( gadget quot -- )
  95     [ children>> ] dip each ; inline
  96
  97 ! Selection protocol
  98 GENERIC: gadget-selection? ( gadget -- ? )
  99
 100 M: gadget gadget-selection? drop f ;
 101
 102 GENERIC: gadget-selection ( gadget -- string/f )
 103
 104 M: gadget gadget-selection drop f ;
 105
 106 ! Text protocol
 107 GENERIC: gadget-text* ( gadget -- )
 108
 109 GENERIC: gadget-text-separator ( gadget -- str )
 110
 111 M: gadget gadget-text-separator
 112     orientation>> vertical = "\n" "" ? ;
 113
 114 : gadget-seq-text ( seq gadget -- )
 115     gadget-text-separator swap
 116     [ dup % ] [ gadget-text* ] interleave drop ;
 117
 118 M: gadget gadget-text*
 119     [ children>> ] keep gadget-seq-text ;
 120
 121 M: array gadget-text*
 122     [ gadget-text* ] each ;
 123
 124 : gadget-text ( gadget -- string ) [ gadget-text* ] "" make ;
 125
 126 DEFER: relayout
 127
 128 <PRIVATE
 129
 130 SYMBOL: ui-notify-flag
 131
 132 : notify-ui-thread ( -- ) ui-notify-flag get-global raise-flag ;
 133
 134 : invalidate ( gadget -- )
 135     \ invalidate >>layout-state drop ;
 136
 137 : forget-pref-dim ( gadget -- ) f >>pref-dim drop ;
 138
 139 : layout-queue ( -- queue ) \ layout-queue get ;
 140
 141 : layout-later ( gadget -- )
 142     #! When unit testing gadgets without the UI running, the
 143     #! invalid queue is not initialized and we simply ignore
 144     #! invalidation requests.
 145     layout-queue [ push-front notify-ui-thread ] [ drop ] if* ;
 146
 147 : invalidate* ( gadget -- )
 148     \ invalidate* >>layout-state
 149     dup forget-pref-dim
 150     dup root?>>
 151     [ layout-later ] [ parent>> [ relayout ] when* ] if ;
 152
 153 PRIVATE>
 154
 155 : relayout ( gadget -- )
 156     dup layout-state>> \ invalidate* eq?
 157     [ drop ] [ invalidate* ] if ;
 158
 159 : relayout-1 ( gadget -- )
 160     dup layout-state>>
 161     [ drop ] [ dup invalidate layout-later ] if ;
 162
 163 : show-gadget ( gadget -- ) t >>visible? drop ;
 164
 165 : hide-gadget ( gadget -- ) f >>visible? drop ;
 166
 167 <PRIVATE
 168
 169 SYMBOL: in-layout?
 170
 171 GENERIC: dim-changed ( gadget -- )
 172
 173 M: gadget dim-changed
 174     in-layout? get [ invalidate ] [ invalidate* ] if ;
 175
 176 PRIVATE>
 177
 178 M: gadget (>>dim) ( dim gadget -- )
 179     2dup dim>> =
 180     [ 2drop ]
 181     [ [ nip ] [ call-next-method ] 2bi dim-changed ] if ;
 182
 183 GENERIC: pref-dim* ( gadget -- dim )
 184
 185 : pref-dim ( gadget -- dim )
 186     dup pref-dim>> [ ] [
 187         [ pref-dim* ] keep dup layout-state>>
 188         [ drop ] [ dupd (>>pref-dim) ] if
 189     ] ?if ;
 190
 191 : pref-dims ( gadgets -- seq ) [ pref-dim ] map ;
 192
 193 M: gadget pref-dim* dim>> ;
 194
 195 GENERIC: layout* ( gadget -- )
 196
 197 M: gadget layout* drop ;
 198
 199 : prefer ( gadget -- ) dup pref-dim >>dim drop ;
 200
 201 : layout ( gadget -- )
 202     dup layout-state>> [
 203         f >>layout-state
 204         dup layout*
 205         dup [ layout ] each-child
 206     ] when drop ;
 207
 208 GENERIC: graft* ( gadget -- )
 209
 210 M: gadget graft* drop ;
 211
 212 GENERIC: ungraft* ( gadget -- )
 213
 214 M: gadget ungraft* drop ;
 215
 216 <PRIVATE
 217
 218 : graft-queue ( -- dlist )
 219     \ graft-queue get [ "UI not running" throw ] unless* ;
 220
 221 : unqueue-graft ( gadget -- )
 222     [ graft-node>> graft-queue delete-node ]
 223     [ [ first { t t } { f f } ? ] change-graft-state drop ] bi ;
 224
 225 : (queue-graft) ( gadget flags -- )
 226     >>graft-state
 227     dup graft-queue push-front* >>graft-node drop
 228     notify-ui-thread ;
 229
 230 : queue-graft ( gadget -- )
 231     { f t } (queue-graft) ;
 232
 233 : queue-ungraft ( gadget -- )
 234     { t f } (queue-graft) ;
 235
 236 : graft-later ( gadget -- )
 237     dup graft-state>> {
 238         { { f t } [ drop ] }
 239         { { t t } [ drop ] }
 240         { { t f } [ unqueue-graft ] }
 241         { { f f } [ queue-graft ] }
 242     } case ;
 243
 244 : graft ( gadget -- )
 245     dup graft-later [ graft ] each-child ;
 246
 247 : ungraft-later ( gadget -- )
 248     dup graft-state>> {
 249         { { f f } [ drop ] }
 250         { { t f } [ drop ] }
 251         { { f t } [ unqueue-graft ] }
 252         { { t t } [ queue-ungraft ] }
 253     } case ;
 254
 255 : ungraft ( gadget -- )
 256     dup [ ungraft ] each-child ungraft-later ;
 257
 258 : activate-control ( gadget -- )
 259     dup model>> dup [
 260         2dup add-connection
 261         swap model-changed
 262     ] [
 263         2drop
 264     ] if ;
 265
 266 : deactivate-control ( gadget -- )
 267     dup model>> dup [ 2dup remove-connection ] when 2drop ;
 268
 269 : notify ( gadget -- )
 270     dup graft-state>>
 271     [ first { f f } { t t } ? >>graft-state ] keep
 272     {
 273         { { f t } [ dup activate-control graft* ] }
 274         { { t f } [ dup deactivate-control ungraft* ] }
 275     } case ;
 276
 277 : notify-queued ( -- )
 278     graft-queue [ notify ] slurp-deque ;
 279
 280 : (unparent) ( gadget -- )
 281     dup ungraft
 282     dup forget-pref-dim
 283     f >>parent drop ;
 284
 285 : (clear-gadget) ( gadget -- )
 286     dup [ (unparent) ] each-child
 287     f >>focus f >>children drop ;
 288
 289 : unfocus-gadget ( child gadget -- )
 290     [ nip ] [ focus>> eq? ] 2bi [ f >>focus ] when drop ;
 291
 292 PRIVATE>
 293
 294 : not-in-layout ( -- )
 295     in-layout? get
 296     [ "Cannot add/remove gadgets in layout*" throw ] when ;
 297
 298 GENERIC: remove-gadget ( gadget parent -- )
 299
 300 M: gadget remove-gadget 2drop ;
 301
 302 : unparent ( gadget -- )
 303     not-in-layout
 304     [
 305         dup parent>> dup
 306         [
 307             [ remove-gadget ] [
 308                 over (unparent)
 309                 [ unfocus-gadget ]
 310                 [ children>> delete ]
 311                 [ nip relayout ]
 312                 2tri
 313             ] 2bi
 314         ] [ 2drop ] if
 315     ] when* ;
 316
 317 : clear-gadget ( gadget -- )
 318     not-in-layout
 319     [ (clear-gadget) ] [ relayout ] bi ;
 320
 321 <PRIVATE
 322
 323 : (add-gadget) ( child parent -- )
 324     {
 325         [ drop unparent ]
 326         [ >>parent drop ]
 327         [ [ ?push ] change-children drop ]
 328         [ graft-state>> second [ graft ] [ drop ] if ]
 329     } 2cleave ;
 330
 331 PRIVATE>
 332
 333 : add-gadget ( parent child -- parent )
 334     not-in-layout
 335     over (add-gadget)
 336     dup relayout ;
 337
 338 : add-gadgets ( parent children -- parent )
 339     not-in-layout
 340     [ over (add-gadget) ] each
 341     dup relayout ;
 342
 343 : parents ( gadget -- seq )
 344     [ parent>> ] follow ;
 345
 346 : each-parent ( gadget quot -- ? )
 347     [ parents ] dip all? ; inline
 348
 349 : find-parent ( gadget quot -- parent )
 350     [ parents ] dip find nip ; inline
 351
 352 : screen-loc ( gadget -- loc )
 353     parents { 0 0 } [ loc>> v+ ] reduce ;
 354
 355 <PRIVATE
 356
 357 : (screen-rect) ( gadget -- loc ext )
 358     dup parent>> [
 359         [ rect-extent ] dip (screen-rect)
 360         [ [ nip ] [ v+ ] 2bi ] dip [ v+ ] [ vmin ] 2bi*
 361     ] [
 362         rect-extent
 363     ] if* ;
 364
 365 PRIVATE>
 366
 367 : screen-rect ( gadget -- rect )
 368     (screen-rect) <extent-rect> ;
 369
 370 : child? ( parent child -- ? )
 371     {
 372         { [ 2dup eq? ] [ 2drop t ] }
 373         { [ dup not ] [ 2drop f ] }
 374         [ parent>> child? ]
 375     } cond ;
 376
 377 GENERIC: focusable-child* ( gadget -- child/t )
 378
 379 M: gadget focusable-child* drop t ;
 380
 381 : focusable-child ( gadget -- child )
 382     dup focusable-child*
 383     dup t eq? [ drop ] [ nip focusable-child ] if ;
 384
 385 GENERIC: request-focus-on ( child gadget -- )
 386
 387 M: gadget request-focus-on parent>> request-focus-on ;
 388
 389 M: f request-focus-on 2drop ;
 390
 391 : request-focus ( gadget -- )
 392     [ focusable-child ] keep request-focus-on ;
 393
 394 : focus-path ( gadget -- seq )
 395     [ focus>> ] follow ;
 396
 397 USING: vocabs vocabs.loader ;
 398
 399 "prettyprint" vocab [ "ui.gadgets.prettyprint" require ] when