basis/ui/tools/debugger/debugger.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays hashtables io kernel math models
   4 colors.constants namespaces sequences words continuations
   5 debugger prettyprint help editors fonts ui ui.commands ui.gestures
   6 ui.gadgets ui.pens.solid ui.gadgets.worlds ui.gadgets.packs
   7 ui.gadgets.buttons ui.gadgets.labels ui.gadgets.panes
   8 ui.gadgets.presentations ui.gadgets.viewports ui.gadgets.tables
   9 ui.gadgets.tracks ui.gadgets.scrollers ui.gadgets.panes
  10 ui.gadgets.borders ui.gadgets.status-bar ui.tools.traceback
  11 ui.tools.inspector ui.tools.browser ui.debugger ;
  12 IN: ui.tools.debugger
  13
  14 TUPLE: debugger < track error restarts restart-hook restart-list continuation ;
  15
  16 <PRIVATE
  17
  18 SINGLETON: restart-renderer
  19
  20 M: restart-renderer row-columns
  21     drop [ name>> ] [ "Abort" ] if* "• " prepend 1array ;
  22
  23 : <restart-list> ( debugger -- gadget )
  24     dup restarts>> f prefix <model> restart-renderer <table>
  25         [ [ \ restart invoke-command ] when* ] >>action
  26         swap restart-hook>> >>hook
  27         t >>selection-required?
  28         t >>single-click? ; inline
  29
  30 : <error-display> ( debugger -- gadget )
  31     [ <filled-pile> ] dip
  32     [ error>> <error-pane> add-gadget ]
  33     [
  34         dup restart-hook>> [
  35             [ "To continue, pick one of the options below:" <label> add-gadget ] dip
  36             restart-list>> add-gadget
  37         ] [ drop ] if
  38     ] bi ;
  39
  40 PRIVATE>
  41
  42 : <debugger> ( error continuation restarts restart-hook -- debugger )
  43     vertical debugger new-track
  44         { 3 3 } >>gap
  45         swap >>restart-hook
  46         swap >>restarts
  47         swap >>continuation
  48         swap >>error
  49         add-toolbar
  50         dup <restart-list> >>restart-list
  51         dup <error-display> f track-add
  52         COLOR: white <solid> >>interior ;
  53
  54 M: debugger focusable-child*
  55     dup restart-hook>> [ restart-list>> ] [ drop t ] if ;
  56
  57 : debugger-window ( error continuation -- )
  58     #! No restarts for the debugger window
  59     f f <debugger> "Error" open-status-window ;
  60
  61 GENERIC: error-in-debugger? ( error -- ? )
  62
  63 M: world-error error-in-debugger?
  64     world>> children>> [ f ] [ first debugger? ] if-empty ;
  65
  66 M: object error-in-debugger? drop f ;
  67
  68 [
  69     dup error-in-debugger?
  70     [ rethrow ] [ error-continuation get debugger-window ] if
  71 ] ui-error-hook set-global
  72
  73 debugger "gestures" f {
  74     { T{ button-down } request-focus }
  75 } define-command-map
  76
  77 : com-inspect ( debugger -- ) error>> inspector ;
  78
  79 : com-traceback ( debugger -- ) continuation>> traceback-window ;
  80
  81 : com-help ( debugger -- ) error>> error-help-window ;
  82
  83 : com-edit ( debugger -- ) error>> (:edit) ;
  84
  85 \ com-edit H{ { +listener+ t } } define-command
  86
  87 debugger "toolbar" f {
  88     { T{ key-down f { C+ } "i" } com-inspect }
  89     { T{ key-down f { C+ } "t" } com-traceback }
  90     { T{ key-down f { C+ } "h" } com-help }
  91     { T{ key-down f { C+ } "e" } com-edit }
  92 } define-command-map