basis/ui/text/text.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel arrays sequences math math.order cache opengl
   4 opengl.gl strings fonts colors accessors namespaces
   5 ui.gadgets.worlds ;
   6 IN: ui.text
   7
   8 <PRIVATE
   9
  10 SYMBOL: font-renderer
  11
  12 : world-text-handle ( world -- handle )
  13     dup text-handle>> [ <cache-assoc> >>text-handle ] unless
  14     text-handle>> ;
  15
  16 HOOK: flush-layout-cache font-renderer ( -- )
  17
  18 [ flush-layout-cache ] flush-layout-cache-hook set-global
  19
  20 HOOK: string-dim font-renderer ( font string -- dim )
  21
  22 HOOK: string-width font-renderer ( font string -- w )
  23
  24 HOOK: string-height font-renderer ( font string -- h )
  25
  26 M: object string-dim [ string-width ] [ string-height ] 2bi 2array ;
  27
  28 M: object string-width string-dim first ;
  29
  30 M: object string-height string-dim second ;
  31
  32 HOOK: draw-string font-renderer ( font string -- )
  33
  34 HOOK: free-fonts font-renderer ( world -- )
  35
  36 : combine-text-dim ( dim1 dim2 -- dim3 )
  37     [ [ first ] bi@ max ]
  38     [ [ second ] bi@ + ]
  39     2bi 2array ;
  40
  41 PRIVATE>
  42
  43 HOOK: x>offset font-renderer ( x font string -- n )
  44
  45 HOOK: offset>x font-renderer ( n font string -- x )
  46
  47 GENERIC: text-dim ( font text -- dim )
  48
  49 M: string text-dim string-dim ;
  50
  51 M: array text-dim
  52     [ { 0 0 } ] 2dip [ string-dim combine-text-dim ] with each ;
  53
  54 : text-width ( font text -- w ) text-dim first ;
  55
  56 : text-height ( font text -- h ) text-dim second ;
  57
  58 HOOK: font-metrics font-renderer ( font -- metrics )
  59
  60 HOOK: line-metrics font-renderer ( font string -- metrics )
  61
  62 GENERIC: draw-text ( font text -- )
  63
  64 M: string draw-text draw-string ;
  65
  66 M: selection draw-text draw-string ;
  67
  68 M: array draw-text
  69     [
  70         [
  71             [ draw-string ]
  72             [ [ 0.0 ] 2dip string-height 0.0 glTranslated ] 2bi
  73         ] with each
  74     ] do-matrix ;
  75
  76 USING: vocabs.loader system combinators ;
  77
  78 {
  79     { [ os macosx? ] [ "core-text" ] }
  80     { [ os windows? ] [ "uniscribe" ] }
  81     { [ os unix? ] [ "pango" ] }
  82 } cond "ui.text." prepend require