basis/ui/tools/browser/browser.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays classes combinators
   4 combinators.short-circuit compiler.units debugger fry help
   5 help.apropos help.crossref help.home help.stylesheet help.topics
   6 kernel models sequences sets ui ui.commands ui.gadgets
   7 ui.gadgets.borders ui.gadgets.buttons ui.gadgets.editors
   8 ui.gadgets.glass ui.gadgets.labels ui.gadgets.panes
   9 ui.gadgets.scrollers ui.gadgets.status-bar ui.gadgets.tracks
  10 ui.gadgets.viewports ui.gadgets.worlds ui.gestures
  11 ui.tools.browser.history ui.tools.browser.popups ui.tools.common
  12 vocabs ;
  13 IN: ui.tools.browser
  14
  15 TUPLE: browser-gadget < tool history scroller search-field popup ;
  16
  17 { 650 700 } browser-gadget set-tool-dim
  18
  19 M: browser-gadget history-value
  20     [ control-value ] [ scroller>> scroll-position ]
  21     bi 2array ;
  22
  23 M: browser-gadget set-history-value
  24     [ first2 ] dip
  25     [ set-control-value ] [ scroller>> set-scroll-position ]
  26     bi-curry bi* ;
  27
  28 : show-help ( link browser-gadget -- )
  29     [ >link ] dip
  30     [
  31         2dup control-value =
  32         [ 2drop ] [ [ add-recent ] [ history>> add-history ] bi* ] if
  33     ]
  34     [ set-control-value ]
  35     2bi ;
  36
  37 : <help-header> ( browser-gadget -- gadget )
  38     model>> [ '[ _ $title ] try ] <pane-control> ;
  39
  40 CONSTANT: help-header-background COLOR: FactorLightTan
  41
  42 : help-header ( track -- track )
  43     dup <help-header> { 3 3 } <border>
  44     help-header-background <solid> >>interior
  45     { 1 0 } >>fill f track-add ;
  46
  47 : <help-pane> ( browser-gadget -- gadget )
  48     model>> [ '[ _ print-topic ] try ] <pane-control> ;
  49
  50 : help-pane ( track -- track )
  51     dup dup <help-pane> margins
  52     <scroller> >>scroller scroller>> white-interior 1 track-add ;
  53
  54 : search-browser ( string browser -- )
  55     '[ <apropos-search> _ show-help ] unless-empty ;
  56
  57 : <search-field> ( browser -- field )
  58     '[ _ search-browser ] <action-field>
  59         10 >>min-cols
  60         10 >>max-cols
  61         white-interior ;
  62
  63 : <browser-toolbar> ( browser -- toolbar )
  64     horizontal <track>
  65         0 >>fill
  66         1/2 >>align
  67         { 5 5 } >>gap
  68         over <toolbar> f track-add
  69         swap search-field>> "          Search" label-on-left 1 track-add ;
  70
  71 : browser-toolbar ( track -- track )
  72     dup <browser-toolbar> { 3 3 } <border>
  73     toolbar-background <solid> >>interior { 1 0 } >>fill
  74     f track-add ;
  75
  76 : <browser-gadget> ( link -- gadget )
  77     vertical browser-gadget new-track with-lines
  78         1 >>fill
  79         swap >link <model> >>model
  80         dup <history> >>history
  81         dup <search-field> >>search-field
  82         browser-toolbar
  83         help-header
  84         help-pane ;
  85
  86 M: browser-gadget graft*
  87     [ add-definition-observer ] [ call-next-method ] bi ;
  88
  89 M: browser-gadget ungraft*
  90     [ call-next-method ] [ remove-definition-observer ] bi ;
  91
  92 M: browser-gadget handle-gesture
  93     {
  94         { [ over key-gesture? not ] [ call-next-method ] }
  95         { [ dup popup>> ] [ { [ pass-to-popup ] [ call-next-method ] } 2&& ] }
  96         [ call-next-method ]
  97     } cond ;
  98
  99 : showing-definition? ( defspec set -- ? )
 100     {
 101         [ in? ]
 102         [ [ dup word-link? [ name>> ] when ] dip in? ]
 103         [ [ dup vocab-link? [ lookup-vocab ] when ] dip in? ]
 104     } 2|| ;
 105
 106 M: browser-gadget definitions-changed ( set browser -- )
 107     [ control-value swap showing-definition? ] keep
 108     '[ _ [ history-value ] keep set-history-value ] when ;
 109
 110 M: browser-gadget focusable-child* search-field>> ;
 111
 112 : (browser-window) ( topic -- )
 113     <browser-gadget>
 114     <world-attributes>
 115         "Browser" >>title
 116     open-status-window ;
 117
 118 : browser-window ( -- )
 119     "help.home" (browser-window) ;
 120
 121 : error-help-window ( error -- )
 122     {
 123         [ error-help ]
 124         [ dup tuple? [ class-of ] [ drop "errors" ] if ]
 125     } 1|| (browser-window) ;
 126
 127 \ browser-window H{ { +nullary+ t } } define-command
 128
 129 : com-browse ( link -- )
 130     [ browser-gadget? ] find-window
 131     [ [ raise-window ] [ gadget-child show-help ] bi ]
 132     [ (browser-window) ] if* ;
 133
 134 : show-browser ( -- )
 135     [ browser-gadget? ] find-window
 136     [ [ raise-window ] [ request-focus ] bi ] [ browser-window ] if* ;
 137
 138 \ show-browser H{ { +nullary+ t } } define-command
 139
 140 : com-back ( browser -- ) history>> go-back ;
 141
 142 : com-forward ( browser -- ) history>> go-forward ;
 143
 144 : com-home ( browser -- ) "help.home" swap show-help ;
 145
 146 : browser-help ( -- ) "ui-browser" com-browse ;
 147
 148 : glossary ( -- ) "conventions" com-browse ;
 149
 150 \ browser-help H{ { +nullary+ t } } define-command
 151 \ glossary H{ { +nullary+ t } } define-command
 152
 153 browser-gadget "toolbar" f {
 154     { T{ key-down f { A+ } "LEFT" } com-back }
 155     { T{ key-down f { A+ } "RIGHT" } com-forward }
 156     { T{ key-down f { A+ } "H" } com-home }
 157     { T{ key-down f f "F1" } browser-help }
 158     { T{ key-down f { A+ } "F1" } glossary }
 159 } define-command-map
 160
 161 : ?show-help ( link browser -- )
 162     over [ show-help ] [ 2drop ] if ;
 163
 164 : navigate ( browser quot -- )
 165     '[ control-value @ ] keep ?show-help ; inline
 166
 167 : com-up ( browser -- ) [ article-parent ] navigate ;
 168
 169 : com-prev ( browser -- ) [ prev-article ] navigate ;
 170
 171 : com-next ( browser -- ) [ next-article ] navigate ;
 172
 173 browser-gadget "navigation" "Commands for navigating in the article hierarchy" {
 174     { T{ key-down f { A+ } "u" } com-up }
 175     { T{ key-down f { A+ } "p" } com-prev }
 176     { T{ key-down f { A+ } "n" } com-next }
 177     { T{ key-down f { A+ } "k" } com-show-outgoing-links }
 178     { T{ key-down f { A+ } "K" } com-show-incoming-links }
 179 } define-command-map
 180
 181 browser-gadget "multi-touch" f {
 182     { left-action com-back }
 183     { right-action com-forward }
 184 } define-command-map
 185
 186 browser-gadget "scrolling"
 187 "The browser's scroller can be scrolled from the keyboard."
 188 {
 189     { T{ key-down f f "UP" } com-scroll-up }
 190     { T{ key-down f f "DOWN" } com-scroll-down }
 191     { T{ key-down f f "PAGE_UP" } com-page-up }
 192     { T{ key-down f f "PAGE_DOWN" } com-page-down }
 193 } define-command-map
 194
 195 : com-font-size-plus ( browser -- )
 196     2 adjust-help-font-size model>> notify-connections ;
 197
 198 : com-font-size-minus ( browser -- )
 199     -2 adjust-help-font-size model>> notify-connections ;
 200
 201 browser-gadget "fonts" f {
 202     { T{ key-down f { A+ } "+" } com-font-size-plus }
 203     { T{ key-down f { A+ } "=" } com-font-size-plus }
 204     { T{ key-down f { A+ } "_" } com-font-size-minus }
 205     { T{ key-down f { A+ } "-" } com-font-size-minus }
 206 } define-command-map
 207
 208 MAIN: browser-window