basis/ui/tools/inspector/inspector.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors inspector namespaces kernel models fry
   4 models.filter prettyprint sequences mirrors assocs classes
   5 io io.styles arrays hashtables math.order sorting refs fonts
   6 ui.tools.browser ui.commands ui.operations ui.gadgets ui.gadgets.panes
   7 ui.gadgets.scrollers ui.gadgets.slots ui.gadgets.tracks
   8 ui.gestures ui.gadgets.buttons ui.gadgets.tables
   9 ui.gadgets.status-bar ui.gadgets.labeled
  10 ui.tools.common ui ;
  11 IN: ui.tools.inspector
  12
  13 TUPLE: inspector-gadget < tool table ;
  14
  15 { 500 300 } inspector-gadget set-tool-dim
  16
  17 TUPLE: slot-description key key-string value value-string ;
  18
  19 : <slot-description> ( key value -- slot-description )
  20     [ dup unparse-short ] bi@ slot-description boa ;
  21
  22 SINGLETON: inspector-renderer
  23
  24 M: inspector-renderer row-columns
  25     drop [ key-string>> ] [ value-string>> ] bi 2array ;
  26
  27 M: inspector-renderer row-value
  28     drop value>> ;
  29
  30 M: inspector-renderer column-titles
  31     drop { "Key" "Value" } ;
  32
  33 : <summary-gadget> ( model -- gadget )
  34     [
  35         standard-table-style [
  36             [
  37                 [
  38                     [ "Class:" write ] with-cell
  39                     [ class . ] with-cell
  40                 ] with-row
  41             ]
  42             [
  43                 [
  44                     [ "Object:" write ] with-cell
  45                     [ short. ] with-cell
  46                 ] with-row
  47             ]
  48             [
  49                 [
  50                     [ "Summary:" write ] with-cell
  51                     [ summary. ] with-cell
  52                 ] with-row
  53             ] tri
  54         ] tabular-output
  55     ] <pane-control> ;
  56
  57 GENERIC: make-slot-descriptions ( obj -- seq )
  58
  59 M: object make-slot-descriptions
  60     make-mirror [ <slot-description> ] { } assoc>map ;
  61
  62 M: hashtable make-slot-descriptions
  63     call-next-method [ [ key-string>> ] compare ] sort ;
  64
  65 : <inspector-table> ( model -- table )
  66     [ make-slot-descriptions ] <filter> inspector-renderer <table>
  67         [ dup primary-operation invoke-command ] >>action
  68         monospace-font >>font ;
  69
  70 : <inspector-gadget> ( model -- gadget )
  71     vertical inspector-gadget new-track
  72         { 3 3 } >>gap
  73         add-toolbar
  74         swap >>model
  75         dup model>> <inspector-table> >>table
  76         dup model>> <summary-gadget> "Object" <labeled-gadget> f track-add
  77         dup table>> <scroller> "Contents" <labeled-gadget> 1 track-add ;
  78
  79 M: inspector-gadget focusable-child*
  80     table>> ;
  81
  82 : com-refresh ( inspector -- )
  83     model>> notify-connections ;
  84
  85 : com-push ( inspector -- obj )
  86     control-value ;
  87
  88 \ com-push H{ { +listener+ t } } define-command
  89
  90 : slot-editor-window ( close-hook update-hook assoc key key-string -- )
  91     [ <value-ref> <slot-editor> ] [ "Slot editor: " prepend ] bi*
  92     open-window ;
  93
  94 : com-edit-slot ( inspector -- )
  95     [ close-window ] swap
  96     [ '[ _ com-refresh ] ]
  97     [ control-value make-mirror ]
  98     [ table>> (selected-row) ] tri [
  99         [ key>> ] [ key-string>> ] bi
 100         slot-editor-window
 101     ] [ 2drop 2drop ] if ;
 102
 103 : inspector-help ( -- ) "ui-inspector" com-follow ;
 104
 105 \ inspector-help H{ { +nullary+ t } } define-command
 106
 107 inspector-gadget "toolbar" f {
 108     { T{ update-object } com-refresh }
 109     { T{ key-down f f "p" } com-push }
 110     { T{ key-down f f "e" } com-edit-slot }
 111     { T{ key-down f f "F1" } inspector-help }
 112 } define-command-map
 113
 114 inspector-gadget "multi-touch" f {
 115     { up-action com-refresh }
 116 } define-command-map
 117
 118 : inspect-model ( model -- )
 119     <inspector-gadget> "Inspector" open-status-window ;
 120
 121 : inspector ( obj -- )
 122     <model> inspect-model ;