basis/ui/tools/traceback/traceback.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors continuations kernel models namespaces arrays
   4 fry prettyprint ui ui.commands ui.gadgets ui.gadgets.labeled assocs
   5 ui.gadgets.tracks ui.gadgets.buttons ui.gadgets.panes
   6 ui.gadgets.status-bar ui.gadgets.scrollers ui.gadgets.borders
   7 ui.gadgets.tables ui.gestures sequences inspector
   8 models.filter fonts ;
   9 QUALIFIED-WITH: ui.tools.inspector i
  10 IN: ui.tools.traceback
  11
  12 TUPLE: stack-entry object string ;
  13
  14 : <stack-entry> ( object -- stack-entry )
  15     dup unparse-short stack-entry boa ;
  16
  17 SINGLETON: stack-entry-renderer
  18
  19 M: stack-entry-renderer row-columns drop string>> 1array ;
  20
  21 M: stack-entry-renderer row-value drop object>> ;
  22
  23 : <stack-table> ( model -- table )
  24     [ [ <stack-entry> ] map ] <filter> stack-entry-renderer <table>
  25         monospace-font >>font
  26         [ i:inspector ] >>action
  27         t >>single-click? ;
  28
  29 : <stack-display> ( model quot title -- gadget )
  30     [ '[ dup _ when ] <filter> <stack-table> <scroller> ] dip
  31     <labeled-gadget> ;
  32
  33 : <callstack-display> ( model -- gadget )
  34     [ [ call>> callstack. ] when* ]
  35     <pane-control> t >>scrolls? <scroller>
  36     "Call stack" <labeled-gadget> ;
  37
  38 : <datastack-display> ( model -- gadget )
  39     [ data>> ] "Data stack" <stack-display> ;
  40
  41 : <retainstack-display> ( model -- gadget )
  42     [ retain>> ] "Retain stack" <stack-display> ;
  43
  44 TUPLE: traceback-gadget < track ;
  45
  46 M: traceback-gadget pref-dim* drop { 550 600 } ;
  47
  48 : <traceback-gadget> ( model -- gadget )
  49     [
  50         vertical traceback-gadget new-track
  51         { 3 3 } >>gap
  52     ] dip
  53     [ >>model ]
  54     [
  55         [ vertical <track> { 3 3 } >>gap ] dip
  56         [
  57             [ horizontal <track> { 3 3 } >>gap ] dip
  58             [ <datastack-display> 1/2 track-add ]
  59             [ <retainstack-display> 1/2 track-add ] bi
  60             1/3 track-add
  61         ]
  62         [ <callstack-display> 2/3 track-add ] bi
  63         { 3 3 } <filled-border> 1 track-add
  64     ] bi
  65     add-toolbar ;
  66
  67 : variables ( traceback -- )
  68     model>> [ dup [ name>> vars-in-scope ] when ] <filter> i:inspect-model ;
  69
  70 : traceback-window ( continuation -- )
  71     <model> <traceback-gadget> "Traceback" open-status-window ;
  72
  73 : inspect-continuation ( traceback -- )
  74     control-value i:inspector ;
  75
  76 traceback-gadget "toolbar" f {
  77     { T{ key-down f f "v" } variables }
  78     { T{ key-down f f "n" } inspect-continuation }
  79 } define-command-map