basis/ui/tools/browser/browser.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays classes colors colors.constants combinators
   4 combinators.short-circuit compiler.units debugger fry help
   5 help.apropos help.crossref help.home help.stylesheet help.topics
   6 kernel models sequences sets ui ui.commands ui.gadgets
   7 ui.gadgets.borders ui.gadgets.buttons ui.gadgets.colors ui.gadgets.editors
   8 ui.gadgets.glass ui.gadgets.labels ui.gadgets.panes
   9 ui.gadgets.scrollers ui.gadgets.status-bar ui.gadgets.tracks ui.gadgets.toolbar
  10 ui.gadgets.packs ui.gadgets.viewports ui.gadgets.worlds ui.gestures
  11 ui.tools.browser.history ui.tools.browser.popups ui.tools.common
  12 ui.pens.solid vocabs ;
  13 IN: ui.tools.browser
  14
  15 TUPLE: browser-gadget < tool history scroller search-field popup ;
  16
  17 { 650 700 } browser-gadget set-tool-dim
  18
  19 M: browser-gadget history-value
  20     [ control-value ] [ scroller>> scroll-position ]
  21     bi 2array ;
  22
  23 M: browser-gadget set-history-value
  24     [ first2 ] dip
  25     [ set-control-value ] [ scroller>> set-scroll-position ]
  26     bi-curry bi* ;
  27
  28 : show-help ( link browser-gadget -- )
  29     [ >link ] dip
  30     [
  31         2dup control-value =
  32         [ 2drop ] [ [ add-recent ] [ history>> add-history ] bi* ] if
  33     ]
  34     [ set-control-value ]
  35     2bi ;
  36
  37 : <help-header> ( browser-gadget -- gadget )
  38     model>> [ '[ _ $title ] try ] <pane-control> ;
  39
  40 : add-help-header ( track -- track )
  41     dup <help-header> { 3 3 } <border>
  42     help-header-background <solid> >>interior
  43     { 1 0 } >>fill f track-add ;
  44
  45 : <help-footer-prev> ( browser-gadget -- gadget )
  46     model>> [ '[ _ $navigation-prev ] try ] <pane-control>
  47     { 0 0 } <border> { 1/2 1/2 } >>align
  48     toolbar-background <solid> >>interior ;
  49
  50 : <help-footer-next> ( browser-gadget -- gadget )
  51     model>> [ '[ _ $navigation-next ] try ] <pane-control>
  52     { 0 0 } <border> { 1/2 1/2 } >>align
  53     toolbar-background <solid> >>interior ;
  54
  55 : add-help-footer ( track -- track )
  56     horizontal <track> with-lines
  57     dupd swap <help-footer-prev> 1 track-add
  58     dupd swap <help-footer-next> 1 track-add
  59     f track-add ;
  60
  61 : <help-pane> ( browser-gadget -- gadget )
  62     model>> [ '[ _ print-topic ] try ] <pane-control> ;
  63
  64 : add-help-pane ( track -- track )
  65     dup dup <help-pane> margins
  66     <scroller> >>scroller scroller>> white-interior 1 track-add ;
  67
  68 : search-browser ( string browser -- )
  69     '[ <apropos-search> _ show-help ] unless-empty ;
  70
  71 : <search-field> ( browser -- field )
  72     '[ _ search-browser ] <action-field>
  73         10 >>min-cols
  74         10 >>max-cols
  75         white-interior ;
  76
  77 : add-spacer ( track -- track )
  78     <pile> { 10 0 } <border> f track-add ;
  79
  80 : <browser-toolbar> ( browser -- toolbar )
  81     horizontal <track>
  82         0 >>fill
  83         1/2 >>align
  84         { 5 5 } >>gap
  85         over <toolbar> f track-add
  86         add-spacer
  87         swap search-field>> "Search" label-on-left 1 track-add ;
  88
  89 : add-browser-toolbar ( track -- track )
  90     dup <browser-toolbar> format-toolbar f track-add ;
  91
  92 : <browser-gadget> ( link -- gadget )
  93     vertical browser-gadget new-track with-lines
  94         1 >>fill
  95         swap >link <model> >>model
  96         dup <history> >>history
  97         dup <search-field> >>search-field
  98         add-browser-toolbar
  99         add-help-header
 100         add-help-pane
 101         add-help-footer ;
 102
 103 M: browser-gadget graft*
 104     [ add-definition-observer ] [ call-next-method ] bi ;
 105
 106 M: browser-gadget ungraft*
 107     [ call-next-method ] [ remove-definition-observer ] bi ;
 108
 109 M: browser-gadget handle-gesture
 110     {
 111         { [ over key-gesture? not ] [ call-next-method ] }
 112         { [ dup popup>> ] [ { [ pass-to-popup ] [ call-next-method ] } 2&& ] }
 113         [ call-next-method ]
 114     } cond ;
 115
 116 : showing-definition? ( defspec set -- ? )
 117     {
 118         [ in? ]
 119         [ [ dup word-link? [ name>> ] when ] dip in? ]
 120         [ [ dup vocab-link? [ lookup-vocab ] when ] dip in? ]
 121     } 2|| ;
 122
 123 M: browser-gadget definitions-changed ( set browser -- )
 124     [ control-value swap showing-definition? ] keep
 125     '[ _ [ history-value ] keep set-history-value ] when ;
 126
 127 M: browser-gadget focusable-child* search-field>> ;
 128
 129 : (browser-window) ( topic -- )
 130     <browser-gadget>
 131     <world-attributes>
 132         "Browser" >>title
 133     open-status-window ;
 134
 135 : browser-window ( -- )
 136     "help.home" (browser-window) ;
 137
 138 : error-help-window ( error -- )
 139     {
 140         [ error-help ]
 141         [ dup tuple? [ class-of ] [ drop "errors" ] if ]
 142     } 1|| (browser-window) ;
 143
 144 \ browser-window H{ { +nullary+ t } } define-command
 145
 146 : com-browse ( link -- )
 147     [ browser-gadget? ] find-window
 148     [ [ raise-window ] [ gadget-child show-help ] bi ]
 149     [ (browser-window) ] if* ;
 150
 151 : show-browser ( -- )
 152     [ browser-gadget? ] find-window
 153     [ [ raise-window ] [ request-focus ] bi ] [ browser-window ] if* ;
 154
 155 \ show-browser H{ { +nullary+ t } } define-command
 156
 157 : com-back ( browser -- ) history>> go-back ;
 158
 159 : com-forward ( browser -- ) history>> go-forward ;
 160
 161 : com-home ( browser -- ) "help.home" swap show-help ;
 162
 163 : browser-help ( -- ) "ui-browser" com-browse ;
 164
 165 : glossary ( -- ) "conventions" com-browse ;
 166
 167 \ browser-help H{ { +nullary+ t } } define-command
 168 \ glossary H{ { +nullary+ t } } define-command
 169
 170 browser-gadget "toolbar" f {
 171     { T{ key-down f { A+ } "LEFT" } com-back }
 172     { T{ key-down f { A+ } "RIGHT" } com-forward }
 173     { T{ key-down f { A+ } "H" } com-home }
 174     { T{ key-down f f "F1" } browser-help }
 175     { T{ key-down f { A+ } "F1" } glossary }
 176 } define-command-map
 177
 178 : ?show-help ( link browser -- )
 179     over [ show-help ] [ 2drop ] if ;
 180
 181 : navigate ( browser quot -- )
 182     '[ control-value @ ] keep ?show-help ; inline
 183
 184 : com-up ( browser -- ) [ article-parent ] navigate ;
 185
 186 : com-prev ( browser -- ) [ prev-article ] navigate ;
 187
 188 : com-next ( browser -- ) [ next-article ] navigate ;
 189
 190 browser-gadget "navigation" "Commands for navigating in the article hierarchy" {
 191     { T{ key-down f { A+ } "u" } com-up }
 192     { T{ key-down f { A+ } "p" } com-prev }
 193     { T{ key-down f { A+ } "n" } com-next }
 194     { T{ key-down f { A+ } "k" } com-show-outgoing-links }
 195     { T{ key-down f { A+ } "K" } com-show-incoming-links }
 196 } define-command-map
 197
 198 browser-gadget "multi-touch" f {
 199     { left-action com-back }
 200     { right-action com-forward }
 201 } define-command-map
 202
 203 browser-gadget "scrolling"
 204 "The browser's scroller can be scrolled from the keyboard."
 205 {
 206     { T{ key-down f f "UP" } com-scroll-up }
 207     { T{ key-down f f "DOWN" } com-scroll-down }
 208     { T{ key-down f f "PAGE_UP" } com-page-up }
 209     { T{ key-down f f "PAGE_DOWN" } com-page-down }
 210 } define-command-map
 211
 212 : com-font-size-plus ( browser -- )
 213     2 adjust-help-font-size model>> notify-connections ;
 214
 215 : com-font-size-minus ( browser -- )
 216     -2 adjust-help-font-size model>> notify-connections ;
 217
 218 browser-gadget "fonts" f {
 219     { T{ key-down f { A+ } "+" } com-font-size-plus }
 220     { T{ key-down f { A+ } "=" } com-font-size-plus }
 221     { T{ key-down f { A+ } "_" } com-font-size-minus }
 222     { T{ key-down f { A+ } "-" } com-font-size-minus }
 223 } define-command-map
 224
 225 MAIN: browser-window