basis/ui/tools/browser/browser.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs classes combinators
   4 combinators.short-circuit compiler.units debugger fry help
   5 help.apropos help.crossref help.home help.topics kernel models
   6 sequences ui ui.commands ui.gadgets ui.gadgets.borders
   7 ui.gadgets.buttons ui.gadgets.editors ui.gadgets.glass
   8 ui.gadgets.labels ui.gadgets.panes ui.gadgets.scrollers
   9 ui.gadgets.status-bar ui.gadgets.tracks ui.gadgets.viewports
  10 ui.gestures ui.tools.browser.history ui.tools.browser.popups
  11 ui.tools.common vocabs ;
  12 IN: ui.tools.browser
  13
  14 TUPLE: browser-gadget < tool history scroller search-field popup ;
  15
  16 { 650 700 } browser-gadget set-tool-dim
  17
  18 M: browser-gadget history-value
  19     [ control-value ] [ scroller>> scroll-position ]
  20     bi 2array ;
  21
  22 M: browser-gadget set-history-value
  23     [ first2 ] dip
  24     [ set-control-value ] [ scroller>> set-scroll-position ]
  25     bi-curry bi* ;
  26
  27 : show-help ( link browser-gadget -- )
  28     [ >link ] dip
  29     [
  30         2dup model>> value>> =
  31         [ 2drop ] [ [ add-recent ] [ history>> add-history ] bi* ] if
  32     ]
  33     [ model>> set-model ]
  34     2bi ;
  35
  36 : <help-pane> ( browser-gadget -- gadget )
  37     model>> [ '[ _ print-topic ] try ] <pane-control> ;
  38
  39 : search-browser ( string browser -- )
  40     '[ <apropos> _ show-help ] unless-empty ;
  41
  42 : <search-field> ( browser -- field )
  43     '[ _ search-browser ] <action-field>
  44         10 >>min-cols
  45         10 >>max-cols ;
  46
  47 : <browser-toolbar> ( browser -- toolbar )
  48     horizontal <track>
  49         0 >>fill
  50         1/2 >>align
  51         { 5 5 } >>gap
  52         over <toolbar> f track-add
  53         swap search-field>> "Search:" label-on-left 1 track-add ;
  54
  55 : <browser-gadget> ( link -- gadget )
  56     vertical browser-gadget new-track
  57         1 >>fill
  58         swap >link <model> >>model
  59         dup <history> >>history
  60         dup <search-field> >>search-field
  61         dup <browser-toolbar> { 3 3 } <border> { 1 0 } >>fill f track-add
  62         dup dup <help-pane> { 10 0 } <border> { 1 1 } >>fill
  63         <scroller> >>scroller scroller>> 1 track-add ;
  64
  65 M: browser-gadget graft*
  66     [ add-definition-observer ] [ call-next-method ] bi ;
  67
  68 M: browser-gadget ungraft*
  69     [ call-next-method ] [ remove-definition-observer ] bi ;
  70
  71 M: browser-gadget handle-gesture
  72     {
  73         { [ over key-gesture? not ] [ call-next-method ] }
  74         { [ dup popup>> ] [ { [ pass-to-popup ] [ call-next-method ] } 2&& ] }
  75         [ call-next-method ]
  76     } cond ;
  77
  78 : showing-definition? ( defspec assoc -- ? )
  79     {
  80         [ key? ]
  81         [ [ dup word-link? [ name>> ] when ] dip key? ]
  82         [ [ dup vocab-link? [ vocab ] when ] dip key? ]
  83     } 2|| ;
  84
  85 M: browser-gadget definitions-changed ( assoc browser -- )
  86     [ model>> value>> swap showing-definition? ] keep
  87     '[ _ [ history-value ] keep set-history-value ] when ;
  88
  89 M: browser-gadget focusable-child* search-field>> ;
  90
  91 : (browser-window) ( topic -- )
  92     <browser-gadget> "Browser" open-status-window ;
  93
  94 : browser-window ( -- )
  95     "help.home" (browser-window) ;
  96
  97 : error-help-window ( error -- )
  98     {
  99         [ error-help ]
 100         [ dup tuple? [ class ] [ drop "errors" ] if ]
 101     } 1|| (browser-window) ;
 102
 103 \ browser-window H{ { +nullary+ t } } define-command
 104
 105 : com-browse ( link -- )
 106     [ browser-gadget? ] find-window
 107     [ [ raise-window ] [ gadget-child show-help ] bi ]
 108     [ (browser-window) ] if* ;
 109
 110 : show-browser ( -- )
 111     [ browser-gadget? ] find-window
 112     [ [ raise-window ] [ request-focus ] bi ] [ browser-window ] if* ;
 113
 114 \ show-browser H{ { +nullary+ t } } define-command
 115
 116 : com-back ( browser -- ) history>> go-back ;
 117
 118 : com-forward ( browser -- ) history>> go-forward ;
 119
 120 : com-home ( browser -- ) "help.home" swap show-help ;
 121
 122 : browser-help ( -- ) "ui-browser" com-browse ;
 123
 124 : glossary ( -- ) "conventions" com-browse ;
 125
 126 \ browser-help H{ { +nullary+ t } } define-command
 127 \ glossary H{ { +nullary+ t } } define-command
 128
 129 browser-gadget "toolbar" f {
 130     { T{ key-down f { A+ } "LEFT" } com-back }
 131     { T{ key-down f { A+ } "RIGHT" } com-forward }
 132     { T{ key-down f { A+ } "H" } com-home }
 133     { T{ key-down f f "F1" } browser-help }
 134     { T{ key-down f { A+ } "F1" } glossary }
 135 } define-command-map
 136
 137 : ?show-help ( link browser -- )
 138     over [ show-help ] [ 2drop ] if ;
 139
 140 : navigate ( browser quot -- )
 141     '[ control-value @ ] keep ?show-help ; inline
 142
 143 : com-up ( browser -- ) [ article-parent ] navigate ;
 144
 145 : com-prev ( browser -- ) [ prev-article ] navigate ;
 146
 147 : com-next ( browser -- ) [ next-article ] navigate ;
 148
 149 browser-gadget "navigation" "Commands for navigating in the article hierarchy" {
 150     { T{ key-down f { A+ } "u" } com-up }
 151     { T{ key-down f { A+ } "p" } com-prev }
 152     { T{ key-down f { A+ } "n" } com-next }
 153     { T{ key-down f { A+ } "k" } com-show-outgoing-links }
 154     { T{ key-down f { A+ } "K" } com-show-incoming-links }
 155 } define-command-map
 156
 157 browser-gadget "multi-touch" f {
 158     { left-action com-back }
 159     { right-action com-forward }
 160 } define-command-map
 161
 162 browser-gadget "scrolling"
 163 "The browser's scroller can be scrolled from the keyboard."
 164 {
 165     { T{ key-down f f "UP" } com-scroll-up }
 166     { T{ key-down f f "DOWN" } com-scroll-down }
 167     { T{ key-down f f "PAGE_UP" } com-page-up }
 168     { T{ key-down f f "PAGE_DOWN" } com-page-down }
 169 } define-command-map
 170
 171 MAIN: browser-window