basis/ui/tools/browser/browser.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs classes combinators
   4 combinators.short-circuit compiler.units debugger fonts fry help
   5 help.apropos help.crossref help.home help.markup help.stylesheet
   6 help.topics io.styles kernel literals locals make math math.vectors
   7 models namespaces sequences sets system ui ui.commands
   8 ui.gadgets ui.gadgets.borders ui.gadgets.editors
   9 ui.gadgets.glass ui.gadgets.panes ui.gadgets.scrollers
  10 ui.gadgets.status-bar ui.gadgets.toolbar ui.gadgets.tracks
  11 ui.gadgets.viewports ui.gadgets.worlds ui.gestures ui.pens.solid
  12 ui.theme ui.tools.browser.history ui.tools.browser.popups
  13 ui.tools.common unicode vocabs ;
  14 IN: ui.tools.browser
  15
  16 TUPLE: browser-gadget < tool history scroller search-field popup ;
  17
  18 browser-gadget default-font-size { 54 58 } n*v set-tool-dim
  19
  20 M: browser-gadget history-value
  21     [ control-value ] [ scroller>> scroll-position ]
  22     bi 2array ;
  23
  24 M: browser-gadget set-history-value
  25     [ first2 ] dip
  26     [ set-control-value ] [ scroller>> set-scroll-position ]
  27     bi-curry bi* ;
  28
  29 : show-help ( link browser-gadget -- )
  30     [ >link ] dip
  31     [
  32         2dup control-value =
  33         [ 2drop ] [ [ add-recent ] [ history>> add-history ] bi* ] if
  34     ]
  35     [ set-control-value ]
  36     2bi ;
  37
  38 CONSTANT: prev -1
  39 CONSTANT: next 1
  40
  41 : add-navigation-arrow ( str direction -- str )
  42     prev = [ "←" prefix ] [ "→" suffix ] if ;
  43
  44 : $navigation-arrow ( content element direction -- )
  45     [ prefix 1array ] dip add-navigation-arrow , ;
  46
  47 :: $navigation ( topic direction -- )
  48     help-path-style get [
  49         topic [
  50             direction prev/next-article
  51             [ 1array \ $long-link direction $navigation-arrow ] when*
  52         ] { } make [ ($navigation-table) ] unless-empty
  53     ] with-style ;
  54
  55 : $title ( topic -- )
  56     title-style get clone page-color over delete-at
  57     [
  58         [ ($title) ]
  59         [ ($navigation-path) ] bi
  60     ] with-nesting ;
  61
  62 : <help-header> ( browser-gadget -- gadget )
  63     model>> [ '[ _ $title ] try ] <pane-control> ;
  64
  65 : add-help-header ( track -- track )
  66     dup <help-header> { 3 3 } <border>
  67     help-header-background <solid> >>interior
  68     { 1 0 } >>fill f track-add ;
  69
  70 : <help-footer> ( browser-gadget direction -- gadget )
  71     [ model>> ] dip '[ [ _ $navigation ] try ] <pane-control>
  72     { 0 0 } <border> { 1/2 1/2 } >>align
  73     toolbar-background <solid> >>interior ;
  74
  75 : add-help-footer ( track -- track )
  76     horizontal <track> with-lines
  77     dupd swap prev <help-footer> 1 track-add
  78     dupd swap next <help-footer> 1 track-add
  79     f track-add ;
  80
  81 : print-topic ( topic -- )
  82     >link
  83     last-element off
  84     article-content print-content ;
  85
  86 : <help-pane> ( browser-gadget -- gadget )
  87     model>> [ '[ _ print-topic ] try ] <pane-control> ;
  88
  89 : add-help-pane ( track -- track )
  90     dup dup <help-pane> margins
  91     <scroller> >>scroller scroller>> white-interior 1 track-add ;
  92
  93 : search-browser ( string browser -- )
  94     '[ [ blank? ] trim <apropos-search> _ show-help ] unless-empty ;
  95
  96 : <search-field> ( browser -- field )
  97     '[ _ search-browser ] <action-field>
  98         "Search" >>default-text
  99         10 >>min-cols
 100         10 >>max-cols
 101         white-interior ;
 102
 103 : <browser-toolbar> ( browser -- toolbar )
 104     [ <toolbar> ] [
 105         search-field>> horizontal <track>
 106             0 >>fill swap 1 track-add
 107         1 track-add
 108     ] bi ;
 109
 110 : add-browser-toolbar ( track -- track )
 111     dup <browser-toolbar> format-toolbar f track-add ;
 112
 113 : <browser-gadget> ( link -- gadget )
 114     vertical browser-gadget new-track with-lines
 115         1 >>fill
 116         swap >link <model> >>model
 117         dup <history> >>history
 118         dup <search-field> >>search-field
 119         add-browser-toolbar
 120         add-help-header
 121         add-help-pane
 122         add-help-footer ;
 123
 124 M: browser-gadget graft*
 125     [ add-definition-observer ] [ call-next-method ] bi ;
 126
 127 M: browser-gadget ungraft*
 128     [ call-next-method ] [ remove-definition-observer ] bi ;
 129
 130 M: browser-gadget handle-gesture
 131     {
 132         { [ over key-gesture? not ] [ call-next-method ] }
 133         { [ dup popup>> ] [ { [ pass-to-popup ] [ call-next-method ] } 2&& ] }
 134         [ call-next-method ]
 135     } cond ;
 136
 137 : showing-definition? ( defspec set -- ? )
 138     {
 139         [ in? ]
 140         [ [ dup word-link? [ name>> ] when ] dip in? ]
 141         [ [ dup vocab-link? [ lookup-vocab ] when ] dip in? ]
 142     } 2|| ;
 143
 144 M: browser-gadget definitions-changed
 145     [ control-value swap showing-definition? ] keep
 146     '[ _ [ history-value ] keep set-history-value ] when ;
 147
 148 M: browser-gadget focusable-child* search-field>> ;
 149
 150 : (browser-window) ( topic -- )
 151     <browser-gadget>
 152     <world-attributes>
 153         "Browser" >>title
 154     open-status-window ;
 155
 156 : browser-window ( -- )
 157     "help.home" (browser-window) ;
 158
 159 : error-help-window ( error -- )
 160     {
 161         [ error-help ]
 162         [ dup tuple? [ class-of ] [ drop "errors" ] if ]
 163     } 1|| (browser-window) ;
 164
 165 \ browser-window H{ { +nullary+ t } } define-command
 166
 167 : com-browse ( link -- )
 168     [ browser-gadget? ] find-window
 169     [ [ raise-window ] [ gadget-child show-help ] bi ]
 170     [ (browser-window) ] if* ;
 171
 172 : show-browser ( -- )
 173     [ browser-gadget? ] find-window
 174     [ [ raise-window ] [ request-focus ] bi ] [ browser-window ] if* ;
 175
 176 \ show-browser H{ { +nullary+ t } } define-command
 177
 178 : com-back ( browser -- ) history>> go-back ;
 179
 180 : com-forward ( browser -- ) history>> go-forward ;
 181
 182 : com-home ( browser -- ) "help.home" swap show-help ;
 183
 184 : browser-help ( -- ) "ui-browser" com-browse ;
 185
 186 : glossary ( -- ) "conventions" com-browse ;
 187
 188 \ browser-help H{ { +nullary+ t } } define-command
 189 \ glossary H{ { +nullary+ t } } define-command
 190
 191 browser-gadget "toolbar" f {
 192     { T{ key-down f ${ os macosx? M+ A+ ? } "LEFT" } com-back }
 193     { T{ key-down f ${ os macosx? M+ A+ ? } "RIGHT" } com-forward }
 194     { T{ key-down f ${ os macosx? M+ A+ ? } "HOME" } com-home }
 195     { T{ key-down f f "F1" } browser-help }
 196     { T{ key-down f ${ os macosx? M+ A+ ? } "F1" } glossary }
 197 } define-command-map
 198
 199 : ?show-help ( link browser -- )
 200     over [ show-help ] [ 2drop ] if ;
 201
 202 : navigate ( browser quot -- )
 203     '[ control-value @ ] keep ?show-help ; inline
 204
 205 : com-up ( browser -- ) [ article-parent ] navigate ;
 206
 207 : com-prev ( browser -- ) [ prev-article ] navigate ;
 208
 209 : com-next ( browser -- ) [ next-article ] navigate ;
 210
 211 browser-gadget "navigation" "Commands for navigating in the article hierarchy" {
 212     { T{ key-down f ${ os macosx? M+ A+ ? } "UP" } com-up }
 213     { T{ key-down f ${ os macosx? M+ A+ ? } "p" } com-prev }
 214     { T{ key-down f ${ os macosx? M+ A+ ? } "n" } com-next }
 215     { T{ key-down f ${ os macosx? M+ A+ ? } "k" } com-show-outgoing-links }
 216     { T{ key-down f ${ os macosx? M+ A+ ? } "K" } com-show-incoming-links }
 217 } os macosx? [ {
 218     { T{ key-down f { M+ } "[" } com-back }
 219     { T{ key-down f { M+ } "]" } com-forward }
 220 } append ] when define-command-map
 221
 222 browser-gadget "multi-touch" f {
 223     { left-action com-back }
 224     { right-action com-forward }
 225 } define-command-map
 226
 227 browser-gadget "touchbar" f {
 228     { f com-back }
 229     { f com-forward }
 230     { f com-home }
 231     { f browser-help }
 232     { f glossary }
 233 } define-command-map
 234
 235 browser-gadget "scrolling"
 236 "The browser's scroller can be scrolled from the keyboard."
 237 {
 238     { T{ key-down f f "UP" } com-scroll-up }
 239     { T{ key-down f f "DOWN" } com-scroll-down }
 240     { T{ key-down f f "PAGE_UP" } com-page-up }
 241     { T{ key-down f f "PAGE_DOWN" } com-page-down }
 242 } define-command-map
 243
 244 : com-font-size-plus ( browser -- )
 245     2 adjust-help-font-size model>> notify-connections ;
 246
 247 : com-font-size-minus ( browser -- )
 248     -2 adjust-help-font-size model>> notify-connections ;
 249
 250 : com-font-size-normal ( browser -- )
 251     font-size-span default-style get font-size of -
 252     adjust-help-font-size model>> notify-connections ;
 253
 254 browser-gadget "fonts" f {
 255     { T{ key-down f ${ os macosx? M+ C+ ? } "+" } com-font-size-plus }
 256     { T{ key-down f ${ os macosx? M+ C+ ? } "=" } com-font-size-plus }
 257     { T{ key-down f ${ os macosx? M+ C+ ? } "_" } com-font-size-minus }
 258     { T{ key-down f ${ os macosx? M+ C+ ? } "-" } com-font-size-minus }
 259     { T{ key-down f ${ os macosx? M+ C+ ? } "0" } com-font-size-normal }
 260 } define-command-map
 261
 262 MAIN: browser-window