basis/ui/tools/browser/browser.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: debugger classes help help.topics help.crossref help.home kernel models
   4 compiler.units assocs words vocabs accessors fry arrays
   5 combinators.short-circuit namespaces sequences models help.apropos
   6 combinators ui ui.commands ui.gadgets ui.gadgets.panes
   7 ui.gadgets.scrollers ui.gadgets.tracks ui.gestures ui.gadgets.buttons
   8 ui.gadgets.packs ui.gadgets.editors ui.gadgets.labels
   9 ui.gadgets.status-bar ui.gadgets.glass ui.gadgets.borders ui.gadgets.viewports
  10 ui.tools.common ui.tools.browser.popups ui.tools.browser.history ;
  11 IN: ui.tools.browser
  12
  13 TUPLE: browser-gadget < tool history pane scroller search-field popup ;
  14
  15 { 650 400 } browser-gadget set-tool-dim
  16
  17 M: browser-gadget history-value
  18     [ control-value ] [ scroller>> scroll-position ]
  19     bi 2array ;
  20
  21 M: browser-gadget set-history-value
  22     [ first2 ] dip
  23     [ set-control-value ] [ scroller>> set-scroll-position ]
  24     bi-curry bi* ;
  25
  26 : show-help ( link browser-gadget -- )
  27     [ >link ] dip
  28     [ [ add-recent ] [ history>> add-history ] bi* ]
  29     [ model>> set-model ]
  30     2bi ;
  31
  32 : <help-pane> ( browser-gadget -- gadget )
  33     model>> [ '[ _ print-topic ] try ] <pane-control> ;
  34
  35 : search-browser ( string browser -- )
  36     '[ <apropos> _ show-help ] unless-empty ;
  37
  38 : <search-field> ( browser -- field )
  39     '[ _ search-browser ] <action-field>
  40         10 >>min-cols
  41         10 >>max-cols ;
  42
  43 : <browser-toolbar> ( browser -- toolbar )
  44     horizontal <track>
  45         0 >>fill
  46         1/2 >>align
  47         { 5 5 } >>gap
  48         over <toolbar> f track-add
  49         swap search-field>> "Search:" label-on-left 1 track-add ;
  50
  51 : <browser-gadget> ( link -- gadget )
  52     vertical browser-gadget new-track
  53         1 >>fill
  54         swap >link <model> >>model
  55         dup <history> >>history
  56         dup <search-field> >>search-field
  57         dup <browser-toolbar> { 3 3 } <border> { 1 0 } >>fill f track-add
  58         dup <help-pane> >>pane
  59         dup pane>> <scroller> >>scroller
  60         dup scroller>> 1 track-add ;
  61
  62 M: browser-gadget graft*
  63     [ add-definition-observer ] [ call-next-method ] bi ;
  64
  65 M: browser-gadget ungraft*
  66     [ call-next-method ] [ remove-definition-observer ] bi ;
  67
  68 M: browser-gadget handle-gesture
  69     {
  70         { [ over key-gesture? not ] [ call-next-method ] }
  71         { [ dup popup>> ] [ { [ pass-to-popup ] [ call-next-method ] } 2&& ] }
  72         [ call-next-method ]
  73     } cond ;
  74
  75 : showing-definition? ( defspec assoc -- ? )
  76     {
  77         [ key? ]
  78         [ [ dup word-link? [ name>> ] when ] dip key? ]
  79         [ [ dup vocab-link? [ vocab ] when ] dip key? ]
  80     } 2|| ;
  81
  82 M: browser-gadget definitions-changed ( assoc browser -- )
  83     model>> [ value>> swap showing-definition? ] keep
  84     '[ _ notify-connections ] when ;
  85
  86 M: browser-gadget focusable-child* search-field>> ;
  87
  88 : (browser-window) ( topic -- )
  89     <browser-gadget> "Browser" open-status-window ;
  90
  91 : browser-window ( -- )
  92     "help.home" (browser-window) ;
  93
  94 : error-help-window ( error -- )
  95     [ error-help ]
  96     [ dup tuple? [ class ] [ drop "errors" ] if ] bi or (browser-window) ;
  97
  98 \ browser-window H{ { +nullary+ t } } define-command
  99
 100 : com-browse ( link -- )
 101     [ browser-gadget? ] find-window
 102     [ [ raise-window ] [ gadget-child show-help ] bi ]
 103     [ (browser-window) ] if* ;
 104
 105 : show-browser ( -- )
 106     [ browser-gadget? ] find-window
 107     [ [ raise-window ] [ request-focus ] bi ] [ browser-window ] if* ;
 108
 109 \ show-browser H{ { +nullary+ t } } define-command
 110
 111 : com-back ( browser -- ) history>> go-back ;
 112
 113 : com-forward ( browser -- ) history>> go-forward ;
 114
 115 : com-home ( browser -- ) "help.home" swap show-help ;
 116
 117 : browser-help ( -- ) "ui-browser" com-browse ;
 118
 119 \ browser-help H{ { +nullary+ t } } define-command
 120
 121 browser-gadget "toolbar" f {
 122     { T{ key-down f { A+ } "LEFT" } com-back }
 123     { T{ key-down f { A+ } "RIGHT" } com-forward }
 124     { T{ key-down f { A+ } "H" } com-home }
 125     { T{ key-down f f "F1" } browser-help }
 126 } define-command-map
 127
 128 : ?show-help ( link browser -- )
 129     over [ show-help ] [ 2drop ] if ;
 130
 131 : navigate ( browser quot -- )
 132     '[ control-value @ ] keep ?show-help ; inline
 133
 134 : com-up ( browser -- ) [ article-parent ] navigate ;
 135
 136 : com-prev ( browser -- ) [ prev-article ] navigate ;
 137
 138 : com-next ( browser -- ) [ next-article ] navigate ;
 139
 140 browser-gadget "navigation" "Commands for navigating in the article hierarchy" {
 141     { T{ key-down f { A+ } "u" } com-up }
 142     { T{ key-down f { A+ } "p" } com-prev }
 143     { T{ key-down f { A+ } "n" } com-next }
 144     { T{ key-down f { A+ } "k" } com-show-outgoing-links }
 145     { T{ key-down f { A+ } "K" } com-show-incoming-links }
 146 } define-command-map
 147
 148 browser-gadget "multi-touch" f {
 149     { left-action com-back }
 150     { right-action com-forward }
 151 } define-command-map
 152
 153 browser-gadget "scrolling"
 154 "The browser's scroller can be scrolled from the keyboard."
 155 {
 156     { T{ key-down f f "UP" } com-scroll-up }
 157     { T{ key-down f f "DOWN" } com-scroll-down }
 158     { T{ key-down f f "PAGE_UP" } com-page-up }
 159     { T{ key-down f f "PAGE_DOWN" } com-page-down }
 160 } define-command-map
 161
 162 MAIN: browser-window