basis/ui/text/core-text/core-text.factor

   1 ! Copyright (C) 2009, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors cache core-graphics.types core-text
   4 core-text.fonts io.encodings.string io.encodings.utf16 kernel
   5 locals math math.vectors namespaces sequences ui.text
   6 ui.text.private ;
   7 IN: ui.text.core-text
   8
   9 SINGLETON: core-text-renderer
  10
  11 <PRIVATE
  12
  13 : unscale ( m -- n )
  14     retina? get-global [ 2.0 / ] when ; inline
  15
  16 : scale ( m -- n )
  17     retina? get-global [ 2.0 * ] when ; inline
  18
  19 : scale-dim ( dim -- dim' )
  20     retina? get-global [ [ 2.0 / ] map ] when ; inline
  21
  22 : scale-metrics ( metrics -- metrics' )
  23     retina? get-global [
  24         clone
  25             [ 2.0 / ] change-width
  26             [ 2.0 / ] change-ascent
  27             [ 2.0 / ] change-descent
  28             [ 2.0 / ] change-height
  29             [ 2.0 / ] change-leading
  30             [ 2.0 / ] change-cap-height
  31             [ 2.0 / ] change-x-height
  32     ] when ; inline
  33
  34 PRIVATE>
  35
  36 M: core-text-renderer string-dim
  37     [ " " string-dim { 0 1 } v* ]
  38     [ cached-line dim>> scale-dim ]
  39     if-empty ;
  40
  41 M: core-text-renderer flush-layout-cache
  42     cached-lines get-global purge-cache ;
  43
  44 M: core-text-renderer string>image ( font string -- image loc )
  45     cached-line [ line>image ] [ loc>> scale-dim ] bi ;
  46
  47 M:: core-text-renderer x>offset ( x font string -- n )
  48     x font string
  49     [ 2drop 0 ] [
  50         cached-line line>>
  51         swap scale 0 <CGPoint> CTLineGetStringIndexForPosition
  52     ] if-empty
  53     2 * 0 swap string utf16n encode subseq
  54     utf16n decode length ;
  55
  56 M:: core-text-renderer offset>x ( n font string -- x )
  57     font string cached-line line>>
  58     0 n string subseq utf16n encode length 2 / >integer
  59     f
  60     CTLineGetOffsetForStringIndex unscale ;
  61
  62 M: core-text-renderer font-metrics ( font -- metrics )
  63     cache-font-metrics ;
  64
  65 M: core-text-renderer line-metrics ( font string -- metrics )
  66     [ " " line-metrics clone 0 >>width ]
  67     [ cached-line metrics>> scale-metrics ]
  68     if-empty ;
  69
  70 core-text-renderer font-renderer set-global