basis/ui/text/core-text/core-text.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs accessors alien core-graphics.types core-text
   4 core-text.fonts kernel hashtables namespaces sequences
   5 ui.gadgets.worlds ui.text ui.text.private opengl opengl.gl
   6 opengl.textures destructors combinators core-foundation
   7 core-foundation.strings math math.vectors init colors colors.constants
   8 cache arrays images ;
   9 IN: ui.text.core-text
  10
  11 SINGLETON: core-text-renderer
  12
  13 M: core-text-renderer string-dim
  14     [ " " string-dim { 0 1 } v* ]
  15     [ cached-line dim>> ]
  16     if-empty ;
  17
  18 M: core-text-renderer flush-layout-cache
  19     cached-lines get purge-cache ;
  20
  21 : rendered-line ( font string -- texture )
  22     world get world-text-handle [
  23         cached-line [ image>> ] [ loc>> ] bi <texture>
  24     ] 2cache ;
  25
  26 M: core-text-renderer draw-string ( font string -- )
  27     rendered-line draw-texture ;
  28
  29 M: core-text-renderer x>offset ( x font string -- n )
  30     [ 2drop 0 ] [
  31         cached-line line>>
  32         swap 0 <CGPoint> CTLineGetStringIndexForPosition
  33     ] if-empty ;
  34
  35 M: core-text-renderer offset>x ( n font string -- x )
  36     cached-line line>> swap f
  37     CTLineGetOffsetForStringIndex ;
  38
  39 M: core-text-renderer font-metrics ( font -- metrics )
  40     cache-font-metrics ;
  41
  42 M: core-text-renderer line-metrics ( font string -- metrics )
  43     [ " " line-metrics clone 0 >>width ]
  44     [ cached-line metrics>> ]
  45     if-empty ;
  46
  47 core-text-renderer font-renderer set-global