basis/ui/theme/switching/switching.factor

   1 ! Copyright (C) 2016 Nicolas Pénet.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs fonts fry hashtables help.stylesheet help.tips
   4 io.styles kernel listener namespaces prettyprint.stylesheet
   5 sequences ui.theme ui.tools.listener vocabs.prettyprint words ;
   6 IN: ui.theme.switching
   7
   8 <PRIVATE
   9
  10 : update-style ( style color elt -- )
  11     '[ _ _ rot ?set-at ] change-global ;
  12
  13 : update-stylesheet ( -- )
  14     ! fonts
  15     text-color default-font-foreground-color set-global
  16     content-background default-font-background-color set-global
  17
  18     ! help.stylesheet
  19     default-style text-color foreground update-style
  20     link-style link-color foreground update-style
  21     title-style title-color foreground update-style
  22     help-path-style help-path-border-color table-border update-style
  23     heading-style heading-color foreground update-style
  24     snippet-style snippet-color foreground update-style
  25     code-style code-background-color page-color update-style
  26     output-style output-color foreground update-style
  27     url-style link-color foreground update-style
  28     warning-style warning-background-color page-color update-style
  29     warning-style warning-border-color border-color update-style
  30     deprecated-style deprecated-background-color page-color update-style
  31     deprecated-style deprecated-border-color border-color update-style
  32     table-style table-border-color table-border update-style
  33
  34     ! help.tips
  35     tip-of-the-day-style tip-background-color page-color update-style
  36
  37     ! ui.tools.listener
  38     listener-input-style text-color foreground update-style
  39     listener-word-style text-color foreground update-style
  40
  41     ! prettyprint.stylesheet
  42     { POSTPONE: USING: POSTPONE: USE: POSTPONE: IN: }
  43     [ "word-style" word-prop [ dim-color foreground  ] dip set-at ] each
  44     base-word-style text-color foreground update-style
  45     highlighted-word-style highlighted-word-color foreground update-style
  46     base-string-style string-color foreground update-style
  47     base-vocab-style dim-color foreground update-style
  48     stack-effect-style stack-effect-color foreground update-style
  49
  50     ! listener
  51     prompt-style prompt-background-color background update-style
  52     prompt-style text-color foreground update-style
  53
  54     ! vocabs.prettyprint
  55     manifest-style vocab-background-color page-color update-style
  56     manifest-style vocab-border-color border-color update-style ;
  57
  58 PRIVATE>
  59
  60 : switch-theme ( theme -- )
  61     theme set-global update-stylesheet ;
  62
  63 : light-mode ( -- ) light-theme switch-theme ;
  64
  65 : dark-mode ( -- ) dark-theme switch-theme ;