basis/ui/tools/browser/browser.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs classes combinators
   4 combinators.short-circuit compiler.units debugger fonts fry help
   5 help.apropos help.crossref help.home help.markup help.stylesheet
   6 help.topics io.styles kernel locals make math.vectors models
   7 namespaces sequences sets ui ui.commands ui.gadgets ui.gadgets.borders
   8 ui.gadgets.editors ui.gadgets.glass ui.gadgets.panes
   9 ui.gadgets.scrollers ui.gadgets.status-bar ui.gadgets.toolbar
  10 ui.gadgets.tracks ui.gadgets.viewports ui.gadgets.worlds ui.gestures
  11 ui.pens.solid ui.theme ui.tools.browser.history
  12 ui.tools.browser.popups ui.tools.common unicode vocabs ;
  13 IN: ui.tools.browser
  14
  15 TUPLE: browser-gadget < tool history scroller search-field popup ;
  16
  17 browser-gadget default-font-size { 54 58 } n*v set-tool-dim
  18
  19 M: browser-gadget history-value
  20     [ control-value ] [ scroller>> scroll-position ]
  21     bi 2array ;
  22
  23 M: browser-gadget set-history-value
  24     [ first2 ] dip
  25     [ set-control-value ] [ scroller>> set-scroll-position ]
  26     bi-curry bi* ;
  27
  28 : show-help ( link browser-gadget -- )
  29     [ >link ] dip
  30     [
  31         2dup control-value =
  32         [ 2drop ] [ [ add-recent ] [ history>> add-history ] bi* ] if
  33     ]
  34     [ set-control-value ]
  35     2bi ;
  36
  37 CONSTANT: prev -1
  38 CONSTANT: next 1
  39
  40 : add-navigation-arrow ( str direction -- str )
  41     prev = [ "←" prefix ] [ "→" suffix ] if ;
  42
  43 : $navigation-arrow ( content element direction -- )
  44     [ prefix 1array ] dip add-navigation-arrow , ;
  45
  46 :: $navigation ( topic direction -- )
  47     help-path-style get [
  48         topic [
  49             direction prev/next-article
  50             [ 1array \ $long-link direction $navigation-arrow ] when*
  51         ] { } make [ ($navigation-table) ] unless-empty
  52     ] with-style ;
  53
  54 : $title ( topic -- )
  55     title-style get clone page-color over delete-at
  56     [
  57         [ ($title) ]
  58         [ ($navigation-path) ] bi
  59     ] with-nesting ;
  60
  61 : <help-header> ( browser-gadget -- gadget )
  62     model>> [ '[ _ $title ] try ] <pane-control> ;
  63
  64 : add-help-header ( track -- track )
  65     dup <help-header> { 3 3 } <border>
  66     help-header-background <solid> >>interior
  67     { 1 0 } >>fill f track-add ;
  68
  69 : <help-footer> ( browser-gadget direction -- gadget )
  70     [ model>> ] dip '[ [ _ $navigation ] try ] <pane-control>
  71     { 0 0 } <border> { 1/2 1/2 } >>align
  72     toolbar-background <solid> >>interior ;
  73
  74 : add-help-footer ( track -- track )
  75     horizontal <track> with-lines
  76     dupd swap prev <help-footer> 1 track-add
  77     dupd swap next <help-footer> 1 track-add
  78     f track-add ;
  79
  80 : print-topic ( topic -- )
  81     >link
  82     last-element off
  83     article-content print-content ;
  84
  85 : <help-pane> ( browser-gadget -- gadget )
  86     model>> [ '[ _ print-topic ] try ] <pane-control> ;
  87
  88 : add-help-pane ( track -- track )
  89     dup dup <help-pane> margins
  90     <scroller> >>scroller scroller>> white-interior 1 track-add ;
  91
  92 : search-browser ( string browser -- )
  93     '[ [ blank? ] trim <apropos-search> _ show-help ] unless-empty ;
  94
  95 : <search-field> ( browser -- field )
  96     '[ _ search-browser ] <action-field>
  97         "Search" >>default-text
  98         10 >>min-cols
  99         10 >>max-cols
 100         white-interior ;
 101
 102 : <browser-toolbar> ( browser -- toolbar )
 103     [ <toolbar> ] [
 104         search-field>> horizontal <track>
 105             0 >>fill swap 1 track-add
 106         1 track-add
 107     ] bi ;
 108
 109 : add-browser-toolbar ( track -- track )
 110     dup <browser-toolbar> format-toolbar f track-add ;
 111
 112 : <browser-gadget> ( link -- gadget )
 113     vertical browser-gadget new-track with-lines
 114         1 >>fill
 115         swap >link <model> >>model
 116         dup <history> >>history
 117         dup <search-field> >>search-field
 118         add-browser-toolbar
 119         add-help-header
 120         add-help-pane
 121         add-help-footer ;
 122
 123 M: browser-gadget graft*
 124     [ add-definition-observer ] [ call-next-method ] bi ;
 125
 126 M: browser-gadget ungraft*
 127     [ call-next-method ] [ remove-definition-observer ] bi ;
 128
 129 M: browser-gadget handle-gesture
 130     {
 131         { [ over key-gesture? not ] [ call-next-method ] }
 132         { [ dup popup>> ] [ { [ pass-to-popup ] [ call-next-method ] } 2&& ] }
 133         [ call-next-method ]
 134     } cond ;
 135
 136 : showing-definition? ( defspec set -- ? )
 137     {
 138         [ in? ]
 139         [ [ dup word-link? [ name>> ] when ] dip in? ]
 140         [ [ dup vocab-link? [ lookup-vocab ] when ] dip in? ]
 141     } 2|| ;
 142
 143 M: browser-gadget definitions-changed
 144     [ control-value swap showing-definition? ] keep
 145     '[ _ [ history-value ] keep set-history-value ] when ;
 146
 147 M: browser-gadget focusable-child* search-field>> ;
 148
 149 : (browser-window) ( topic -- )
 150     <browser-gadget>
 151     <world-attributes>
 152         "Browser" >>title
 153     open-status-window ;
 154
 155 : browser-window ( -- )
 156     "help.home" (browser-window) ;
 157
 158 : error-help-window ( error -- )
 159     {
 160         [ error-help ]
 161         [ dup tuple? [ class-of ] [ drop "errors" ] if ]
 162     } 1|| (browser-window) ;
 163
 164 \ browser-window H{ { +nullary+ t } } define-command
 165
 166 : com-browse ( link -- )
 167     [ browser-gadget? ] find-window
 168     [ [ raise-window ] [ gadget-child show-help ] bi ]
 169     [ (browser-window) ] if* ;
 170
 171 : show-browser ( -- )
 172     [ browser-gadget? ] find-window
 173     [ [ raise-window ] [ request-focus ] bi ] [ browser-window ] if* ;
 174
 175 \ show-browser H{ { +nullary+ t } } define-command
 176
 177 : com-back ( browser -- ) history>> go-back ;
 178
 179 : com-forward ( browser -- ) history>> go-forward ;
 180
 181 : com-home ( browser -- ) "help.home" swap show-help ;
 182
 183 : browser-help ( -- ) "ui-browser" com-browse ;
 184
 185 : glossary ( -- ) "conventions" com-browse ;
 186
 187 \ browser-help H{ { +nullary+ t } } define-command
 188 \ glossary H{ { +nullary+ t } } define-command
 189
 190 browser-gadget "toolbar" f {
 191     { T{ key-down f { A+ } "LEFT" } com-back }
 192     { T{ key-down f { A+ } "RIGHT" } com-forward }
 193     { T{ key-down f { A+ } "H" } com-home }
 194     { T{ key-down f f "F1" } browser-help }
 195     { T{ key-down f { A+ } "F1" } glossary }
 196 } define-command-map
 197
 198 : ?show-help ( link browser -- )
 199     over [ show-help ] [ 2drop ] if ;
 200
 201 : navigate ( browser quot -- )
 202     '[ control-value @ ] keep ?show-help ; inline
 203
 204 : com-up ( browser -- ) [ article-parent ] navigate ;
 205
 206 : com-prev ( browser -- ) [ prev-article ] navigate ;
 207
 208 : com-next ( browser -- ) [ next-article ] navigate ;
 209
 210 browser-gadget "navigation" "Commands for navigating in the article hierarchy" {
 211     { T{ key-down f { A+ } "u" } com-up }
 212     { T{ key-down f { A+ } "p" } com-prev }
 213     { T{ key-down f { A+ } "n" } com-next }
 214     { T{ key-down f { A+ } "k" } com-show-outgoing-links }
 215     { T{ key-down f { A+ } "K" } com-show-incoming-links }
 216 } define-command-map
 217
 218 browser-gadget "multi-touch" f {
 219     { left-action com-back }
 220     { right-action com-forward }
 221 } define-command-map
 222
 223 browser-gadget "touchbar" f {
 224     { f com-back }
 225     { f com-forward }
 226     { f com-home }
 227     { f browser-help }
 228     { f glossary }
 229 } define-command-map
 230
 231 browser-gadget "scrolling"
 232 "The browser's scroller can be scrolled from the keyboard."
 233 {
 234     { T{ key-down f f "UP" } com-scroll-up }
 235     { T{ key-down f f "DOWN" } com-scroll-down }
 236     { T{ key-down f f "PAGE_UP" } com-page-up }
 237     { T{ key-down f f "PAGE_DOWN" } com-page-down }
 238 } define-command-map
 239
 240 : com-font-size-plus ( browser -- )
 241     2 adjust-help-font-size model>> notify-connections ;
 242
 243 : com-font-size-minus ( browser -- )
 244     -2 adjust-help-font-size model>> notify-connections ;
 245
 246 browser-gadget "fonts" f {
 247     { T{ key-down f { A+ } "+" } com-font-size-plus }
 248     { T{ key-down f { A+ } "=" } com-font-size-plus }
 249     { T{ key-down f { A+ } "_" } com-font-size-minus }
 250     { T{ key-down f { A+ } "-" } com-font-size-minus }
 251 } define-command-map
 252
 253 MAIN: browser-window