basis/ui/tools/browser/browser.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays classes colors colors.constants combinators
   4 combinators.short-circuit compiler.units debugger fry help
   5 help.apropos help.crossref help.home help.stylesheet help.topics
   6 kernel models sequences sets ui ui.commands ui.gadgets
   7 ui.gadgets.borders ui.gadgets.buttons ui.gadgets.colors ui.gadgets.editors
   8 ui.gadgets.glass ui.gadgets.labels ui.gadgets.lines ui.gadgets.panes
   9 ui.gadgets.scrollers ui.gadgets.status-bar ui.gadgets.tracks ui.gadgets.toolbar
  10 ui.gadgets.viewports ui.gadgets.worlds ui.gestures
  11 ui.tools.browser.history ui.tools.browser.popups ui.tools.common
  12 ui.pens.solid vocabs ;
  13 IN: ui.tools.browser
  14
  15 TUPLE: browser-gadget < tool history scroller search-field popup ;
  16
  17 { 650 700 } browser-gadget set-tool-dim
  18
  19 M: browser-gadget history-value
  20     [ control-value ] [ scroller>> scroll-position ]
  21     bi 2array ;
  22
  23 M: browser-gadget set-history-value
  24     [ first2 ] dip
  25     [ set-control-value ] [ scroller>> set-scroll-position ]
  26     bi-curry bi* ;
  27
  28 : show-help ( link browser-gadget -- )
  29     [ >link ] dip
  30     [
  31         2dup control-value =
  32         [ 2drop ] [ [ add-recent ] [ history>> add-history ] bi* ] if
  33     ]
  34     [ set-control-value ]
  35     2bi ;
  36
  37 : <help-header> ( browser-gadget -- gadget )
  38     model>> [ '[ _ $title ] try ] <pane-control> ;
  39
  40 : add-help-header ( track -- track )
  41     dup <help-header> { 3 3 } <border>
  42     help-header-background <solid> >>interior
  43     { 1 0 } >>fill f track-add ;
  44
  45 : <help-pane> ( browser-gadget -- gadget )
  46     model>> [ '[ _ print-topic ] try ] <pane-control> ;
  47
  48 : add-help-pane ( track -- track )
  49     dup dup <help-pane> margins
  50     <scroller> >>scroller scroller>> white-interior 1 track-add ;
  51
  52 : search-browser ( string browser -- )
  53     '[ <apropos-search> _ show-help ] unless-empty ;
  54
  55 : <search-field> ( browser -- field )
  56     '[ _ search-browser ] <action-field>
  57         10 >>min-cols
  58         10 >>max-cols
  59         white-interior ;
  60
  61 : <browser-toolbar> ( browser -- toolbar )
  62     horizontal <track>
  63         0 >>fill
  64         1/2 >>align
  65         { 5 5 } >>gap
  66         over <toolbar> f track-add
  67         swap search-field>> "          Search" label-on-left 1 track-add ;
  68
  69 : add-browser-toolbar ( track -- track )
  70     dup <browser-toolbar> format-toolbar f track-add ;
  71
  72 : <browser-gadget> ( link -- gadget )
  73     vertical browser-gadget new-track with-lines
  74         1 >>fill
  75         swap >link <model> >>model
  76         dup <history> >>history
  77         dup <search-field> >>search-field
  78         add-browser-toolbar
  79         add-help-header
  80         add-help-pane ;
  81
  82 M: browser-gadget graft*
  83     [ add-definition-observer ] [ call-next-method ] bi ;
  84
  85 M: browser-gadget ungraft*
  86     [ call-next-method ] [ remove-definition-observer ] bi ;
  87
  88 M: browser-gadget handle-gesture
  89     {
  90         { [ over key-gesture? not ] [ call-next-method ] }
  91         { [ dup popup>> ] [ { [ pass-to-popup ] [ call-next-method ] } 2&& ] }
  92         [ call-next-method ]
  93     } cond ;
  94
  95 : showing-definition? ( defspec set -- ? )
  96     {
  97         [ in? ]
  98         [ [ dup word-link? [ name>> ] when ] dip in? ]
  99         [ [ dup vocab-link? [ lookup-vocab ] when ] dip in? ]
 100     } 2|| ;
 101
 102 M: browser-gadget definitions-changed ( set browser -- )
 103     [ control-value swap showing-definition? ] keep
 104     '[ _ [ history-value ] keep set-history-value ] when ;
 105
 106 M: browser-gadget focusable-child* search-field>> ;
 107
 108 : (browser-window) ( topic -- )
 109     <browser-gadget>
 110     <world-attributes>
 111         "Browser" >>title
 112     open-status-window ;
 113
 114 : browser-window ( -- )
 115     "help.home" (browser-window) ;
 116
 117 : error-help-window ( error -- )
 118     {
 119         [ error-help ]
 120         [ dup tuple? [ class-of ] [ drop "errors" ] if ]
 121     } 1|| (browser-window) ;
 122
 123 \ browser-window H{ { +nullary+ t } } define-command
 124
 125 : com-browse ( link -- )
 126     [ browser-gadget? ] find-window
 127     [ [ raise-window ] [ gadget-child show-help ] bi ]
 128     [ (browser-window) ] if* ;
 129
 130 : show-browser ( -- )
 131     [ browser-gadget? ] find-window
 132     [ [ raise-window ] [ request-focus ] bi ] [ browser-window ] if* ;
 133
 134 \ show-browser H{ { +nullary+ t } } define-command
 135
 136 : com-back ( browser -- ) history>> go-back ;
 137
 138 : com-forward ( browser -- ) history>> go-forward ;
 139
 140 : com-home ( browser -- ) "help.home" swap show-help ;
 141
 142 : browser-help ( -- ) "ui-browser" com-browse ;
 143
 144 : glossary ( -- ) "conventions" com-browse ;
 145
 146 \ browser-help H{ { +nullary+ t } } define-command
 147 \ glossary H{ { +nullary+ t } } define-command
 148
 149 browser-gadget "toolbar" f {
 150     { T{ key-down f { A+ } "LEFT" } com-back }
 151     { T{ key-down f { A+ } "RIGHT" } com-forward }
 152     { T{ key-down f { A+ } "H" } com-home }
 153     { T{ key-down f f "F1" } browser-help }
 154     { T{ key-down f { A+ } "F1" } glossary }
 155 } define-command-map
 156
 157 : ?show-help ( link browser -- )
 158     over [ show-help ] [ 2drop ] if ;
 159
 160 : navigate ( browser quot -- )
 161     '[ control-value @ ] keep ?show-help ; inline
 162
 163 : com-up ( browser -- ) [ article-parent ] navigate ;
 164
 165 : com-prev ( browser -- ) [ prev-article ] navigate ;
 166
 167 : com-next ( browser -- ) [ next-article ] navigate ;
 168
 169 browser-gadget "navigation" "Commands for navigating in the article hierarchy" {
 170     { T{ key-down f { A+ } "u" } com-up }
 171     { T{ key-down f { A+ } "p" } com-prev }
 172     { T{ key-down f { A+ } "n" } com-next }
 173     { T{ key-down f { A+ } "k" } com-show-outgoing-links }
 174     { T{ key-down f { A+ } "K" } com-show-incoming-links }
 175 } define-command-map
 176
 177 browser-gadget "multi-touch" f {
 178     { left-action com-back }
 179     { right-action com-forward }
 180 } define-command-map
 181
 182 browser-gadget "scrolling"
 183 "The browser's scroller can be scrolled from the keyboard."
 184 {
 185     { T{ key-down f f "UP" } com-scroll-up }
 186     { T{ key-down f f "DOWN" } com-scroll-down }
 187     { T{ key-down f f "PAGE_UP" } com-page-up }
 188     { T{ key-down f f "PAGE_DOWN" } com-page-down }
 189 } define-command-map
 190
 191 : com-font-size-plus ( browser -- )
 192     2 adjust-help-font-size model>> notify-connections ;
 193
 194 : com-font-size-minus ( browser -- )
 195     -2 adjust-help-font-size model>> notify-connections ;
 196
 197 browser-gadget "fonts" f {
 198     { T{ key-down f { A+ } "+" } com-font-size-plus }
 199     { T{ key-down f { A+ } "=" } com-font-size-plus }
 200     { T{ key-down f { A+ } "_" } com-font-size-minus }
 201     { T{ key-down f { A+ } "-" } com-font-size-minus }
 202 } define-command-map
 203
 204 MAIN: browser-window