basis/ui/text/core-text/core-text.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs accessors alien core-graphics.types core-text
   4 core-text.fonts kernel hashtables namespaces sequences
   5 ui.gadgets.worlds ui.text ui.text.private opengl opengl.gl
   6 opengl.textures destructors combinators core-foundation
   7 core-foundation.strings math math.vectors init colors colors.constants
   8 cache arrays images ;
   9 IN: ui.text.core-text
  10
  11 SINGLETON: core-text-renderer
  12
  13 M: core-text-renderer init-text-rendering
  14     <cache-assoc> >>text-handle drop ;
  15
  16 M: core-text-renderer string-dim
  17     [ " " string-dim { 0 1 } v* ]
  18     [ cached-line dim>> ]
  19     if-empty ;
  20
  21 M: core-text-renderer finish-text-rendering
  22     text-handle>> purge-cache
  23     cached-lines get purge-cache ;
  24
  25 : rendered-line ( font string -- texture )
  26     world get text-handle>>
  27     [ cached-line [ image>> ] [ loc>> ] bi <texture> ]
  28     2cache ;
  29
  30 M: core-text-renderer draw-string ( font string -- )
  31     rendered-line draw-texture ;
  32
  33 M: core-text-renderer x>offset ( x font string -- n )
  34     [ 2drop 0 ] [
  35         cached-line line>>
  36         swap 0 <CGPoint> CTLineGetStringIndexForPosition
  37     ] if-empty ;
  38
  39 M: core-text-renderer offset>x ( n font string -- x )
  40     cached-line line>> swap f
  41     CTLineGetOffsetForStringIndex ;
  42
  43 M: core-text-renderer font-metrics ( font -- metrics )
  44     cache-font-metrics ;
  45
  46 M: core-text-renderer line-metrics ( font string -- metrics )
  47     [ " " line-metrics clone 0 >>width ]
  48     [ cached-line metrics>> ]
  49     if-empty ;
  50
  51 core-text-renderer font-renderer set-global