basis/ui/gadgets/gadgets.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays hashtables kernel models math namespaces
   4 make sequences quotations math.vectors combinators sorting
   5 binary-search vectors dlists deques models threads
   6 concurrency.flags math.order math.rectangles fry ;
   7 IN: ui.gadgets
   8
   9 ! Values for orientation slot
  10 CONSTANT: horizontal { 1 0 }
  11 CONSTANT: vertical { 0 1 }
  12
  13 TUPLE: gadget < rect
  14 pref-dim
  15 parent
  16 children
  17 { orientation initial: { 0 1 } }
  18 focus
  19 { visible? initial: t }
  20 root?
  21 clipped?
  22 layout-state
  23 { graft-state initial: { f f } }
  24 graft-node
  25 interior
  26 boundary
  27 model ;
  28
  29 M: gadget equal? 2drop f ;
  30
  31 M: gadget hashcode* drop gadget hashcode* ;
  32
  33 M: gadget model-changed 2drop ;
  34
  35 : gadget-child ( gadget -- child ) children>> first ;
  36
  37 : nth-gadget ( n gadget -- child ) children>> nth ;
  38
  39 : <gadget> ( -- gadget )
  40     gadget new ;
  41
  42 : control-value ( control -- value )
  43     model>> value>> ;
  44
  45 : set-control-value ( value control -- )
  46     model>> set-model ;
  47
  48 : relative-loc ( fromgadget togadget -- loc )
  49     2dup eq? [
  50         2drop { 0 0 }
  51     ] [
  52         [ [ parent>> ] dip relative-loc ] [ drop loc>> ] 2bi v+
  53     ] if ;
  54
  55 GENERIC: user-input* ( str gadget -- ? )
  56
  57 M: gadget user-input* 2drop t ;
  58
  59 GENERIC: children-on ( rect gadget -- seq )
  60
  61 M: gadget children-on nip children>> ;
  62
  63 <PRIVATE
  64
  65 : ((fast-children-on)) ( gadget dim axis -- <=> )
  66     [ swap loc>> v- ] dip v. 0 <=> ;
  67
  68 : (fast-children-on) ( dim axis children -- i )
  69     -rot '[ _ _ ((fast-children-on)) ] search drop ;
  70
  71 PRIVATE>
  72
  73 : fast-children-on ( rect axis children -- from to )
  74     [ [ loc>> ] 2dip (fast-children-on) 0 or ]
  75     [ [ rect-bounds v+ ] 2dip (fast-children-on) ?1+ ]
  76     3bi ;
  77
  78 M: gadget contains-rect? ( bounds gadget -- ? )
  79     dup visible?>> [ call-next-method ] [ 2drop f ] if ;
  80
  81 M: gadget contains-point? ( loc gadget -- ? )
  82     dup visible?>> [ call-next-method ] [ 2drop f ] if ;
  83
  84 : pick-up ( point gadget -- child/f )
  85     2dup [ dup point>rect ] dip children-on
  86     [ contains-point? ] with find-last nip
  87     [ [ loc>> v- ] keep pick-up ] [ nip ] ?if ;
  88
  89 : max-dim ( dims -- dim ) { 0 0 } [ vmax ] reduce ;
  90
  91 : dim-sum ( seq -- dim ) { 0 0 } [ v+ ] reduce ;
  92
  93 : each-child ( gadget quot -- )
  94     [ children>> ] dip each ; inline
  95
  96 ! Selection protocol
  97 GENERIC: gadget-selection? ( gadget -- ? )
  98
  99 M: gadget gadget-selection? drop f ;
 100
 101 GENERIC: gadget-selection ( gadget -- string/f )
 102
 103 M: gadget gadget-selection drop f ;
 104
 105 ! Text protocol
 106 GENERIC: gadget-text* ( gadget -- )
 107
 108 GENERIC: gadget-text-separator ( gadget -- str )
 109
 110 M: gadget gadget-text-separator
 111     orientation>> vertical = "\n" "" ? ;
 112
 113 : gadget-seq-text ( seq gadget -- )
 114     gadget-text-separator swap
 115     [ dup % ] [ gadget-text* ] interleave drop ;
 116
 117 M: gadget gadget-text*
 118     [ children>> ] keep gadget-seq-text ;
 119
 120 M: array gadget-text*
 121     [ gadget-text* ] each ;
 122
 123 : gadget-text ( gadget -- string ) [ gadget-text* ] "" make ;
 124
 125 DEFER: relayout
 126
 127 <PRIVATE
 128
 129 SYMBOL: ui-notify-flag
 130
 131 : notify-ui-thread ( -- ) ui-notify-flag get-global raise-flag ;
 132
 133 : invalidate ( gadget -- )
 134     \ invalidate >>layout-state drop ;
 135
 136 : forget-pref-dim ( gadget -- ) f >>pref-dim drop ;
 137
 138 : ui-state ( symbol -- value ) get [ "UI not running" throw ] unless* ;
 139
 140 : layout-queue ( -- queue ) \ layout-queue ui-state ;
 141
 142 : layout-later ( gadget -- )
 143     #! When unit testing gadgets without the UI running, the
 144     #! invalid queue is not initialized and we simply ignore
 145     #! invalidation requests.
 146     layout-queue [ push-front notify-ui-thread ] [ drop ] if* ;
 147
 148 : invalidate* ( gadget -- )
 149     \ invalidate* >>layout-state
 150     dup forget-pref-dim
 151     dup root?>>
 152     [ layout-later ] [ parent>> [ relayout ] when* ] if ;
 153
 154 PRIVATE>
 155
 156 : relayout ( gadget -- )
 157     dup layout-state>> \ invalidate* eq?
 158     [ drop ] [ invalidate* ] if ;
 159
 160 : relayout-1 ( gadget -- )
 161     dup layout-state>>
 162     [ drop ] [ dup invalidate layout-later ] if ;
 163
 164 : show-gadget ( gadget -- ) t >>visible? drop ;
 165
 166 : hide-gadget ( gadget -- ) f >>visible? drop ;
 167
 168 <PRIVATE
 169
 170 SYMBOL: in-layout?
 171
 172 GENERIC: dim-changed ( gadget -- )
 173
 174 M: gadget dim-changed
 175     in-layout? get [ invalidate ] [ invalidate* ] if ;
 176
 177 PRIVATE>
 178
 179 M: gadget (>>dim) ( dim gadget -- )
 180     2dup dim>> =
 181     [ 2drop ]
 182     [ [ nip ] [ call-next-method ] 2bi dim-changed ] if ;
 183
 184 GENERIC: pref-dim* ( gadget -- dim )
 185
 186 : pref-dim ( gadget -- dim )
 187     dup pref-dim>> [ ] [
 188         [ pref-dim* ] keep dup layout-state>>
 189         [ drop ] [ dupd (>>pref-dim) ] if
 190     ] ?if ;
 191
 192 : pref-dims ( gadgets -- seq ) [ pref-dim ] map ;
 193
 194 M: gadget pref-dim* dim>> ;
 195
 196 GENERIC: layout* ( gadget -- )
 197
 198 M: gadget layout* drop ;
 199
 200 : prefer ( gadget -- ) dup pref-dim >>dim drop ;
 201
 202 : layout ( gadget -- )
 203     dup layout-state>> [
 204         f >>layout-state
 205         dup layout*
 206         dup [ layout ] each-child
 207     ] when drop ;
 208
 209 GENERIC: graft* ( gadget -- )
 210
 211 M: gadget graft* drop ;
 212
 213 GENERIC: ungraft* ( gadget -- )
 214
 215 M: gadget ungraft* drop ;
 216
 217 <PRIVATE
 218
 219 : graft-queue ( -- dlist ) \ graft-queue ui-state ;
 220
 221 : unqueue-graft ( gadget -- )
 222     [ graft-node>> graft-queue delete-node ]
 223     [ [ first { t t } { f f } ? ] change-graft-state drop ] bi ;
 224
 225 : (queue-graft) ( gadget flags -- )
 226     >>graft-state
 227     dup graft-queue push-front* >>graft-node drop
 228     notify-ui-thread ;
 229
 230 : queue-graft ( gadget -- )
 231     { f t } (queue-graft) ;
 232
 233 : queue-ungraft ( gadget -- )
 234     { t f } (queue-graft) ;
 235
 236 : graft-later ( gadget -- )
 237     dup graft-state>> {
 238         { { f t } [ drop ] }
 239         { { t t } [ drop ] }
 240         { { t f } [ unqueue-graft ] }
 241         { { f f } [ queue-graft ] }
 242     } case ;
 243
 244 : graft ( gadget -- )
 245     dup graft-later [ graft ] each-child ;
 246
 247 : ungraft-later ( gadget -- )
 248     dup graft-state>> {
 249         { { f f } [ drop ] }
 250         { { t f } [ drop ] }
 251         { { f t } [ unqueue-graft ] }
 252         { { t t } [ queue-ungraft ] }
 253     } case ;
 254
 255 : ungraft ( gadget -- )
 256     dup [ ungraft ] each-child ungraft-later ;
 257
 258 : activate-control ( gadget -- )
 259     dup model>> dup [
 260         2dup add-connection
 261         swap model-changed
 262     ] [
 263         2drop
 264     ] if ;
 265
 266 : deactivate-control ( gadget -- )
 267     dup model>> dup [ 2dup remove-connection ] when 2drop ;
 268
 269 : notify ( gadget -- )
 270     dup graft-state>>
 271     [ first { f f } { t t } ? >>graft-state ] keep
 272     {
 273         { { f t } [ dup activate-control graft* ] }
 274         { { t f } [ dup deactivate-control ungraft* ] }
 275     } case ;
 276
 277 : notify-queued ( -- )
 278     graft-queue [ notify ] slurp-deque ;
 279
 280 : (unparent) ( gadget -- )
 281     dup ungraft
 282     dup forget-pref-dim
 283     f >>parent drop ;
 284
 285 : (clear-gadget) ( gadget -- )
 286     dup [ (unparent) ] each-child
 287     f >>focus f >>children drop ;
 288
 289 : unfocus-gadget ( child gadget -- )
 290     [ nip ] [ focus>> eq? ] 2bi [ f >>focus ] when drop ;
 291
 292 PRIVATE>
 293
 294 : not-in-layout ( -- )
 295     in-layout? get
 296     [ "Cannot add/remove gadgets in layout*" throw ] when ;
 297
 298 GENERIC: remove-gadget ( gadget parent -- )
 299
 300 M: gadget remove-gadget 2drop ;
 301
 302 : unparent ( gadget -- )
 303     not-in-layout
 304     [
 305         dup parent>> dup
 306         [
 307             [ remove-gadget ] [
 308                 over (unparent)
 309                 [ unfocus-gadget ]
 310                 [ children>> delete ]
 311                 [ nip relayout ]
 312                 2tri
 313             ] 2bi
 314         ] [ 2drop ] if
 315     ] when* ;
 316
 317 : clear-gadget ( gadget -- )
 318     not-in-layout
 319     [ (clear-gadget) ] [ relayout ] bi ;
 320
 321 <PRIVATE
 322
 323 : (add-gadget) ( child parent -- )
 324     {
 325         [ drop unparent ]
 326         [ >>parent drop ]
 327         [ [ ?push ] change-children drop ]
 328         [ graft-state>> second [ graft ] [ drop ] if ]
 329     } 2cleave ;
 330
 331 PRIVATE>
 332
 333 : add-gadget ( parent child -- parent )
 334     not-in-layout
 335     over (add-gadget)
 336     dup relayout ;
 337
 338 : add-gadgets ( parent children -- parent )
 339     not-in-layout
 340     [ over (add-gadget) ] each
 341     dup relayout ;
 342
 343 : parents ( gadget -- seq )
 344     [ parent>> ] follow ;
 345
 346 : each-parent ( gadget quot -- ? )
 347     [ parents ] dip all? ; inline
 348
 349 : find-parent ( gadget quot -- parent )
 350     [ parents ] dip find nip ; inline
 351
 352 : screen-loc ( gadget -- loc )
 353     parents { 0 0 } [ loc>> v+ ] reduce ;
 354
 355 <PRIVATE
 356
 357 : (screen-rect) ( gadget -- loc ext )
 358     dup parent>> [
 359         [ rect-extent ] dip (screen-rect)
 360         [ [ nip ] [ v+ ] 2bi ] dip [ v+ ] [ vmin ] 2bi*
 361     ] [
 362         rect-extent
 363     ] if* ;
 364
 365 PRIVATE>
 366
 367 : screen-rect ( gadget -- rect )
 368     (screen-rect) <extent-rect> ;
 369
 370 : child? ( parent child -- ? )
 371     {
 372         { [ 2dup eq? ] [ 2drop t ] }
 373         { [ dup not ] [ 2drop f ] }
 374         [ parent>> child? ]
 375     } cond ;
 376
 377 GENERIC: focusable-child* ( gadget -- child/t )
 378
 379 M: gadget focusable-child* drop t ;
 380
 381 : focusable-child ( gadget -- child )
 382     dup focusable-child*
 383     dup t eq? [ drop ] [ nip focusable-child ] if ;
 384
 385 GENERIC: request-focus-on ( child gadget -- )
 386
 387 M: gadget request-focus-on parent>> request-focus-on ;
 388
 389 M: f request-focus-on 2drop ;
 390
 391 : request-focus ( gadget -- )
 392     [ focusable-child ] keep request-focus-on ;
 393
 394 : focus-path ( gadget -- seq )
 395     [ focus>> ] follow ;