basis/ui/gadgets/labels/labels.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays hashtables io kernel math math.functions
   4 namespaces make opengl sequences strings splitting ui.gadgets
   5 ui.gadgets.tracks ui.gadgets.packs fonts ui.render ui.pens.solid
   6 ui.baseline-alignment ui.text colors colors.constants models
   7 combinators ;
   8 IN: ui.gadgets.labels
   9
  10 ! A label gadget draws a string.
  11 TUPLE: label < gadget text font ;
  12
  13 SLOT: string
  14
  15 M: label string>> ( label -- string )
  16     text>> dup string? [ "\n" join ] unless ; inline
  17
  18 <PRIVATE
  19
  20 PREDICATE: string-array < array [ string? ] all? ;
  21
  22 PRIVATE>
  23
  24 : ?string-lines ( string -- string/array )
  25     CHAR: \n over memq? [ string-lines ] when ;
  26
  27 ERROR: not-a-string object ;
  28
  29 M: label (>>string) ( string label -- )
  30     [
  31         {
  32             { [ dup string-array? ] [ ] }
  33             { [ dup string? ] [ ?string-lines ] }
  34             [ not-a-string ]
  35         } cond
  36     ] dip (>>text) ; inline
  37
  38 : label-theme ( gadget -- gadget )
  39     sans-serif-font >>font ; inline
  40
  41 : new-label ( string class -- label )
  42     new
  43     swap >>string
  44     label-theme ; inline
  45
  46 : <label> ( string -- label )
  47     label new-label ;
  48
  49 : >label< ( label -- font text )
  50     [ font>> ] [ text>> ] bi ;
  51
  52 M: label pref-dim*
  53     >label< text-dim ;
  54
  55 <PRIVATE
  56
  57 : label-metrics ( label -- metrics )
  58     >label< dup string? [ first ] unless line-metrics ;
  59
  60 PRIVATE>
  61
  62 M: label baseline
  63     label-metrics ascent>> round ;
  64
  65 M: label cap-height
  66     label-metrics cap-height>> round ;
  67
  68 M: label draw-gadget*
  69     >label<
  70     [
  71         background get [ font-with-background ] when*
  72         foreground get [ font-with-foreground ] when*
  73     ] dip
  74     draw-text ;
  75
  76 M: label gadget-text* string>> % ;
  77
  78 TUPLE: label-control < label ;
  79
  80 M: label-control model-changed
  81     swap value>> >>string relayout ;
  82
  83 : <label-control> ( model -- gadget )
  84     "" label-control new-label
  85         swap >>model ;
  86
  87 : text-theme ( gadget -- gadget )
  88     monospace-font >>font ;
  89
  90 : reverse-video-theme ( label -- label )
  91     sans-serif-font reverse-video-font >>font
  92     COLOR: black <solid> >>interior ;
  93
  94 GENERIC: >label ( obj -- gadget )
  95 M: string >label <label> ;
  96 M: array >label <label> ;
  97 M: object >label ;
  98 M: f >label drop <gadget> ;
  99
 100 <PRIVATE
 101
 102 : label-on-left/right ( -- track )
 103     horizontal <track>
 104         0 >>fill
 105         +baseline+ >>align
 106         { 5 5 } >>gap ; inline
 107 PRIVATE>
 108
 109 : label-on-left ( gadget label -- button )
 110     label-on-left/right
 111         swap >label f track-add
 112         swap 1 track-add ;
 113
 114 : label-on-right ( label gadget -- button )
 115     label-on-left/right
 116         swap f track-add
 117         swap >label 1 track-add ;