basis/ui/tools/browser/browser.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: debugger classes help help.topics help.crossref help.home
   4 kernel models compiler.units assocs words vocabs accessors fry arrays
   5 combinators.short-circuit namespaces sequences help.apropos
   6 combinators ui ui.commands ui.gadgets ui.gadgets.panes
   7 ui.gadgets.scrollers ui.gadgets.tracks ui.gestures ui.gadgets.buttons
   8 ui.gadgets.packs ui.gadgets.editors ui.gadgets.labels
   9 ui.gadgets.status-bar ui.gadgets.glass ui.gadgets.borders
  10 ui.gadgets.viewports ui.tools.common ui.tools.browser.popups
  11 ui.tools.browser.history ;
  12 IN: ui.tools.browser
  13
  14 TUPLE: browser-gadget < tool history scroller search-field popup ;
  15
  16 { 650 400 } browser-gadget set-tool-dim
  17
  18 M: browser-gadget history-value
  19     [ control-value ] [ scroller>> scroll-position ]
  20     bi 2array ;
  21
  22 M: browser-gadget set-history-value
  23     [ first2 ] dip
  24     [ set-control-value ] [ scroller>> set-scroll-position ]
  25     bi-curry bi* ;
  26
  27 : show-help ( link browser-gadget -- )
  28     [ >link ] dip
  29     [
  30         2dup model>> value>> =
  31         [ 2drop ] [ [ add-recent ] [ history>> add-history ] bi* ] if
  32     ]
  33     [ model>> set-model ]
  34     2bi ;
  35
  36 : <help-pane> ( browser-gadget -- gadget )
  37     model>> [ '[ _ print-topic ] try ] <pane-control> ;
  38
  39 : search-browser ( string browser -- )
  40     '[ <apropos> _ show-help ] unless-empty ;
  41
  42 : <search-field> ( browser -- field )
  43     '[ _ search-browser ] <action-field>
  44         10 >>min-cols
  45         10 >>max-cols ;
  46
  47 : <browser-toolbar> ( browser -- toolbar )
  48     horizontal <track>
  49         0 >>fill
  50         1/2 >>align
  51         { 5 5 } >>gap
  52         over <toolbar> f track-add
  53         swap search-field>> "Search:" label-on-left 1 track-add ;
  54
  55 : <browser-gadget> ( link -- gadget )
  56     vertical browser-gadget new-track
  57         1 >>fill
  58         swap >link <model> >>model
  59         dup <history> >>history
  60         dup <search-field> >>search-field
  61         dup <browser-toolbar> { 3 3 } <border> { 1 0 } >>fill f track-add
  62         dup dup <help-pane> { 10 0 } <border> { 1 1 } >>fill
  63         <scroller> >>scroller scroller>> 1 track-add ;
  64
  65 M: browser-gadget graft*
  66     [ add-definition-observer ] [ call-next-method ] bi ;
  67
  68 M: browser-gadget ungraft*
  69     [ call-next-method ] [ remove-definition-observer ] bi ;
  70
  71 M: browser-gadget handle-gesture
  72     {
  73         { [ over key-gesture? not ] [ call-next-method ] }
  74         { [ dup popup>> ] [ { [ pass-to-popup ] [ call-next-method ] } 2&& ] }
  75         [ call-next-method ]
  76     } cond ;
  77
  78 : showing-definition? ( defspec assoc -- ? )
  79     {
  80         [ key? ]
  81         [ [ dup word-link? [ name>> ] when ] dip key? ]
  82         [ [ dup vocab-link? [ vocab ] when ] dip key? ]
  83     } 2|| ;
  84
  85 M: browser-gadget definitions-changed ( assoc browser -- )
  86     model>> [ value>> swap showing-definition? ] keep
  87     '[ _ notify-connections ] when ;
  88
  89 M: browser-gadget focusable-child* search-field>> ;
  90
  91 : (browser-window) ( topic -- )
  92     <browser-gadget> "Browser" open-status-window ;
  93
  94 : browser-window ( -- )
  95     "help.home" (browser-window) ;
  96
  97 : error-help-window ( error -- )
  98     [ error-help ]
  99     [ dup tuple? [ class ] [ drop "errors" ] if ] bi or (browser-window) ;
 100
 101 \ browser-window H{ { +nullary+ t } } define-command
 102
 103 : com-browse ( link -- )
 104     [ browser-gadget? ] find-window
 105     [ [ raise-window ] [ gadget-child show-help ] bi ]
 106     [ (browser-window) ] if* ;
 107
 108 : show-browser ( -- )
 109     [ browser-gadget? ] find-window
 110     [ [ raise-window ] [ request-focus ] bi ] [ browser-window ] if* ;
 111
 112 \ show-browser H{ { +nullary+ t } } define-command
 113
 114 : com-back ( browser -- ) history>> go-back ;
 115
 116 : com-forward ( browser -- ) history>> go-forward ;
 117
 118 : com-home ( browser -- ) "help.home" swap show-help ;
 119
 120 : browser-help ( -- ) "ui-browser" com-browse ;
 121
 122 \ browser-help H{ { +nullary+ t } } define-command
 123
 124 browser-gadget "toolbar" f {
 125     { T{ key-down f { A+ } "LEFT" } com-back }
 126     { T{ key-down f { A+ } "RIGHT" } com-forward }
 127     { T{ key-down f { A+ } "H" } com-home }
 128     { T{ key-down f f "F1" } browser-help }
 129 } define-command-map
 130
 131 : ?show-help ( link browser -- )
 132     over [ show-help ] [ 2drop ] if ;
 133
 134 : navigate ( browser quot -- )
 135     '[ control-value @ ] keep ?show-help ; inline
 136
 137 : com-up ( browser -- ) [ article-parent ] navigate ;
 138
 139 : com-prev ( browser -- ) [ prev-article ] navigate ;
 140
 141 : com-next ( browser -- ) [ next-article ] navigate ;
 142
 143 browser-gadget "navigation" "Commands for navigating in the article hierarchy" {
 144     { T{ key-down f { A+ } "u" } com-up }
 145     { T{ key-down f { A+ } "p" } com-prev }
 146     { T{ key-down f { A+ } "n" } com-next }
 147     { T{ key-down f { A+ } "k" } com-show-outgoing-links }
 148     { T{ key-down f { A+ } "K" } com-show-incoming-links }
 149 } define-command-map
 150
 151 browser-gadget "multi-touch" f {
 152     { left-action com-back }
 153     { right-action com-forward }
 154 } define-command-map
 155
 156 browser-gadget "scrolling"
 157 "The browser's scroller can be scrolled from the keyboard."
 158 {
 159     { T{ key-down f f "UP" } com-scroll-up }
 160     { T{ key-down f f "DOWN" } com-scroll-down }
 161     { T{ key-down f f "PAGE_UP" } com-page-up }
 162     { T{ key-down f f "PAGE_DOWN" } com-page-down }
 163 } define-command-map
 164
 165 MAIN: browser-window