basis/ui/gadgets/labels/labels.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays hashtables io kernel math math.functions
   4 namespaces make opengl sequences strings splitting ui.gadgets
   5 ui.gadgets.tracks ui.gadgets.packs fonts ui.render ui.pens.solid
   6 ui.text colors colors.constants models combinators ;
   7 IN: ui.gadgets.labels
   8
   9 ! A label gadget draws a string.
  10 TUPLE: label < gadget text font ;
  11
  12 SLOT: string
  13
  14 M: label string>> ( label -- string )
  15     text>> dup string? [ "\n" join ] unless ; inline
  16
  17 <PRIVATE
  18
  19 PREDICATE: string-array < array [ string? ] all? ;
  20
  21 PRIVATE>
  22
  23 : ?string-lines ( string -- string/array )
  24     CHAR: \n over memq? [ string-lines ] when ;
  25
  26 ERROR: not-a-string object ;
  27
  28 M: label (>>string) ( string label -- )
  29     [
  30         {
  31             { [ dup string-array? ] [ ] }
  32             { [ dup string? ] [ ?string-lines ] }
  33             [ not-a-string ]
  34         } cond
  35     ] dip (>>text) ; inline
  36
  37 : label-theme ( gadget -- gadget )
  38     sans-serif-font >>font ; inline
  39
  40 : new-label ( string class -- label )
  41     new-gadget
  42     swap >>string
  43     label-theme ; inline
  44
  45 : <label> ( string -- label )
  46     label new-label ;
  47
  48 : >label< ( label -- font text )
  49     [ font>> ] [ text>> ] bi ;
  50
  51 M: label pref-dim*
  52     >label< text-dim ;
  53
  54 M: label baseline
  55     >label< dup string? [ first ] unless
  56     line-metrics ascent>> round ;
  57
  58 M: label draw-gadget* >label< draw-text ;
  59
  60 M: label gadget-text* string>> % ;
  61
  62 TUPLE: label-control < label ;
  63
  64 M: label-control model-changed
  65     swap value>> >>string relayout ;
  66
  67 : <label-control> ( model -- gadget )
  68     "" label-control new-label
  69         swap >>model ;
  70
  71 : text-theme ( gadget -- gadget )
  72     monospace-font >>font ;
  73
  74 : reverse-video-theme ( label -- label )
  75     sans-serif-font reverse-video-font >>font
  76     COLOR: black <solid> >>interior ;
  77
  78 GENERIC: >label ( obj -- gadget )
  79 M: string >label <label> ;
  80 M: array >label <label> ;
  81 M: object >label ;
  82 M: f >label drop <gadget> ;
  83
  84 <PRIVATE
  85
  86 : label-on-left/right ( -- track )
  87     horizontal <track>
  88         +baseline+ >>align
  89         { 5 5 } >>gap ; inline
  90 PRIVATE>
  91
  92 : label-on-left ( gadget label -- button )
  93     label-on-left/right
  94         swap >label f track-add
  95         swap 1 track-add ;
  96
  97 : label-on-right ( label gadget -- button )
  98     label-on-left/right
  99         swap f track-add
 100         swap >label 1 track-add ;