basis/ui/gadgets/labels/labels.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays hashtables io kernel math namespaces
   4 make opengl sequences strings splitting ui.gadgets
   5 ui.gadgets.tracks ui.gadgets.theme ui.render
   6 ui.text colors models ;
   7 IN: ui.gadgets.labels
   8
   9 ! A label gadget draws a string.
  10 TUPLE: label < gadget text font color ;
  11
  12 : label-string ( label -- string )
  13     text>> dup string? [ "\n" join ] unless ; inline
  14
  15 : set-label-string ( string label -- )
  16     [ CHAR: \n over memq? [ string-lines ] when ] dip (>>text) ; inline
  17
  18 : label-theme ( gadget -- gadget )
  19     sans-serif-font >>font
  20     black >>color ; inline
  21
  22 : new-label ( string class -- label )
  23     new-gadget
  24     [ set-label-string ] keep
  25     label-theme ; inline
  26
  27 : <label> ( string -- label )
  28     label new-label ;
  29
  30 M: label pref-dim*
  31     [ font>> ] [ text>> ] bi text-dim ;
  32
  33 M: label draw-gadget*
  34     [ color>> gl-color ]
  35     [ [ font>> ] [ text>> ] bi origin get draw-text ] bi ;
  36
  37 M: label gadget-text* label-string % ;
  38
  39 TUPLE: label-control < label ;
  40
  41 M: label-control model-changed
  42     swap value>> over set-label-string relayout ;
  43
  44 : <label-control> ( model -- gadget )
  45     "" label-control new-label
  46         swap >>model ;
  47
  48 : text-theme ( gadget -- gadget )
  49     black >>color
  50     monospace-font >>font ;
  51
  52 : reverse-video-theme ( label -- label )
  53     white >>color
  54     black solid-interior ;
  55
  56 GENERIC: >label ( obj -- gadget )
  57 M: string >label <label> ;
  58 M: array >label <label> ;
  59 M: object >label ;
  60 M: f >label drop <gadget> ;
  61
  62 : label-on-left ( gadget label -- button )
  63     { 1 0 } <track>
  64         swap >label f track-add
  65         swap 1 track-add ;
  66
  67 : label-on-right ( label gadget -- button )
  68     { 1 0 } <track>
  69         swap f track-add
  70         swap >label 1 track-add ;