basis/ui/gadgets/tracks/tracks.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors combinators fry kernel math math.vectors
   4 sequences ui.gadgets ui.gadgets.packs ui.gadgets.packs.private ;
   5 IN: ui.gadgets.tracks
   6
   7 TUPLE: track < pack sizes ;
   8
   9 : new-track ( orientation class -- track )
  10     new
  11         1 >>fill
  12         V{ } clone >>sizes
  13         swap >>orientation ; inline
  14
  15 : <track> ( orientation -- track ) track new-track ;
  16
  17 <PRIVATE
  18
  19 : normalized-sizes ( track -- seq )
  20     sizes>> dup sift sum '[ dup [ _ / ] when ] map ;
  21
  22 : alloted-dim ( track -- dim )
  23     [ children>> ] [ sizes>> ] bi { 0 0 }
  24     [ [ drop ] [ pref-dim v+ ] if ] 2reduce ;
  25
  26 : available-dim ( track -- dim )
  27     [ dim>> ] [ alloted-dim ] bi v- ;
  28
  29 : track-layout ( track -- sizes )
  30     {
  31         [ children>> pref-dims ]
  32         [ normalized-sizes ]
  33         [ [ available-dim ] [ gap-dim ] bi v- ]
  34         [ orientation>> ]
  35     } cleave
  36     '[ [ _ n*v _ set-axis ] when* ] 2map ;
  37
  38 M: track layout* dup track-layout pack-layout ;
  39
  40 : track-pref-dims-1 ( track -- dim )
  41     [ children>> pref-dims max-dims ]
  42     [ pref-dim>> { 0 0 } or ] bi vmax ;
  43
  44 : track-pref-dims-2 ( track -- dim )
  45     [
  46         [ children>> pref-dims ] [ normalized-sizes ] bi
  47         [ dup { 0 f } member? [ 2drop { 0 0 } ] [ v/n ] if ] 2map
  48         max-dims
  49     ] [ gap-dim ] bi v+ ;
  50
  51 M: track pref-dim*
  52     [ track-pref-dims-1 ]
  53     [ [ alloted-dim ] [ track-pref-dims-2 ] bi v+ ]
  54     [ orientation>> ]
  55     tri
  56     set-axis ;
  57
  58 PRIVATE>
  59
  60 : track-add ( track gadget constraint -- track )
  61     pick sizes>> push add-gadget ;
  62
  63 M: track remove-gadget
  64     [ [ children>> index ] [  sizes>> ] bi remove-nth! drop ]
  65     [ call-next-method ] 2bi ;
  66
  67 : clear-track ( track -- ) [ sizes>> delete-all ] [ clear-gadget ] bi ;