basis/ui/tools/browser/browser.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays classes colors colors.constants combinators
   4 combinators.short-circuit compiler.units debugger fry help
   5 help.apropos help.crossref help.home help.stylesheet help.topics
   6 kernel models sequences sets ui ui.commands ui.gadgets
   7 ui.gadgets.borders ui.gadgets.buttons ui.gadgets.colors ui.gadgets.editors
   8 ui.gadgets.glass ui.gadgets.labels ui.gadgets.lines ui.gadgets.panes
   9 ui.gadgets.scrollers ui.gadgets.status-bar ui.gadgets.tracks ui.gadgets.toolbar
  10 ui.gadgets.viewports ui.gadgets.worlds ui.gestures
  11 ui.tools.browser.history ui.tools.browser.popups ui.tools.common
  12 ui.pens.solid vocabs ;
  13 IN: ui.tools.browser
  14
  15 TUPLE: browser-gadget < tool history scroller search-field popup ;
  16
  17 { 650 700 } browser-gadget set-tool-dim
  18
  19 M: browser-gadget history-value
  20     [ control-value ] [ scroller>> scroll-position ]
  21     bi 2array ;
  22
  23 M: browser-gadget set-history-value
  24     [ first2 ] dip
  25     [ set-control-value ] [ scroller>> set-scroll-position ]
  26     bi-curry bi* ;
  27
  28 : show-help ( link browser-gadget -- )
  29     [ >link ] dip
  30     [
  31         2dup control-value =
  32         [ 2drop ] [ [ add-recent ] [ history>> add-history ] bi* ] if
  33     ]
  34     [ set-control-value ]
  35     2bi ;
  36
  37 : <help-header> ( browser-gadget -- gadget )
  38     model>> [ '[ _ $title ] try ] <pane-control> ;
  39
  40 : add-help-header ( track -- track )
  41     dup <help-header> { 3 3 } <border>
  42     help-header-background <solid> >>interior
  43     { 1 0 } >>fill f track-add ;
  44
  45 : <help-pane> ( browser-gadget -- gadget )
  46     model>> [ '[ _ print-topic ] try ] <pane-control> ;
  47
  48 : add-help-pane ( track -- track )
  49     dup dup <help-pane> margins
  50     <scroller> >>scroller scroller>> white-interior 1 track-add ;
  51
  52 : search-browser ( string browser -- )
  53     '[ <apropos-search> _ show-help ] unless-empty ;
  54
  55 : <search-field> ( browser -- field )
  56     '[ _ search-browser ] <action-field>
  57         10 >>min-cols
  58         10 >>max-cols
  59         white-interior ;
  60
  61 : <browser-toolbar> ( browser -- toolbar )
  62     horizontal <track>
  63         0 >>fill
  64         1/2 >>align
  65         { 5 5 } >>gap
  66         over <toolbar> f track-add
  67         swap search-field>> "          Search" label-on-left 1 track-add ;
  68
  69 : add-browser-toolbar ( track -- track )
  70     dup <browser-toolbar> { 3 3 } <border>
  71     toolbar-background <solid> >>interior { 1 0 } >>fill
  72     f track-add ;
  73
  74 : <browser-gadget> ( link -- gadget )
  75     vertical browser-gadget new-track with-lines
  76         1 >>fill
  77         swap >link <model> >>model
  78         dup <history> >>history
  79         dup <search-field> >>search-field
  80         add-browser-toolbar
  81         add-help-header
  82         add-help-pane ;
  83
  84 M: browser-gadget graft*
  85     [ add-definition-observer ] [ call-next-method ] bi ;
  86
  87 M: browser-gadget ungraft*
  88     [ call-next-method ] [ remove-definition-observer ] bi ;
  89
  90 M: browser-gadget handle-gesture
  91     {
  92         { [ over key-gesture? not ] [ call-next-method ] }
  93         { [ dup popup>> ] [ { [ pass-to-popup ] [ call-next-method ] } 2&& ] }
  94         [ call-next-method ]
  95     } cond ;
  96
  97 : showing-definition? ( defspec set -- ? )
  98     {
  99         [ in? ]
 100         [ [ dup word-link? [ name>> ] when ] dip in? ]
 101         [ [ dup vocab-link? [ lookup-vocab ] when ] dip in? ]
 102     } 2|| ;
 103
 104 M: browser-gadget definitions-changed ( set browser -- )
 105     [ control-value swap showing-definition? ] keep
 106     '[ _ [ history-value ] keep set-history-value ] when ;
 107
 108 M: browser-gadget focusable-child* search-field>> ;
 109
 110 : (browser-window) ( topic -- )
 111     <browser-gadget>
 112     <world-attributes>
 113         "Browser" >>title
 114     open-status-window ;
 115
 116 : browser-window ( -- )
 117     "help.home" (browser-window) ;
 118
 119 : error-help-window ( error -- )
 120     {
 121         [ error-help ]
 122         [ dup tuple? [ class-of ] [ drop "errors" ] if ]
 123     } 1|| (browser-window) ;
 124
 125 \ browser-window H{ { +nullary+ t } } define-command
 126
 127 : com-browse ( link -- )
 128     [ browser-gadget? ] find-window
 129     [ [ raise-window ] [ gadget-child show-help ] bi ]
 130     [ (browser-window) ] if* ;
 131
 132 : show-browser ( -- )
 133     [ browser-gadget? ] find-window
 134     [ [ raise-window ] [ request-focus ] bi ] [ browser-window ] if* ;
 135
 136 \ show-browser H{ { +nullary+ t } } define-command
 137
 138 : com-back ( browser -- ) history>> go-back ;
 139
 140 : com-forward ( browser -- ) history>> go-forward ;
 141
 142 : com-home ( browser -- ) "help.home" swap show-help ;
 143
 144 : browser-help ( -- ) "ui-browser" com-browse ;
 145
 146 : glossary ( -- ) "conventions" com-browse ;
 147
 148 \ browser-help H{ { +nullary+ t } } define-command
 149 \ glossary H{ { +nullary+ t } } define-command
 150
 151 browser-gadget "toolbar" f {
 152     { T{ key-down f { A+ } "LEFT" } com-back }
 153     { T{ key-down f { A+ } "RIGHT" } com-forward }
 154     { T{ key-down f { A+ } "H" } com-home }
 155     { T{ key-down f f "F1" } browser-help }
 156     { T{ key-down f { A+ } "F1" } glossary }
 157 } define-command-map
 158
 159 : ?show-help ( link browser -- )
 160     over [ show-help ] [ 2drop ] if ;
 161
 162 : navigate ( browser quot -- )
 163     '[ control-value @ ] keep ?show-help ; inline
 164
 165 : com-up ( browser -- ) [ article-parent ] navigate ;
 166
 167 : com-prev ( browser -- ) [ prev-article ] navigate ;
 168
 169 : com-next ( browser -- ) [ next-article ] navigate ;
 170
 171 browser-gadget "navigation" "Commands for navigating in the article hierarchy" {
 172     { T{ key-down f { A+ } "u" } com-up }
 173     { T{ key-down f { A+ } "p" } com-prev }
 174     { T{ key-down f { A+ } "n" } com-next }
 175     { T{ key-down f { A+ } "k" } com-show-outgoing-links }
 176     { T{ key-down f { A+ } "K" } com-show-incoming-links }
 177 } define-command-map
 178
 179 browser-gadget "multi-touch" f {
 180     { left-action com-back }
 181     { right-action com-forward }
 182 } define-command-map
 183
 184 browser-gadget "scrolling"
 185 "The browser's scroller can be scrolled from the keyboard."
 186 {
 187     { T{ key-down f f "UP" } com-scroll-up }
 188     { T{ key-down f f "DOWN" } com-scroll-down }
 189     { T{ key-down f f "PAGE_UP" } com-page-up }
 190     { T{ key-down f f "PAGE_DOWN" } com-page-down }
 191 } define-command-map
 192
 193 : com-font-size-plus ( browser -- )
 194     2 adjust-help-font-size model>> notify-connections ;
 195
 196 : com-font-size-minus ( browser -- )
 197     -2 adjust-help-font-size model>> notify-connections ;
 198
 199 browser-gadget "fonts" f {
 200     { T{ key-down f { A+ } "+" } com-font-size-plus }
 201     { T{ key-down f { A+ } "=" } com-font-size-plus }
 202     { T{ key-down f { A+ } "_" } com-font-size-minus }
 203     { T{ key-down f { A+ } "-" } com-font-size-minus }
 204 } define-command-map
 205
 206 MAIN: browser-window