basis/ui/tools/browser/browser.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays classes combinators
   4 combinators.short-circuit compiler.units debugger fry help
   5 help.apropos help.crossref help.home help.stylesheet help.topics
   6 kernel models sequences sets ui ui.commands ui.gadgets
   7 ui.gadgets.borders ui.gadgets.buttons ui.gadgets.editors
   8 ui.gadgets.glass ui.gadgets.labels ui.gadgets.panes
   9 ui.gadgets.scrollers ui.gadgets.status-bar ui.gadgets.tracks
  10 ui.gadgets.viewports ui.gadgets.worlds ui.gestures
  11 ui.tools.browser.history ui.tools.browser.popups ui.tools.common
  12 vocabs ;
  13 IN: ui.tools.browser
  14
  15 TUPLE: browser-gadget < tool history scroller search-field popup ;
  16
  17 { 650 700 } browser-gadget set-tool-dim
  18
  19 M: browser-gadget history-value
  20     [ control-value ] [ scroller>> scroll-position ]
  21     bi 2array ;
  22
  23 M: browser-gadget set-history-value
  24     [ first2 ] dip
  25     [ set-control-value ] [ scroller>> set-scroll-position ]
  26     bi-curry bi* ;
  27
  28 : show-help ( link browser-gadget -- )
  29     [ >link ] dip
  30     [
  31         2dup control-value =
  32         [ 2drop ] [ [ add-recent ] [ history>> add-history ] bi* ] if
  33     ]
  34     [ set-control-value ]
  35     2bi ;
  36
  37 : <help-header> ( browser-gadget -- gadget )
  38     model>> [ '[ _ $title ] try ] <pane-control> ;
  39
  40 CONSTANT: help-header-background COLOR: FactorLightTan
  41
  42 : add-help-header ( track -- track )
  43     dup <help-header> { 3 3 } <border>
  44     help-header-background <solid> >>interior
  45     toolbar-border <solid-underlined> >>boundary
  46     { 1 0 } >>fill f track-add ;
  47
  48 : <help-pane> ( browser-gadget -- gadget )
  49     model>> [ '[ _ print-topic ] try ] <pane-control> ;
  50
  51 : add-help-pane ( track -- track )
  52     dup dup <help-pane> { 10 0 } <border> { 1 1 } >>fill
  53     <scroller> >>scroller scroller>> 1 track-add ;
  54
  55 : search-browser ( string browser -- )
  56     '[ <apropos-search> _ show-help ] unless-empty ;
  57
  58 : <search-field> ( browser -- field )
  59     '[ _ search-browser ] <action-field>
  60         10 >>min-cols
  61         10 >>max-cols
  62         COLOR: white <solid> >>interior ;
  63
  64 : <browser-toolbar> ( browser -- toolbar )
  65     horizontal <track>
  66         0 >>fill
  67         1/2 >>align
  68         { 5 5 } >>gap
  69         over <toolbar> f track-add
  70         swap search-field>> "          Search" label-on-left 1 track-add ;
  71
  72 : add-browser-toolbar ( track -- track )
  73     dup <browser-toolbar> { 3 3 } <border>
  74     button-background <solid> >>interior
  75     toolbar-border <solid-underlined> >>boundary
  76     { 1 0 } >>fill f track-add ;
  77
  78 : <browser-gadget> ( link -- gadget )
  79     vertical browser-gadget new-track
  80         1 >>fill
  81         swap >link <model> >>model
  82         dup <history> >>history
  83         dup <search-field> >>search-field
  84         add-browser-toolbar
  85         add-help-header
  86         add-help-pane ;
  87
  88 M: browser-gadget graft*
  89     [ add-definition-observer ] [ call-next-method ] bi ;
  90
  91 M: browser-gadget ungraft*
  92     [ call-next-method ] [ remove-definition-observer ] bi ;
  93
  94 M: browser-gadget handle-gesture
  95     {
  96         { [ over key-gesture? not ] [ call-next-method ] }
  97         { [ dup popup>> ] [ { [ pass-to-popup ] [ call-next-method ] } 2&& ] }
  98         [ call-next-method ]
  99     } cond ;
 100
 101 : showing-definition? ( defspec set -- ? )
 102     {
 103         [ in? ]
 104         [ [ dup word-link? [ name>> ] when ] dip in? ]
 105         [ [ dup vocab-link? [ lookup-vocab ] when ] dip in? ]
 106     } 2|| ;
 107
 108 M: browser-gadget definitions-changed ( set browser -- )
 109     [ control-value swap showing-definition? ] keep
 110     '[ _ [ history-value ] keep set-history-value ] when ;
 111
 112 M: browser-gadget focusable-child* search-field>> ;
 113
 114 : (browser-window) ( topic -- )
 115     <browser-gadget>
 116     <world-attributes>
 117         "Browser" >>title
 118     open-status-window ;
 119
 120 : browser-window ( -- )
 121     "help.home" (browser-window) ;
 122
 123 : error-help-window ( error -- )
 124     {
 125         [ error-help ]
 126         [ dup tuple? [ class-of ] [ drop "errors" ] if ]
 127     } 1|| (browser-window) ;
 128
 129 \ browser-window H{ { +nullary+ t } } define-command
 130
 131 : com-browse ( link -- )
 132     [ browser-gadget? ] find-window
 133     [ [ raise-window ] [ gadget-child show-help ] bi ]
 134     [ (browser-window) ] if* ;
 135
 136 : show-browser ( -- )
 137     [ browser-gadget? ] find-window
 138     [ [ raise-window ] [ request-focus ] bi ] [ browser-window ] if* ;
 139
 140 \ show-browser H{ { +nullary+ t } } define-command
 141
 142 : com-back ( browser -- ) history>> go-back ;
 143
 144 : com-forward ( browser -- ) history>> go-forward ;
 145
 146 : com-home ( browser -- ) "help.home" swap show-help ;
 147
 148 : browser-help ( -- ) "ui-browser" com-browse ;
 149
 150 : glossary ( -- ) "conventions" com-browse ;
 151
 152 \ browser-help H{ { +nullary+ t } } define-command
 153 \ glossary H{ { +nullary+ t } } define-command
 154
 155 browser-gadget "toolbar" f {
 156     { T{ key-down f { A+ } "LEFT" } com-back }
 157     { T{ key-down f { A+ } "RIGHT" } com-forward }
 158     { T{ key-down f { A+ } "H" } com-home }
 159     { T{ key-down f f "F1" } browser-help }
 160     { T{ key-down f { A+ } "F1" } glossary }
 161 } define-command-map
 162
 163 : ?show-help ( link browser -- )
 164     over [ show-help ] [ 2drop ] if ;
 165
 166 : navigate ( browser quot -- )
 167     '[ control-value @ ] keep ?show-help ; inline
 168
 169 : com-up ( browser -- ) [ article-parent ] navigate ;
 170
 171 : com-prev ( browser -- ) [ prev-article ] navigate ;
 172
 173 : com-next ( browser -- ) [ next-article ] navigate ;
 174
 175 browser-gadget "navigation" "Commands for navigating in the article hierarchy" {
 176     { T{ key-down f { A+ } "u" } com-up }
 177     { T{ key-down f { A+ } "p" } com-prev }
 178     { T{ key-down f { A+ } "n" } com-next }
 179     { T{ key-down f { A+ } "k" } com-show-outgoing-links }
 180     { T{ key-down f { A+ } "K" } com-show-incoming-links }
 181 } define-command-map
 182
 183 browser-gadget "multi-touch" f {
 184     { left-action com-back }
 185     { right-action com-forward }
 186 } define-command-map
 187
 188 browser-gadget "scrolling"
 189 "The browser's scroller can be scrolled from the keyboard."
 190 {
 191     { T{ key-down f f "UP" } com-scroll-up }
 192     { T{ key-down f f "DOWN" } com-scroll-down }
 193     { T{ key-down f f "PAGE_UP" } com-page-up }
 194     { T{ key-down f f "PAGE_DOWN" } com-page-down }
 195 } define-command-map
 196
 197 : com-font-size-plus ( browser -- )
 198     2 adjust-help-font-size model>> notify-connections ;
 199
 200 : com-font-size-minus ( browser -- )
 201     -2 adjust-help-font-size model>> notify-connections ;
 202
 203 browser-gadget "fonts" f {
 204     { T{ key-down f { A+ } "+" } com-font-size-plus }
 205     { T{ key-down f { A+ } "=" } com-font-size-plus }
 206     { T{ key-down f { A+ } "_" } com-font-size-minus }
 207     { T{ key-down f { A+ } "-" } com-font-size-minus }
 208 } define-command-map
 209
 210 MAIN: browser-window