basis/ui/text/core-text/core-text.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs accessors alien core-graphics.types core-text
   4 core-text.fonts kernel hashtables namespaces sequences
   5 ui.gadgets.worlds ui.text ui.text.private opengl opengl.gl
   6 opengl.textures destructors combinators core-foundation
   7 core-foundation.strings math math.vectors init colors colors.constants
   8 cache arrays ;
   9 IN: ui.text.core-text
  10
  11 SINGLETON: core-text-renderer
  12
  13 M: core-text-renderer init-text-rendering
  14     <cache-assoc> >>text-handle drop ;
  15
  16 M: core-text-renderer string-dim
  17     [ " " string-dim { 0 1 } v* ]
  18     [ cached-line image>> dim>> ]
  19     if-empty ;
  20
  21 M: core-text-renderer finish-text-rendering
  22     text-handle>> purge-cache
  23     cached-lines get purge-cache ;
  24
  25 : rendered-line ( font string -- texture )
  26     world get text-handle>> [ cached-line image>> <texture> ] 2cache ;
  27
  28 M: core-text-renderer draw-string ( font string -- )
  29     rendered-line display-list>> glCallList ;
  30
  31 M: core-text-renderer x>offset ( x font string -- n )
  32     [ 2drop 0 ] [
  33         cached-line line>>
  34         swap 0 <CGPoint> CTLineGetStringIndexForPosition
  35     ] if-empty ;
  36
  37 M: core-text-renderer offset>x ( n font string -- x )
  38     cached-line line>> swap f
  39     CTLineGetOffsetForStringIndex ;
  40
  41 M: core-text-renderer font-metrics ( font -- metrics )
  42     cache-font-metrics ;
  43
  44 M: core-text-renderer line-metrics ( font string -- metrics )
  45     [ " " line-metrics clone 0 >>width ]
  46     [ cached-line metrics>> ]
  47     if-empty ;
  48
  49 core-text-renderer font-renderer set-global