basis/ui/tools/deploy/deploy.factor

   1 ! Copyright (C) 2007, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: colors kernel models tools.deploy.config
   4 tools.deploy.config.editor tools.deploy vocabs namespaces
   5 models.mapping sequences system accessors fry ui.gadgets ui.render
   6 ui.gadgets.buttons ui.gadgets.packs ui.gadgets.labels
   7 ui.gadgets.editors ui.gadgets.borders ui.gestures ui.commands assocs
   8 ui.gadgets.tracks ui ui.tools.listener ui.tools.browser
   9 ui.gadgets.worlds ;
  10 IN: ui.tools.deploy
  11
  12 TUPLE: deploy-gadget < pack vocab settings ;
  13
  14 : bundle-name ( parent -- parent )
  15     deploy-name get <model-field>
  16     "Executable name:" label-on-left add-gadget ;
  17
  18 : deploy-console ( parent -- parent )
  19     deploy-console? get
  20     "Deploy as console application" <checkbox> add-gadget ;
  21
  22 : deploy-ui ( parent -- parent )
  23     deploy-ui? get
  24     "Include user interface framework" <checkbox> add-gadget ;
  25
  26 : reflection-settings ( parent -- parent )
  27     "Reflection level:" <label> add-gadget
  28     deploy-reflection get deploy-reflection-options <radio-buttons> add-gadget ;
  29
  30 : advanced-settings ( parent -- parent )
  31     "Additional reflection:" <label> add-gadget
  32     deploy-unicode? get "Unicode character literal table" <checkbox> add-gadget
  33     deploy-word-props? get "Retain all word properties" <checkbox> add-gadget
  34     deploy-word-defs? get "Retain all word definitions" <checkbox> add-gadget
  35     deploy-c-types? get "Retain all C types" <checkbox> add-gadget
  36     deploy-help? get "Retain documentation" <checkbox> add-gadget ;
  37
  38 : deploy-settings-theme ( gadget -- gadget )
  39     { 10 10 } >>gap
  40     1 >>fill ;
  41
  42 : <deploy-settings> ( vocab -- control )
  43     default-config [ <model> ] assoc-map [
  44         <pile>
  45         bundle-name
  46         deploy-ui
  47         deploy-console
  48         reflection-settings
  49         advanced-settings
  50
  51         deploy-settings-theme
  52         namespace <mapping> >>model
  53     ] with-variables ;
  54
  55 : find-deploy-gadget ( gadget -- deploy-gadget )
  56     [ deploy-gadget? ] find-parent ;
  57
  58 : find-deploy-vocab ( gadget -- vocab )
  59     find-deploy-gadget vocab>> ;
  60
  61 : find-deploy-config ( gadget -- config )
  62     find-deploy-vocab deploy-config ;
  63
  64 : find-deploy-settings ( gadget -- settings )
  65     find-deploy-gadget settings>> ;
  66
  67 : com-revert ( gadget -- )
  68     dup find-deploy-config
  69     swap find-deploy-settings set-control-value ;
  70
  71 : com-save ( gadget -- )
  72     dup find-deploy-settings control-value
  73     swap find-deploy-vocab set-deploy-config ;
  74
  75 : com-deploy ( gadget -- )
  76     [ com-save ]
  77     [ find-deploy-vocab '[ _ deploy ] \ deploy call-listener ]
  78     [ close-window ]
  79     tri ;
  80
  81 : com-help ( -- )
  82     "ui.tools.deploy" com-browse ;
  83
  84 \ com-help H{
  85     { +nullary+ t }
  86 } define-command
  87
  88 : com-close ( gadget -- )
  89     close-window ;
  90
  91 deploy-gadget "misc" "Miscellaneous commands" {
  92     { T{ key-down f f "ESC" } com-close }
  93 } define-command-map
  94
  95 deploy-gadget "toolbar" f {
  96     { T{ key-down f f "F1" } com-help }
  97     { f com-revert }
  98     { f com-save }
  99     { T{ key-down f f "RET" } com-deploy }
 100 } define-command-map
 101
 102 : <deploy-gadget> ( vocab -- gadget )
 103     deploy-gadget new
 104       over >>vocab
 105       vertical >>orientation
 106       swap <deploy-settings> >>settings
 107       dup settings>> add-gadget
 108       dup <toolbar> { 10 10 } >>gap add-gadget
 109     deploy-settings-theme
 110     dup com-revert ;
 111
 112 : deploy-tool ( vocab -- )
 113     vocab-name
 114     [ <deploy-gadget> { 10 10 } <border> ]
 115     [
 116         <world-attributes>
 117             swap "Deploying “" "”" surround >>title
 118             [ { dialog-window } append ] change-window-controls
 119     ] bi
 120     open-window ;