basis/ui/tools/browser/browser.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs classes colors.constants
   4 combinators combinators.short-circuit compiler.units debugger
   5 documents fry help help.apropos help.crossref help.home
   6 help.markup help.stylesheet help.topics io.styles kernel locals
   7 make models namespaces sequences sets ui ui.commands ui.gadgets
   8 ui.gadgets.borders ui.gadgets.editors ui.gadgets.editors.private
   9 ui.gadgets.glass ui.gadgets.labels ui.gadgets.labels.private
  10 ui.gadgets.panes ui.gadgets.scrollers ui.gadgets.status-bar
  11 ui.gadgets.theme ui.gadgets.toolbar ui.gadgets.tracks
  12 ui.gadgets.viewports ui.gadgets.worlds ui.gestures ui.pens.solid
  13 ui.render ui.text ui.tools.browser.history
  14 ui.tools.browser.popups ui.tools.common vocabs ;
  15 IN: ui.tools.browser
  16
  17 TUPLE: browser-gadget < tool history scroller search-field popup ;
  18
  19 { 650 700 } browser-gadget set-tool-dim
  20
  21 M: browser-gadget history-value
  22     [ control-value ] [ scroller>> scroll-position ]
  23     bi 2array ;
  24
  25 M: browser-gadget set-history-value
  26     [ first2 ] dip
  27     [ set-control-value ] [ scroller>> set-scroll-position ]
  28     bi-curry bi* ;
  29
  30 : show-help ( link browser-gadget -- )
  31     [ >link ] dip
  32     [
  33         2dup control-value =
  34         [ 2drop ] [ [ add-recent ] [ history>> add-history ] bi* ] if
  35     ]
  36     [ set-control-value ]
  37     2bi ;
  38
  39 CONSTANT: prev -1
  40 CONSTANT: next 1
  41
  42 : add-navigation-arrow ( str direction -- str )
  43     prev = [ "<" prefix ] [ ">" suffix ] if ;
  44
  45 : $navigation-arrow ( content element direction -- )
  46     [ prefix 1array ] dip add-navigation-arrow , ;
  47
  48 :: ($navigation) ( topic direction -- )
  49     help-path-style get [
  50         topic [
  51             direction prev/next-article
  52             [ 1array \ $long-link direction $navigation-arrow ] when*
  53         ] { } make [ ($navigation-table) ] unless-empty
  54     ] with-style ;
  55
  56 : $navigation ( topic direction -- )
  57     title-style get [ ($navigation) ] with-style ;
  58
  59 : $title ( topic -- )
  60     title-style get clone page-color over delete-at dup
  61     [
  62         [
  63             [ ($title) ]
  64             [ ($navigation-path) ] bi
  65         ] with-nesting
  66     ] with-style ;
  67
  68 : <help-header> ( browser-gadget -- gadget )
  69     model>> [ '[ _ $title ] try ] <pane-control> ;
  70
  71 : add-help-header ( track -- track )
  72     dup <help-header> { 3 3 } <border>
  73     help-header-background <solid> >>interior
  74     { 1 0 } >>fill f track-add ;
  75
  76 : <help-footer> ( browser-gadget direction -- gadget )
  77     [ model>> ] dip '[ [ _ $navigation ] try ] <pane-control>
  78     { 0 0 } <border> { 1/2 1/2 } >>align
  79     toolbar-background <solid> >>interior ;
  80
  81 : add-help-footer ( track -- track )
  82     horizontal <track> with-lines
  83     dupd swap prev <help-footer> 1 track-add
  84     dupd swap next <help-footer> 1 track-add
  85     f track-add ;
  86
  87 : print-topic ( topic -- )
  88     >link
  89     last-element off
  90     article-content print-content ;
  91
  92 : <help-pane> ( browser-gadget -- gadget )
  93     model>> [ '[ _ print-topic ] try ] <pane-control> ;
  94
  95 : add-help-pane ( track -- track )
  96     dup dup <help-pane> margins
  97     <scroller> >>scroller scroller>> white-interior 1 track-add ;
  98
  99 : search-browser ( string browser -- )
 100     '[ <apropos-search> _ show-help ] unless-empty ;
 101
 102 : <search-field> ( browser -- field )
 103     '[ _ search-browser ] <action-field>
 104         dup editor>> "Search" >>default-text drop
 105         10 >>min-cols
 106         10 >>max-cols
 107         white-interior ;
 108
 109 : <browser-toolbar> ( browser -- toolbar )
 110     [ <toolbar> ] [
 111         search-field>> horizontal <track>
 112             0 >>fill swap 1 track-add
 113         1 track-add
 114     ] bi ;
 115
 116 : add-browser-toolbar ( track -- track )
 117     dup <browser-toolbar> format-toolbar f track-add ;
 118
 119 : <browser-gadget> ( link -- gadget )
 120     vertical browser-gadget new-track with-lines
 121         1 >>fill
 122         swap >link <model> >>model
 123         dup <history> >>history
 124         dup <search-field> >>search-field
 125         add-browser-toolbar
 126         add-help-header
 127         add-help-pane
 128         add-help-footer ;
 129
 130 M: browser-gadget graft*
 131     [ add-definition-observer ] [ call-next-method ] bi ;
 132
 133 M: browser-gadget ungraft*
 134     [ call-next-method ] [ remove-definition-observer ] bi ;
 135
 136 M: browser-gadget handle-gesture
 137     {
 138         { [ over key-gesture? not ] [ call-next-method ] }
 139         { [ dup popup>> ] [ { [ pass-to-popup ] [ call-next-method ] } 2&& ] }
 140         [ call-next-method ]
 141     } cond ;
 142
 143 : showing-definition? ( defspec set -- ? )
 144     {
 145         [ in? ]
 146         [ [ dup word-link? [ name>> ] when ] dip in? ]
 147         [ [ dup vocab-link? [ lookup-vocab ] when ] dip in? ]
 148     } 2|| ;
 149
 150 M: browser-gadget definitions-changed ( set browser -- )
 151     [ control-value swap showing-definition? ] keep
 152     '[ _ [ history-value ] keep set-history-value ] when ;
 153
 154 M: browser-gadget focusable-child* search-field>> ;
 155
 156 : (browser-window) ( topic -- )
 157     <browser-gadget>
 158     <world-attributes>
 159         "Browser" >>title
 160     open-status-window ;
 161
 162 : browser-window ( -- )
 163     "help.home" (browser-window) ;
 164
 165 : error-help-window ( error -- )
 166     {
 167         [ error-help ]
 168         [ dup tuple? [ class-of ] [ drop "errors" ] if ]
 169     } 1|| (browser-window) ;
 170
 171 \ browser-window H{ { +nullary+ t } } define-command
 172
 173 : com-browse ( link -- )
 174     [ browser-gadget? ] find-window
 175     [ [ raise-window ] [ gadget-child show-help ] bi ]
 176     [ (browser-window) ] if* ;
 177
 178 : show-browser ( -- )
 179     [ browser-gadget? ] find-window
 180     [ [ raise-window ] [ request-focus ] bi ] [ browser-window ] if* ;
 181
 182 \ show-browser H{ { +nullary+ t } } define-command
 183
 184 : com-back ( browser -- ) history>> go-back ;
 185
 186 : com-forward ( browser -- ) history>> go-forward ;
 187
 188 : com-home ( browser -- ) "help.home" swap show-help ;
 189
 190 : browser-help ( -- ) "ui-browser" com-browse ;
 191
 192 : glossary ( -- ) "conventions" com-browse ;
 193
 194 \ browser-help H{ { +nullary+ t } } define-command
 195 \ glossary H{ { +nullary+ t } } define-command
 196
 197 browser-gadget "toolbar" f {
 198     { T{ key-down f { A+ } "LEFT" } com-back }
 199     { T{ key-down f { A+ } "RIGHT" } com-forward }
 200     { T{ key-down f { A+ } "H" } com-home }
 201     { T{ key-down f f "F1" } browser-help }
 202     { T{ key-down f { A+ } "F1" } glossary }
 203 } define-command-map
 204
 205 : ?show-help ( link browser -- )
 206     over [ show-help ] [ 2drop ] if ;
 207
 208 : navigate ( browser quot -- )
 209     '[ control-value @ ] keep ?show-help ; inline
 210
 211 : com-up ( browser -- ) [ article-parent ] navigate ;
 212
 213 : com-prev ( browser -- ) [ prev-article ] navigate ;
 214
 215 : com-next ( browser -- ) [ next-article ] navigate ;
 216
 217 browser-gadget "navigation" "Commands for navigating in the article hierarchy" {
 218     { T{ key-down f { A+ } "u" } com-up }
 219     { T{ key-down f { A+ } "p" } com-prev }
 220     { T{ key-down f { A+ } "n" } com-next }
 221     { T{ key-down f { A+ } "k" } com-show-outgoing-links }
 222     { T{ key-down f { A+ } "K" } com-show-incoming-links }
 223 } define-command-map
 224
 225 browser-gadget "multi-touch" f {
 226     { left-action com-back }
 227     { right-action com-forward }
 228 } define-command-map
 229
 230 browser-gadget "scrolling"
 231 "The browser's scroller can be scrolled from the keyboard."
 232 {
 233     { T{ key-down f f "UP" } com-scroll-up }
 234     { T{ key-down f f "DOWN" } com-scroll-down }
 235     { T{ key-down f f "PAGE_UP" } com-page-up }
 236     { T{ key-down f f "PAGE_DOWN" } com-page-down }
 237 } define-command-map
 238
 239 : com-font-size-plus ( browser -- )
 240     2 adjust-help-font-size model>> notify-connections ;
 241
 242 : com-font-size-minus ( browser -- )
 243     -2 adjust-help-font-size model>> notify-connections ;
 244
 245 browser-gadget "fonts" f {
 246     { T{ key-down f { A+ } "+" } com-font-size-plus }
 247     { T{ key-down f { A+ } "=" } com-font-size-plus }
 248     { T{ key-down f { A+ } "_" } com-font-size-minus }
 249     { T{ key-down f { A+ } "-" } com-font-size-minus }
 250 } define-command-map
 251
 252 MAIN: browser-window