basis/ui/tools/browser/browser.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs classes colors.constants
   4 combinators combinators.short-circuit compiler.units debugger
   5 documents fry help help.apropos help.crossref help.home
   6 help.markup help.stylesheet help.topics io.styles kernel locals
   7 make models namespaces sequences sets ui ui.commands ui.gadgets
   8 ui.gadgets.borders ui.gadgets.editors ui.gadgets.editors.private
   9 ui.gadgets.glass ui.gadgets.labels ui.gadgets.labels.private
  10 ui.gadgets.panes ui.gadgets.scrollers ui.gadgets.status-bar
  11 ui.theme ui.gadgets.theme ui.gadgets.toolbar ui.gadgets.tracks
  12 ui.gadgets.viewports ui.gadgets.worlds ui.gestures ui.pens.solid
  13 ui.render ui.text ui.tools.common ui.tools.browser.history
  14 ui.tools.browser.popups vocabs ;
  15 IN: ui.tools.browser
  16
  17 TUPLE: browser-gadget < tool history scroller search-field popup ;
  18
  19 { 650 700 } browser-gadget set-tool-dim
  20
  21 M: browser-gadget history-value
  22     [ control-value ] [ scroller>> scroll-position ]
  23     bi 2array ;
  24
  25 M: browser-gadget set-history-value
  26     [ first2 ] dip
  27     [ set-control-value ] [ scroller>> set-scroll-position ]
  28     bi-curry bi* ;
  29
  30 : show-help ( link browser-gadget -- )
  31     [ >link ] dip
  32     [
  33         2dup control-value =
  34         [ 2drop ] [ [ add-recent ] [ history>> add-history ] bi* ] if
  35     ]
  36     [ set-control-value ]
  37     2bi ;
  38
  39 CONSTANT: prev -1
  40 CONSTANT: next 1
  41
  42 : add-navigation-arrow ( str direction -- str )
  43     prev = [ "<" prefix ] [ ">" suffix ] if ;
  44
  45 : $navigation-arrow ( content element direction -- )
  46     [ prefix 1array ] dip add-navigation-arrow , ;
  47
  48 :: ($navigation) ( topic direction -- )
  49     help-path-style get [
  50         topic [
  51             direction prev/next-article
  52             [ 1array \ $long-link direction $navigation-arrow ] when*
  53         ] { } make [ ($navigation-table) ] unless-empty
  54     ] with-style ;
  55
  56 : $navigation ( topic direction -- )
  57     title-style get [ ($navigation) ] with-style ;
  58
  59 : $title ( topic -- )
  60     title-style get clone page-color over delete-at dup
  61     [
  62         [
  63             [ ($title) ]
  64             [ ($navigation-path) ] bi
  65         ] with-nesting
  66     ] with-style ;
  67
  68 : <help-header> ( browser-gadget -- gadget )
  69     model>> [ '[ _ $title ] try ] <pane-control> ;
  70
  71 : add-help-header ( track -- track )
  72     dup <help-header> { 3 3 } <border>
  73     help-header-background <solid> >>interior
  74     { 1 0 } >>fill f track-add ;
  75
  76 : <help-footer> ( browser-gadget direction -- gadget )
  77     [ model>> ] dip '[ [ _ $navigation ] try ] <pane-control>
  78     { 0 0 } <border> { 1/2 1/2 } >>align
  79     toolbar-background <solid> >>interior ;
  80
  81 : add-help-footer ( track -- track )
  82     horizontal <track> with-lines
  83     dupd swap prev <help-footer> 1 track-add
  84     dupd swap next <help-footer> 1 track-add
  85     f track-add ;
  86
  87 : print-topic ( topic -- )
  88     >link
  89     last-element off
  90     article-content print-content ;
  91
  92 : <help-pane> ( browser-gadget -- gadget )
  93     model>> [ '[ _ print-topic ] try ] <pane-control> ;
  94
  95 : add-help-pane ( track -- track )
  96     dup dup <help-pane> margins
  97     <scroller> >>scroller scroller>> white-interior 1 track-add ;
  98
  99 : search-browser ( string browser -- )
 100     '[ <apropos-search> _ show-help ] unless-empty ;
 101
 102 : <search-field> ( browser -- field )
 103     '[ _ search-browser ] <action-field>
 104         [ theme-font-colors ] change-editor
 105         "Search" >>default-text
 106         10 >>min-cols
 107         10 >>max-cols
 108         white-interior ;
 109
 110 : <browser-toolbar> ( browser -- toolbar )
 111     [ <toolbar> ] [
 112         search-field>> horizontal <track>
 113             0 >>fill swap 1 track-add
 114         1 track-add
 115     ] bi ;
 116
 117 : add-browser-toolbar ( track -- track )
 118     dup <browser-toolbar> format-toolbar f track-add ;
 119
 120 : <browser-gadget> ( link -- gadget )
 121     vertical browser-gadget new-track with-lines
 122         1 >>fill
 123         swap >link <model> >>model
 124         dup <history> >>history
 125         dup <search-field> >>search-field
 126         add-browser-toolbar
 127         add-help-header
 128         add-help-pane
 129         add-help-footer ;
 130
 131 M: browser-gadget graft*
 132     [ add-definition-observer ] [ call-next-method ] bi ;
 133
 134 M: browser-gadget ungraft*
 135     [ call-next-method ] [ remove-definition-observer ] bi ;
 136
 137 M: browser-gadget handle-gesture
 138     {
 139         { [ over key-gesture? not ] [ call-next-method ] }
 140         { [ dup popup>> ] [ { [ pass-to-popup ] [ call-next-method ] } 2&& ] }
 141         [ call-next-method ]
 142     } cond ;
 143
 144 : showing-definition? ( defspec set -- ? )
 145     {
 146         [ in? ]
 147         [ [ dup word-link? [ name>> ] when ] dip in? ]
 148         [ [ dup vocab-link? [ lookup-vocab ] when ] dip in? ]
 149     } 2|| ;
 150
 151 M: browser-gadget definitions-changed ( set browser -- )
 152     [ control-value swap showing-definition? ] keep
 153     '[ _ [ history-value ] keep set-history-value ] when ;
 154
 155 M: browser-gadget focusable-child* search-field>> ;
 156
 157 : (browser-window) ( topic -- )
 158     <browser-gadget>
 159     <world-attributes>
 160         "Browser" >>title
 161     open-status-window ;
 162
 163 : browser-window ( -- )
 164     "help.home" (browser-window) ;
 165
 166 : error-help-window ( error -- )
 167     {
 168         [ error-help ]
 169         [ dup tuple? [ class-of ] [ drop "errors" ] if ]
 170     } 1|| (browser-window) ;
 171
 172 \ browser-window H{ { +nullary+ t } } define-command
 173
 174 : com-browse ( link -- )
 175     [ browser-gadget? ] find-window
 176     [ [ raise-window ] [ gadget-child show-help ] bi ]
 177     [ (browser-window) ] if* ;
 178
 179 : show-browser ( -- )
 180     [ browser-gadget? ] find-window
 181     [ [ raise-window ] [ request-focus ] bi ] [ browser-window ] if* ;
 182
 183 \ show-browser H{ { +nullary+ t } } define-command
 184
 185 : com-back ( browser -- ) history>> go-back ;
 186
 187 : com-forward ( browser -- ) history>> go-forward ;
 188
 189 : com-home ( browser -- ) "help.home" swap show-help ;
 190
 191 : browser-help ( -- ) "ui-browser" com-browse ;
 192
 193 : glossary ( -- ) "conventions" com-browse ;
 194
 195 \ browser-help H{ { +nullary+ t } } define-command
 196 \ glossary H{ { +nullary+ t } } define-command
 197
 198 browser-gadget "toolbar" f {
 199     { T{ key-down f { A+ } "LEFT" } com-back }
 200     { T{ key-down f { A+ } "RIGHT" } com-forward }
 201     { T{ key-down f { A+ } "H" } com-home }
 202     { T{ key-down f f "F1" } browser-help }
 203     { T{ key-down f { A+ } "F1" } glossary }
 204 } define-command-map
 205
 206 : ?show-help ( link browser -- )
 207     over [ show-help ] [ 2drop ] if ;
 208
 209 : navigate ( browser quot -- )
 210     '[ control-value @ ] keep ?show-help ; inline
 211
 212 : com-up ( browser -- ) [ article-parent ] navigate ;
 213
 214 : com-prev ( browser -- ) [ prev-article ] navigate ;
 215
 216 : com-next ( browser -- ) [ next-article ] navigate ;
 217
 218 browser-gadget "navigation" "Commands for navigating in the article hierarchy" {
 219     { T{ key-down f { A+ } "u" } com-up }
 220     { T{ key-down f { A+ } "p" } com-prev }
 221     { T{ key-down f { A+ } "n" } com-next }
 222     { T{ key-down f { A+ } "k" } com-show-outgoing-links }
 223     { T{ key-down f { A+ } "K" } com-show-incoming-links }
 224 } define-command-map
 225
 226 browser-gadget "multi-touch" f {
 227     { left-action com-back }
 228     { right-action com-forward }
 229 } define-command-map
 230
 231 browser-gadget "scrolling"
 232 "The browser's scroller can be scrolled from the keyboard."
 233 {
 234     { T{ key-down f f "UP" } com-scroll-up }
 235     { T{ key-down f f "DOWN" } com-scroll-down }
 236     { T{ key-down f f "PAGE_UP" } com-page-up }
 237     { T{ key-down f f "PAGE_DOWN" } com-page-down }
 238 } define-command-map
 239
 240 : com-font-size-plus ( browser -- )
 241     2 adjust-help-font-size model>> notify-connections ;
 242
 243 : com-font-size-minus ( browser -- )
 244     -2 adjust-help-font-size model>> notify-connections ;
 245
 246 browser-gadget "fonts" f {
 247     { T{ key-down f { A+ } "+" } com-font-size-plus }
 248     { T{ key-down f { A+ } "=" } com-font-size-plus }
 249     { T{ key-down f { A+ } "_" } com-font-size-minus }
 250     { T{ key-down f { A+ } "-" } com-font-size-minus }
 251 } define-command-map
 252
 253 MAIN: browser-window