basis/ui/tools/browser/browser.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs classes combinators
   4 combinators.short-circuit compiler.units debugger fry help
   5 help.apropos help.crossref help.home help.topics help.stylesheet
   6 kernel models sequences sets ui ui.commands ui.gadgets
   7 ui.gadgets.borders ui.gadgets.buttons ui.gadgets.editors
   8 ui.gadgets.glass ui.gadgets.labels ui.gadgets.panes
   9 ui.gadgets.scrollers ui.gadgets.status-bar ui.gadgets.tracks
  10 ui.gadgets.viewports ui.gestures ui.tools.browser.history
  11 ui.tools.browser.popups ui.tools.common vocabs ui.gadgets.worlds ;
  12 IN: ui.tools.browser
  13
  14 TUPLE: browser-gadget < tool history scroller search-field popup ;
  15
  16 { 650 700 } browser-gadget set-tool-dim
  17
  18 M: browser-gadget history-value
  19     [ control-value ] [ scroller>> scroll-position ]
  20     bi 2array ;
  21
  22 M: browser-gadget set-history-value
  23     [ first2 ] dip
  24     [ set-control-value ] [ scroller>> set-scroll-position ]
  25     bi-curry bi* ;
  26
  27 : show-help ( link browser-gadget -- )
  28     [ >link ] dip
  29     [
  30         2dup model>> value>> =
  31         [ 2drop ] [ [ add-recent ] [ history>> add-history ] bi* ] if
  32     ]
  33     [ model>> set-model ]
  34     2bi ;
  35
  36 : <help-pane> ( browser-gadget -- gadget )
  37     model>> [ '[ _ print-topic ] try ] <pane-control> ;
  38
  39 : search-browser ( string browser -- )
  40     '[ <apropos-search> _ show-help ] unless-empty ;
  41
  42 : <search-field> ( browser -- field )
  43     '[ _ search-browser ] <action-field>
  44         10 >>min-cols
  45         10 >>max-cols ;
  46
  47 : <browser-toolbar> ( browser -- toolbar )
  48     horizontal <track>
  49         0 >>fill
  50         1/2 >>align
  51         { 5 5 } >>gap
  52         over <toolbar> f track-add
  53         swap search-field>> "Search:" label-on-left 1 track-add ;
  54
  55 : <browser-gadget> ( link -- gadget )
  56     vertical browser-gadget new-track
  57         1 >>fill
  58         swap >link <model> >>model
  59         dup <history> >>history
  60         dup <search-field> >>search-field
  61         dup <browser-toolbar> { 3 3 } <border> { 1 0 } >>fill f track-add
  62         dup dup <help-pane> { 10 0 } <border> { 1 1 } >>fill
  63         <scroller> >>scroller scroller>> 1 track-add ;
  64
  65 M: browser-gadget graft*
  66     [ add-definition-observer ] [ call-next-method ] bi ;
  67
  68 M: browser-gadget ungraft*
  69     [ call-next-method ] [ remove-definition-observer ] bi ;
  70
  71 M: browser-gadget handle-gesture
  72     {
  73         { [ over key-gesture? not ] [ call-next-method ] }
  74         { [ dup popup>> ] [ { [ pass-to-popup ] [ call-next-method ] } 2&& ] }
  75         [ call-next-method ]
  76     } cond ;
  77
  78 : showing-definition? ( defspec set -- ? )
  79     {
  80         [ in? ]
  81         [ [ dup word-link? [ name>> ] when ] dip in? ]
  82         [ [ dup vocab-link? [ lookup-vocab ] when ] dip in? ]
  83     } 2|| ;
  84
  85 M: browser-gadget definitions-changed ( set browser -- )
  86     [ model>> value>> swap showing-definition? ] keep
  87     '[ _ [ history-value ] keep set-history-value ] when ;
  88
  89 M: browser-gadget focusable-child* search-field>> ;
  90
  91 : (browser-window) ( topic -- )
  92     <browser-gadget>
  93     <world-attributes>
  94         "Browser" >>title
  95         [ { dialog-window } append ] change-window-controls
  96     open-status-window ;
  97
  98 : browser-window ( -- )
  99     "help.home" (browser-window) ;
 100
 101 : error-help-window ( error -- )
 102     {
 103         [ error-help ]
 104         [ dup tuple? [ class-of ] [ drop "errors" ] if ]
 105     } 1|| (browser-window) ;
 106
 107 \ browser-window H{ { +nullary+ t } } define-command
 108
 109 : com-browse ( link -- )
 110     [ browser-gadget? ] find-window
 111     [ [ raise-window ] [ gadget-child show-help ] bi ]
 112     [ (browser-window) ] if* ;
 113
 114 : show-browser ( -- )
 115     [ browser-gadget? ] find-window
 116     [ [ raise-window ] [ request-focus ] bi ] [ browser-window ] if* ;
 117
 118 \ show-browser H{ { +nullary+ t } } define-command
 119
 120 : com-back ( browser -- ) history>> go-back ;
 121
 122 : com-forward ( browser -- ) history>> go-forward ;
 123
 124 : com-home ( browser -- ) "help.home" swap show-help ;
 125
 126 : browser-help ( -- ) "ui-browser" com-browse ;
 127
 128 : glossary ( -- ) "conventions" com-browse ;
 129
 130 \ browser-help H{ { +nullary+ t } } define-command
 131 \ glossary H{ { +nullary+ t } } define-command
 132
 133 browser-gadget "toolbar" f {
 134     { T{ key-down f { A+ } "LEFT" } com-back }
 135     { T{ key-down f { A+ } "RIGHT" } com-forward }
 136     { T{ key-down f { A+ } "H" } com-home }
 137     { T{ key-down f f "F1" } browser-help }
 138     { T{ key-down f { A+ } "F1" } glossary }
 139 } define-command-map
 140
 141 : ?show-help ( link browser -- )
 142     over [ show-help ] [ 2drop ] if ;
 143
 144 : navigate ( browser quot -- )
 145     '[ control-value @ ] keep ?show-help ; inline
 146
 147 : com-up ( browser -- ) [ article-parent ] navigate ;
 148
 149 : com-prev ( browser -- ) [ prev-article ] navigate ;
 150
 151 : com-next ( browser -- ) [ next-article ] navigate ;
 152
 153 browser-gadget "navigation" "Commands for navigating in the article hierarchy" {
 154     { T{ key-down f { A+ } "u" } com-up }
 155     { T{ key-down f { A+ } "p" } com-prev }
 156     { T{ key-down f { A+ } "n" } com-next }
 157     { T{ key-down f { A+ } "k" } com-show-outgoing-links }
 158     { T{ key-down f { A+ } "K" } com-show-incoming-links }
 159 } define-command-map
 160
 161 browser-gadget "multi-touch" f {
 162     { left-action com-back }
 163     { right-action com-forward }
 164 } define-command-map
 165
 166 browser-gadget "scrolling"
 167 "The browser's scroller can be scrolled from the keyboard."
 168 {
 169     { T{ key-down f f "UP" } com-scroll-up }
 170     { T{ key-down f f "DOWN" } com-scroll-down }
 171     { T{ key-down f f "PAGE_UP" } com-page-up }
 172     { T{ key-down f f "PAGE_DOWN" } com-page-down }
 173 } define-command-map
 174
 175 : com-font-size-plus ( browser -- )
 176     2 adjust-help-font-size model>> notify-connections ;
 177
 178 : com-font-size-minus ( browser -- )
 179     -2 adjust-help-font-size model>> notify-connections ;
 180
 181 browser-gadget "fonts" f {
 182     { T{ key-down f { A+ } "+" } com-font-size-plus }
 183     { T{ key-down f { A+ } "=" } com-font-size-plus }
 184     { T{ key-down f { A+ } "_" } com-font-size-minus }
 185     { T{ key-down f { A+ } "-" } com-font-size-minus }
 186 } define-command-map
 187
 188 MAIN: browser-window