basis/ui/tools/debugger/debugger.factor

   1 ! Copyright (C) 2006, 2011 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays hashtables io kernel math models
   4 colors.constants namespaces sequences words continuations
   5 debugger prettyprint help editors fonts ui ui.commands
   6 ui.debugger ui.gestures ui.gadgets ui.pens.solid
   7 ui.gadgets.worlds ui.gadgets.packs ui.gadgets.buttons
   8 ui.gadgets.labels ui.gadgets.presentations ui.gadgets.panes
   9 ui.gadgets.viewports ui.gadgets.tables ui.theme
  10 ui.gadgets.tracks ui.gadgets.toolbar ui.gadgets.scrollers
  11 ui.gadgets.borders ui.gadgets.status-bar ui.theme.images
  12 ui.tools.traceback ui.tools.inspector ui.tools.browser
  13 ui.tools.common ;
  14 IN: ui.tools.debugger
  15
  16 TUPLE: debugger < track error restarts restart-hook restart-list continuation ;
  17
  18 <PRIVATE
  19
  20 SINGLETON: restart-renderer
  21
  22 M: restart-renderer row-columns
  23     drop [ name>> ] [ "Abort" ] if* "• " prepend 1array ;
  24
  25 : <restart-list> ( debugger -- gadget )
  26     dup restarts>> f prefix <model> restart-renderer <table>
  27         [ [ \ continue-restart invoke-command ] when* ] >>action
  28         swap restart-hook>> >>hook
  29         t >>selection-required?
  30         t >>single-click? ; inline
  31
  32 : <error-pane> ( error -- pane )
  33     <pane> [ [ print-error ] with-pane ] keep ; inline
  34
  35 : <error-display> ( debugger -- gadget )
  36     [ <filled-pile> ] dip
  37     [ error>> <error-pane> add-gadget ]
  38     [
  39         dup restart-hook>> [
  40             [ "To continue, pick one of the options below:" <label> add-gadget ] dip
  41             restart-list>> add-gadget
  42         ] [ drop ] if
  43     ] bi ;
  44
  45 PRIVATE>
  46
  47 : <debugger> ( error continuation restarts restart-hook -- debugger )
  48     vertical debugger new-track with-lines
  49         swap >>restart-hook
  50         swap >>restarts
  51         swap >>continuation
  52         swap >>error
  53         dup <restart-list> >>restart-list
  54         dup <error-display> margins white-interior f track-add
  55         add-toolbar ;
  56
  57 M: debugger focusable-child*
  58     dup restart-hook>> [ restart-list>> ] [ drop t ] if ;
  59
  60 : debugger-window ( error continuation -- )
  61     ! No restarts for the debugger window
  62     f f <debugger> "Error" open-status-window ;
  63
  64 GENERIC: error-in-debugger? ( error -- ? )
  65
  66 M: world-error error-in-debugger?
  67     world>> children>> ?first debugger? ;
  68
  69 M: object error-in-debugger? drop f ;
  70
  71 [
  72     dup error-in-debugger?
  73     [ error-alert ] [ error-continuation get debugger-window ] if
  74 ] ui-error-hook set-global
  75
  76 debugger "gestures" f {
  77     { T{ button-down } request-focus }
  78 } define-command-map
  79
  80 : com-inspect ( debugger -- ) error>> inspector ;
  81
  82 : com-traceback ( debugger -- ) continuation>> traceback-window ;
  83
  84 : com-help ( debugger -- ) error>> error-help-window ;
  85
  86 : com-edit ( debugger -- ) error>> edit-error ;
  87
  88 \ com-edit H{ { +listener+ t } } define-command
  89
  90 debugger "toolbar" f {
  91     { T{ key-down f f "i" } com-inspect }
  92     { T{ key-down f f "t" } com-traceback }
  93     { T{ key-down f f "h" } com-help }
  94     { T{ key-down f f "e" } com-edit }
  95 } define-command-map