basis/ui/tools/browser/browser.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: debugger classes help help.topics help.crossref help.home
   4 kernel models compiler.units assocs words vocabs accessors fry arrays
   5 combinators.short-circuit namespaces sequences help.apropos
   6 combinators ui ui.commands ui.gadgets ui.gadgets.panes
   7 ui.gadgets.scrollers ui.gadgets.tracks ui.gestures ui.gadgets.buttons
   8 ui.gadgets.packs ui.gadgets.editors ui.gadgets.labels
   9 ui.gadgets.status-bar ui.gadgets.glass ui.gadgets.borders
  10 ui.gadgets.viewports ui.tools.common ui.tools.browser.popups
  11 ui.tools.browser.history ;
  12 IN: ui.tools.browser
  13
  14 TUPLE: browser-gadget < tool history pane scroller search-field popup ;
  15
  16 { 650 400 } browser-gadget set-tool-dim
  17
  18 M: browser-gadget history-value
  19     [ control-value ] [ scroller>> scroll-position ]
  20     bi 2array ;
  21
  22 M: browser-gadget set-history-value
  23     [ first2 ] dip
  24     [ set-control-value ] [ scroller>> set-scroll-position ]
  25     bi-curry bi* ;
  26
  27 : show-help ( link browser-gadget -- )
  28     [ >link ] dip
  29     [
  30         2dup model>> value>> =
  31         [ 2drop ] [ [ add-recent ] [ history>> add-history ] bi* ] if
  32     ]
  33     [ model>> set-model ]
  34     2bi ;
  35
  36 : <help-pane> ( browser-gadget -- gadget )
  37     model>> [ '[ _ print-topic ] try ] <pane-control> ;
  38
  39 : search-browser ( string browser -- )
  40     '[ <apropos> _ show-help ] unless-empty ;
  41
  42 : <search-field> ( browser -- field )
  43     '[ _ search-browser ] <action-field>
  44         10 >>min-cols
  45         10 >>max-cols ;
  46
  47 : <browser-toolbar> ( browser -- toolbar )
  48     horizontal <track>
  49         0 >>fill
  50         1/2 >>align
  51         { 5 5 } >>gap
  52         over <toolbar> f track-add
  53         swap search-field>> "Search:" label-on-left 1 track-add ;
  54
  55 : <browser-gadget> ( link -- gadget )
  56     vertical browser-gadget new-track
  57         1 >>fill
  58         swap >link <model> >>model
  59         dup <history> >>history
  60         dup <search-field> >>search-field
  61         dup <browser-toolbar> { 3 3 } <border> { 1 0 } >>fill f track-add
  62         dup <help-pane> >>pane
  63         dup pane>> <scroller> >>scroller
  64         dup scroller>> 1 track-add ;
  65
  66 M: browser-gadget graft*
  67     [ add-definition-observer ] [ call-next-method ] bi ;
  68
  69 M: browser-gadget ungraft*
  70     [ call-next-method ] [ remove-definition-observer ] bi ;
  71
  72 M: browser-gadget handle-gesture
  73     {
  74         { [ over key-gesture? not ] [ call-next-method ] }
  75         { [ dup popup>> ] [ { [ pass-to-popup ] [ call-next-method ] } 2&& ] }
  76         [ call-next-method ]
  77     } cond ;
  78
  79 : showing-definition? ( defspec assoc -- ? )
  80     {
  81         [ key? ]
  82         [ [ dup word-link? [ name>> ] when ] dip key? ]
  83         [ [ dup vocab-link? [ vocab ] when ] dip key? ]
  84     } 2|| ;
  85
  86 M: browser-gadget definitions-changed ( assoc browser -- )
  87     model>> [ value>> swap showing-definition? ] keep
  88     '[ _ notify-connections ] when ;
  89
  90 M: browser-gadget focusable-child* search-field>> ;
  91
  92 : (browser-window) ( topic -- )
  93     <browser-gadget> "Browser" open-status-window ;
  94
  95 : browser-window ( -- )
  96     "help.home" (browser-window) ;
  97
  98 : error-help-window ( error -- )
  99     [ error-help ]
 100     [ dup tuple? [ class ] [ drop "errors" ] if ] bi or (browser-window) ;
 101
 102 \ browser-window H{ { +nullary+ t } } define-command
 103
 104 : com-browse ( link -- )
 105     [ browser-gadget? ] find-window
 106     [ [ raise-window ] [ gadget-child show-help ] bi ]
 107     [ (browser-window) ] if* ;
 108
 109 : show-browser ( -- )
 110     [ browser-gadget? ] find-window
 111     [ [ raise-window ] [ request-focus ] bi ] [ browser-window ] if* ;
 112
 113 \ show-browser H{ { +nullary+ t } } define-command
 114
 115 : com-back ( browser -- ) history>> go-back ;
 116
 117 : com-forward ( browser -- ) history>> go-forward ;
 118
 119 : com-home ( browser -- ) "help.home" swap show-help ;
 120
 121 : browser-help ( -- ) "ui-browser" com-browse ;
 122
 123 \ browser-help H{ { +nullary+ t } } define-command
 124
 125 browser-gadget "toolbar" f {
 126     { T{ key-down f { A+ } "LEFT" } com-back }
 127     { T{ key-down f { A+ } "RIGHT" } com-forward }
 128     { T{ key-down f { A+ } "H" } com-home }
 129     { T{ key-down f f "F1" } browser-help }
 130 } define-command-map
 131
 132 : ?show-help ( link browser -- )
 133     over [ show-help ] [ 2drop ] if ;
 134
 135 : navigate ( browser quot -- )
 136     '[ control-value @ ] keep ?show-help ; inline
 137
 138 : com-up ( browser -- ) [ article-parent ] navigate ;
 139
 140 : com-prev ( browser -- ) [ prev-article ] navigate ;
 141
 142 : com-next ( browser -- ) [ next-article ] navigate ;
 143
 144 browser-gadget "navigation" "Commands for navigating in the article hierarchy" {
 145     { T{ key-down f { A+ } "u" } com-up }
 146     { T{ key-down f { A+ } "p" } com-prev }
 147     { T{ key-down f { A+ } "n" } com-next }
 148     { T{ key-down f { A+ } "k" } com-show-outgoing-links }
 149     { T{ key-down f { A+ } "K" } com-show-incoming-links }
 150 } define-command-map
 151
 152 browser-gadget "multi-touch" f {
 153     { left-action com-back }
 154     { right-action com-forward }
 155 } define-command-map
 156
 157 browser-gadget "scrolling"
 158 "The browser's scroller can be scrolled from the keyboard."
 159 {
 160     { T{ key-down f f "UP" } com-scroll-up }
 161     { T{ key-down f f "DOWN" } com-scroll-down }
 162     { T{ key-down f f "PAGE_UP" } com-page-up }
 163     { T{ key-down f f "PAGE_DOWN" } com-page-down }
 164 } define-command-map
 165
 166 MAIN: browser-window