basis/ui/tools/inspector/inspector.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs classes combinators fonts fry
   4 hashtables inspector io io.styles kernel math.vectors mirrors
   5 models models.arrow namespaces prettyprint refs sequences
   6 sorting ui ui.commands ui.gadgets ui.gadgets.labeled
   7 ui.gadgets.panes ui.gadgets.scrollers ui.gadgets.slots
   8 ui.gadgets.status-bar ui.gadgets.tables
   9 ui.gadgets.tables.private ui.gadgets.toolbar ui.gadgets.tracks
  10 ui.gadgets.worlds ui.gestures ui.operations ui.theme
  11 ui.tools.browser ui.tools.common ;
  12 IN: ui.tools.inspector
  13
  14 TUPLE: inspector-gadget < tool table ;
  15
  16 TUPLE: slot-description key key-string value value-string ;
  17
  18 : <slot-description> ( key value -- slot-description )
  19     [ dup unparse-short ] bi@ slot-description boa ;
  20
  21 SINGLETON: inspector-renderer
  22
  23 M: inspector-renderer row-columns
  24     drop [ key-string>> ] [ value-string>> ] bi 2array ;
  25
  26 M: inspector-renderer row-value
  27     drop value>> ;
  28
  29 M: inspector-renderer column-titles
  30     drop { "Key" "Value" } ;
  31
  32 : <summary-gadget> ( model -- gadget )
  33     [
  34         standard-table-style [
  35             {
  36                 [
  37                     [
  38                         [ "Class:" write ] with-cell
  39                         [ class-of pprint ] with-cell
  40                     ] with-row
  41                 ]
  42                 [
  43                     [
  44                         [ "Object:" write ] with-cell
  45                         [ pprint-short ] with-cell
  46                     ] with-row
  47                 ]
  48                 [
  49                     [
  50                         [ "Summary:" write ] with-cell
  51                         [ print-summary ] with-cell
  52                     ] with-row
  53                 ]
  54                 [
  55                     content-gadget [
  56                         [
  57                             [ "Content:" write ] with-cell
  58                             [ output-stream get write-gadget ] with-cell
  59                         ] with-row
  60                     ] when*
  61                 ]
  62             } cleave
  63         ] tabular-output
  64     ] <pane-control> ;
  65
  66 GENERIC: make-slot-descriptions ( obj -- seq )
  67
  68 M: object make-slot-descriptions
  69     make-mirror [ <slot-description> ] { } assoc>map ;
  70
  71 M: hashtable make-slot-descriptions
  72     call-next-method [ key-string>> ] sort-with ;
  73
  74 TUPLE: inspector-table < table ;
  75
  76 ! Improve performance for big arrays or large hashtables by
  77 ! only calculating column width for the longest key.
  78 M: inspector-table compute-column-widths
  79     dup rows>> [ drop 0 { } ] [
  80         [ drop gap>> ]
  81         [ initial-widths ]
  82         [ keys longest "" 2array row-column-widths ] 2tri
  83         vmax [ compute-total-width ] keep
  84     ] if-empty ;
  85
  86 : <inspector-table> ( model -- table )
  87     [ make-slot-descriptions ] <arrow> inspector-renderer
  88     inspector-table new-table
  89         [ invoke-primary-operation ] >>action
  90         monospace-font >>font
  91         line-color >>column-line-color
  92         6 >>gap
  93         15 >>min-rows
  94         15 >>max-rows
  95         40 >>min-cols
  96         40 >>max-cols ;
  97
  98 : <inspector-gadget> ( model -- gadget )
  99     vertical inspector-gadget new-track with-lines
 100         add-toolbar
 101         swap >>model
 102         dup model>> <inspector-table> >>table
 103         dup model>> <summary-gadget> margins white-interior "Object" object-color <labeled> f track-add
 104         dup table>> <scroller> margins white-interior "Contents" contents-color <labeled> 1 track-add ;
 105
 106 M: inspector-gadget focusable-child*
 107     table>> ;
 108
 109 : com-refresh ( inspector -- )
 110     model>> notify-connections ;
 111
 112 : com-push ( inspector -- obj )
 113     control-value ;
 114
 115 \ com-push H{ { +listener+ t } } define-command
 116
 117 : slot-editor-window ( close-hook update-hook assoc key key-string -- )
 118     [ <value-ref> <slot-editor> ]
 119     [
 120         <world-attributes>
 121             swap "Slot editor: " prepend >>title
 122             [ { dialog-window } append ] change-window-controls
 123     ] bi*
 124     open-status-window ;
 125
 126 : com-edit-slot ( inspector -- )
 127     [ close-window ] swap
 128     [ '[ _ com-refresh ] ]
 129     [ control-value make-mirror ]
 130     [ table>> (selected-row) ] tri [
 131         [ key>> ] [ key-string>> ] bi
 132         slot-editor-window
 133     ] [ 4drop ] if ;
 134
 135 : inspector-help ( -- ) "ui-inspector" com-browse ;
 136
 137 \ inspector-help H{ { +nullary+ t } } define-command
 138
 139 inspector-gadget "toolbar" f {
 140     { T{ key-down f f "r" } com-refresh }
 141     { T{ key-down f f "p" } com-push }
 142     { T{ key-down f f "e" } com-edit-slot }
 143     { T{ key-down f f "F1" } inspector-help }
 144 } define-command-map
 145
 146 inspector-gadget "multi-touch" f {
 147     { up-action com-refresh }
 148 } define-command-map
 149
 150 : inspect-model ( model -- )
 151     <inspector-gadget> "Inspector" open-status-window ;
 152
 153 : inspector ( obj -- )
 154     <model> inspect-model ;
 155
 156 inspector-gadget { 550 400 } set-tool-dim