basis/ui/gadgets/labels/labels.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays hashtables io kernel math math.functions
   4 namespaces make opengl sequences strings splitting ui.gadgets
   5 ui.gadgets.tracks ui.gadgets.packs fonts ui.render ui.pens.solid
   6 ui.baseline-alignment ui.text colors colors.constants models
   7 combinators opengl.gl ;
   8 IN: ui.gadgets.labels
   9
  10 ! A label gadget draws a string.
  11 TUPLE: label < gadget text font ;
  12
  13 SLOT: string
  14
  15 M: label string>> ( label -- string )
  16     text>> dup string? [ "\n" join ] unless ; inline
  17
  18 <PRIVATE
  19
  20 PREDICATE: string-array < array [ string? ] all? ;
  21
  22 PRIVATE>
  23
  24 : ?string-lines ( string -- string/array )
  25     CHAR: \n over member-eq? [ string-lines ] when ;
  26
  27 ERROR: not-a-string object ;
  28
  29 M: label string<< ( string label -- )
  30     [
  31         {
  32             { [ dup string-array? ] [ ] }
  33             { [ dup string? ] [ ?string-lines ] }
  34             [ not-a-string ]
  35         } cond
  36     ] dip text<< ; inline
  37
  38 : label-theme ( gadget -- gadget )
  39     sans-serif-font >>font ; inline
  40
  41 : new-label ( string class -- label )
  42     new
  43     swap >>string
  44     label-theme ; inline
  45
  46 : <label> ( string -- label )
  47     label new-label ;
  48
  49 : >label< ( label -- font text )
  50     [ font>> ] [ text>> ] bi ;
  51
  52 M: label pref-dim*
  53     >label< text-dim ;
  54
  55 M: label baseline
  56     font>> font-metrics ascent>> round ;
  57
  58 M: label cap-height
  59     font>> font-metrics cap-height>> round ;
  60
  61 M: label draw-gadget*
  62     >label<
  63     [
  64         background get [ font-with-background ] when*
  65         foreground get [ font-with-foreground ] when*
  66     ] dip
  67     draw-text ;
  68
  69 M: label gadget-text* string>> % ;
  70
  71 TUPLE: label-control < label ;
  72
  73 M: label-control model-changed
  74     swap value>> >>string relayout ;
  75
  76 : <label-control> ( model -- gadget )
  77     "" label-control new-label
  78         swap >>model ;
  79
  80 : text-theme ( gadget -- gadget )
  81     monospace-font >>font ;
  82
  83 : reverse-video-theme ( label -- label )
  84     sans-serif-font reverse-video-font >>font
  85     COLOR: black <solid> >>interior ;
  86
  87 GENERIC: >label ( obj -- gadget )
  88 M: string >label <label> ;
  89 M: array >label <label> ;
  90 M: object >label ;
  91 M: f >label drop <gadget> ;
  92
  93 <PRIVATE
  94
  95 : label-on-left/right ( -- track )
  96     horizontal <track>
  97         0 >>fill
  98         +baseline+ >>align
  99         { 5 5 } >>gap ; inline
 100 PRIVATE>
 101
 102 : label-on-left ( gadget label -- track )
 103     label-on-left/right
 104         swap >label f track-add
 105         swap 1 track-add ;
 106
 107 : label-on-right ( label gadget -- track )
 108     label-on-left/right
 109         swap f track-add
 110         swap >label 1 track-add ;