basis/ui/tools/listener/listener.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs calendar combinators locals
   4 colors.constants combinators.short-circuit compiler.units
   5 concurrency.flags concurrency.mailboxes continuations destructors
   6 documents documents.elements fry hashtables help help.markup io
   7 io.styles kernel lexer listener math models models.delay models.filter
   8 namespaces parser prettyprint quotations sequences strings threads
   9 tools.vocabs vocabs vocabs.loader vocabs.parser words ui ui.commands
  10 ui.pens.solid ui.gadgets ui.gadgets.glass ui.gadgets.buttons ui.gadgets.editors
  11 ui.gadgets.labeled ui.gadgets.panes ui.gadgets.scrollers
  12 ui.gadgets.status-bar ui.gadgets.tracks ui.gadgets.borders ui.gestures
  13 ui.operations ui.tools.browser ui.tools.common ui.tools.debugger
  14 ui.tools.listener.completion ui.tools.listener.popups
  15 ui.tools.listener.history ;
  16 IN: ui.tools.listener
  17
  18 ! If waiting is t, we're waiting for user input, and invoking
  19 ! evaluate-input resumes the thread.
  20 TUPLE: interactor < source-editor
  21 output history flag mailbox thread waiting token-model word-model popup ;
  22
  23 : register-self ( interactor -- )
  24     <mailbox> >>mailbox
  25     self >>thread
  26     drop ;
  27
  28 : interactor-continuation ( interactor -- continuation )
  29     thread>> continuation>> value>> ;
  30
  31 : interactor-busy? ( interactor -- ? )
  32     #! We're busy if there's no thread to resume.
  33     [ waiting>> ]
  34     [ thread>> dup [ thread-registered? ] when ]
  35     bi and not ;
  36
  37 SLOT: vocabs
  38
  39 M: interactor vocabs>>
  40     dup interactor-busy? [ drop f ] [
  41         use swap
  42         interactor-continuation name>>
  43         assoc-stack
  44     ] if ;
  45
  46 : vocab-exists? ( name -- ? )
  47     { [ vocab ] [ find-vocab-root ] } 1|| ;
  48
  49 GENERIC: (word-at-caret) ( token completion-mode -- obj )
  50
  51 M: vocab-completion (word-at-caret)
  52     drop dup vocab-exists? [ >vocab-link ] [ drop f ] if ;
  53
  54 M: word-completion (word-at-caret)
  55     vocabs>> assoc-stack ;
  56
  57 M: char-completion (word-at-caret)
  58     2drop f ;
  59
  60 : word-at-caret ( token interactor -- obj )
  61     completion-mode (word-at-caret) ;
  62
  63 : <word-model> ( interactor -- model )
  64     [ token-model>> 1/3 seconds <delay> ]
  65     [ '[ _ word-at-caret ] ] bi
  66     <filter> ;
  67
  68 : <interactor> ( -- gadget )
  69     interactor new-editor
  70         <flag> >>flag
  71         dup one-word-elt <element-model> >>token-model
  72         dup <word-model> >>word-model
  73         dup model>> <history> >>history ;
  74
  75 M: interactor graft*
  76     [ call-next-method ] [ dup word-model>> add-connection ] bi ;
  77
  78 M: interactor ungraft*
  79     [ dup word-model>> remove-connection ] [ call-next-method ] bi ;
  80
  81 M: interactor model-changed
  82     2dup word-model>> eq? [
  83         dup popup>>
  84         [ 2drop ] [ [ value>> ] dip show-summary ] if
  85     ] [ call-next-method ] if ;
  86
  87 GENERIC: (print-input) ( object -- )
  88
  89 M: input (print-input)
  90     dup presented associate
  91     [ string>> H{ { font-style bold } } format ] with-nesting nl ;
  92
  93 M: word (print-input)
  94     "Command: "
  95     [
  96         "sans-serif" font-name set
  97         bold font-style set
  98     ] H{ } make-assoc format . ;
  99
 100 : print-input ( object interactor -- )
 101     output>> [ (print-input) ] with-output-stream* ;
 102
 103 : interactor-continue ( obj interactor -- )
 104     mailbox>> mailbox-put ;
 105
 106 : interactor-finish ( interactor -- )
 107     [ history>> history-add ] keep
 108     [ print-input ]
 109     [ clear-editor drop ]
 110     [ model>> clear-undo drop ] 2tri ;
 111
 112 : interactor-eof ( interactor -- )
 113     dup interactor-busy? [
 114         f over interactor-continue
 115     ] unless drop ;
 116
 117 : evaluate-input ( interactor -- )
 118     dup interactor-busy? [ drop ] [
 119         [ control-value ] keep interactor-continue
 120     ] if ;
 121
 122 : interactor-yield ( interactor -- obj )
 123     dup thread>> self eq? [
 124         {
 125             [ t >>waiting drop ]
 126             [ flag>> raise-flag ]
 127             [ mailbox>> mailbox-get ]
 128             [ f >>waiting drop ]
 129         } cleave
 130     ] [ drop f ] if ;
 131
 132 : interactor-read ( interactor -- lines )
 133     [ interactor-yield ] [ interactor-finish ] bi ;
 134
 135 M: interactor stream-readln
 136     interactor-read dup [ first ] when ;
 137
 138 : (call-listener) ( quot command listener -- )
 139     input>> dup interactor-busy? [ 3drop ] [
 140         [ print-input drop ]
 141         [ nip interactor-continue ]
 142         3bi
 143     ] if ;
 144
 145 M: interactor stream-read
 146     swap dup zero? [
 147         2drop ""
 148     ] [
 149         [ interactor-read dup [ "\n" join ] when ] dip short head
 150     ] if ;
 151
 152 M: interactor stream-read-partial
 153     stream-read ;
 154
 155 M: interactor stream-read1
 156     dup interactor-read {
 157         { [ dup not ] [ 2drop f ] }
 158         { [ dup empty? ] [ drop stream-read1 ] }
 159         { [ dup first empty? ] [ 2drop CHAR: \n ] }
 160         [ nip first first ]
 161     } cond ;
 162
 163 M: interactor dispose drop ;
 164
 165 : go-to-error ( interactor error -- )
 166     [ line>> 1- ] [ column>> ] bi 2array
 167     over set-caret
 168     mark>caret ;
 169
 170 TUPLE: listener-gadget < tool input output scroller ;
 171
 172 { 600 700 } listener-gadget set-tool-dim
 173
 174 : find-listener ( gadget -- listener )
 175     [ listener-gadget? ] find-parent ;
 176
 177 : listener-streams ( listener -- input output )
 178     [ input>> ] [ output>> ] bi <pane-stream> ;
 179
 180 : init-listener ( listener -- listener )
 181     <interactor>
 182     [ >>input ] [ pane new-pane t >>scrolls? >>output ] bi
 183     dup listener-streams >>output drop ;
 184
 185 : <listener-gadget> ( -- gadget )
 186     vertical listener-gadget new-track
 187         add-toolbar
 188         init-listener
 189         dup output>> <scroller> >>scroller
 190         dup scroller>> 1 track-add ;
 191
 192 M: listener-gadget focusable-child*
 193     input>> dup popup>> or ;
 194
 195 : wait-for-listener ( listener -- )
 196     #! Wait for the listener to start.
 197     input>> flag>> wait-for-flag ;
 198
 199 : listener-busy? ( listener -- ? )
 200     input>> interactor-busy? ;
 201
 202 : listener-window* ( -- listener )
 203     <listener-gadget>
 204     dup "Listener" open-status-window ;
 205
 206 : listener-window ( -- )
 207     [ listener-window* drop ] with-ui ;
 208
 209 \ listener-window H{ { +nullary+ t } } define-command
 210
 211 : (get-listener) ( quot -- listener )
 212     find-window [
 213         [ raise-window ]
 214         [
 215             gadget-child
 216             [ ]
 217             [ input>> scroll>caret ]
 218             [ input>> request-focus ] tri
 219         ] bi
 220     ] [ listener-window* ] if* ; inline
 221
 222 : get-listener ( -- listener )
 223     [ listener-gadget? ] (get-listener) ;
 224
 225 : show-listener ( -- )
 226     get-listener drop ;
 227
 228 \ show-listener H{ { +nullary+ t } } define-command
 229
 230 : get-ready-listener ( -- listener )
 231     [
 232         {
 233             [ listener-gadget? ]
 234             [ listener-busy? not ]
 235         } 1&&
 236     ] (get-listener) ;
 237
 238 GENERIC: listener-input ( obj -- )
 239
 240 M: input listener-input string>> listener-input ;
 241
 242 M: string listener-input
 243     get-listener input>>
 244     [ set-editor-string ] [ request-focus ] bi ;
 245
 246 : call-listener ( quot command -- )
 247     get-ready-listener
 248     '[ _ _ _ dup wait-for-listener (call-listener) ]
 249     "Listener call" spawn drop ;
 250
 251 M: listener-command invoke-command ( target command -- )
 252     [ command-quot ] [ nip ] 2bi call-listener ;
 253
 254 M: listener-operation invoke-command ( target command -- )
 255     [ operation-quot ] [ nip command>> ] 2bi call-listener ;
 256
 257 : eval-listener ( string -- )
 258     get-listener input>> [ set-editor-string ] keep
 259     evaluate-input ;
 260
 261 : listener-run-files ( seq -- )
 262     [
 263         [ \ listener-run-files ] dip
 264         '[ _ [ run-file ] each ] call-listener
 265     ] unless-empty ;
 266
 267 : com-end ( listener -- )
 268     input>> interactor-eof ;
 269
 270 : clear-output ( listener -- )
 271     output>> pane-clear ;
 272
 273 \ clear-output H{ { +listener+ t } } define-command
 274
 275 : clear-stack ( listener -- )
 276     [ [ clear ] \ clear ] dip (call-listener) ;
 277
 278 : use-if-necessary ( word seq -- )
 279     2dup [ vocabulary>> ] dip and [
 280         2dup [ assoc-stack ] keep = [ 2drop ] [
 281             [ vocabulary>> vocab-words ] dip push
 282         ] if
 283     ] [ 2drop ] if ;
 284
 285 M: word accept-completion-hook
 286     interactor>> vocabs>> use-if-necessary ;
 287
 288 M: object accept-completion-hook 2drop ;
 289
 290 : quot-action ( interactor -- lines )
 291     [ history>> history-add drop ] [ control-value ] [ select-all ] tri
 292     [ parse-lines ] with-compilation-unit ;
 293
 294 : <debugger-popup> ( error continuation -- popup )
 295     over compute-restarts [ hide-glass ] <debugger> "Error" <labeled-gadget> ;
 296
 297 : debugger-popup ( interactor error continuation -- )
 298     [ one-line-elt ] 2dip <debugger-popup> show-listener-popup ;
 299
 300 : handle-parse-error ( interactor error -- )
 301     dup lexer-error? [ 2dup go-to-error error>> ] when
 302     error-continuation get
 303     debugger-popup ;
 304
 305 : try-parse ( lines interactor -- quot/error/f )
 306     [ drop parse-lines-interactive ] [
 307         2nip
 308         dup lexer-error? [
 309             dup error>> unexpected-eof? [ drop f ] when
 310         ] when
 311     ] recover ;
 312
 313 : handle-interactive ( lines interactor -- quot/f ? )
 314     [ nip ] [ try-parse ] 2bi {
 315         { [ dup quotation? ] [ nip t ] }
 316         { [ dup not ] [ drop "\n" swap user-input* drop f f ] }
 317         [ handle-parse-error f f ]
 318     } cond ;
 319
 320 M: interactor stream-read-quot
 321     [ interactor-yield ] keep {
 322         { [ over not ] [ drop ] }
 323         { [ over callable? ] [ drop ] }
 324         [
 325             [ handle-interactive ] keep swap
 326             [ interactor-finish ] [ nip stream-read-quot ] if
 327         ]
 328     } cond ;
 329
 330 : interactor-operation ( gesture interactor -- ? )
 331     [ token-model>> value>> ] keep word-at-caret
 332     [ nip ] [ gesture>operation ] 2bi dup [ invoke-command f ] [ 2drop t ] if ;
 333
 334 M: interactor handle-gesture
 335     {
 336         { [ over key-gesture? not ] [ call-next-method ] }
 337         { [ dup popup>> ] [ { [ pass-to-popup ] [ call-next-method ] } 2&& ] }
 338         { [ dup token-model>> value>> ] [ { [ interactor-operation ] [ call-next-method ] } 2&& ] }
 339         [ call-next-method ]
 340     } cond ;
 341
 342 interactor "interactor" f {
 343     { T{ key-down f f "RET" } evaluate-input }
 344     { T{ key-down f { C+ } "k" } clear-editor }
 345 } define-command-map
 346
 347 interactor "completion" f {
 348     { T{ key-down f f "TAB" } code-completion-popup }
 349     { T{ key-down f { C+ } "p" } recall-previous }
 350     { T{ key-down f { C+ } "n" } recall-next }
 351     { T{ key-down f { C+ } "r" } history-completion-popup }
 352 } define-command-map
 353
 354 : welcome. ( -- )
 355     "If this is your first time with Factor, please read the " print
 356     "handbook" ($link) ". To see a list of keyboard shortcuts," print
 357     "press F1." print nl ;
 358
 359 : listener-thread ( listener -- )
 360     dup listener-streams [
 361         [ com-browse ] help-hook set
 362         '[ [ _ input>> ] 2dip debugger-popup ] error-hook set
 363         welcome.
 364         listener
 365     ] with-streams* ;
 366
 367 : start-listener-thread ( listener -- )
 368     '[
 369         _
 370         [ input>> register-self ]
 371         [ listener-thread ]
 372         bi
 373     ] "Listener" spawn drop ;
 374
 375 : restart-listener ( listener -- )
 376     #! Returns when listener is ready to receive input.
 377     {
 378         [ com-end ]
 379         [ clear-output ]
 380         [ input>> clear-editor ]
 381         [ start-listener-thread ]
 382         [ wait-for-listener ]
 383     } cleave ;
 384
 385 : listener-help ( -- ) "ui-listener" com-browse ;
 386
 387 \ listener-help H{ { +nullary+ t } } define-command
 388
 389 : com-auto-use ( -- )
 390     auto-use? [ not ] change ;
 391
 392 \ com-auto-use H{ { +nullary+ t } { +listener+ t } } define-command
 393
 394 listener-gadget "misc" "Miscellaneous commands" {
 395     { T{ key-down f f "F1" } listener-help }
 396 } define-command-map
 397
 398 listener-gadget "toolbar" f {
 399     { f restart-listener }
 400     { T{ key-down f { A+ } "u" } com-auto-use }
 401     { T{ key-down f { A+ } "k" } clear-output }
 402     { T{ key-down f { A+ } "K" } clear-stack }
 403     { T{ key-down f { C+ } "d" } com-end }
 404 } define-command-map
 405
 406 listener-gadget "scrolling"
 407 "The listener's scroller can be scrolled from the keyboard."
 408 {
 409     { T{ key-down f { A+ } "UP" } com-scroll-up }
 410     { T{ key-down f { A+ } "DOWN" } com-scroll-down }
 411     { T{ key-down f { A+ } "PAGE_UP" } com-page-up }
 412     { T{ key-down f { A+ } "PAGE_DOWN" } com-page-down }
 413 } define-command-map
 414
 415 listener-gadget "multi-touch" f {
 416     { up-action refresh-all }
 417 } define-command-map
 418
 419 M: listener-gadget graft*
 420     [ call-next-method ] [ restart-listener ] bi ;
 421
 422 M: listener-gadget ungraft*
 423     [ com-end ] [ call-next-method ] bi ;