basis/ui/tools/traceback/traceback.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors continuations kernel models namespaces arrays
   4 fry prettyprint ui ui.commands ui.gadgets ui.gadgets.labelled assocs
   5 ui.gadgets.tracks ui.gadgets.buttons ui.gadgets.panes
   6 ui.gadgets.status-bar ui.gadgets.scrollers
   7 ui.gadgets.tables ui.gestures sequences inspector
   8 models.filter fonts ;
   9 QUALIFIED-WITH: ui.tools.inspector i
  10 IN: ui.tools.traceback
  11
  12 TUPLE: stack-entry object string ;
  13
  14 : <stack-entry> ( object -- stack-entry )
  15     dup unparse-short stack-entry boa ;
  16
  17 SINGLETON: stack-entry-renderer
  18
  19 M: stack-entry-renderer row-columns drop string>> 1array ;
  20
  21 M: stack-entry-renderer row-value drop object>> ;
  22
  23 : <stack-table> ( model -- table )
  24     [ [ <stack-entry> ] map ] <filter> <table>
  25         monospace-font >>font
  26         [ i:inspector ] >>action
  27         stack-entry-renderer >>renderer
  28         t >>single-click? ;
  29
  30 : <stack-display> ( model quot title -- gadget )
  31     [ '[ dup _ when ] <filter> <stack-table> <scroller> ] dip
  32     <labelled-gadget> ;
  33
  34 : <callstack-display> ( model -- gadget )
  35     [ [ call>> callstack. ] when* ]
  36     t "Call stack" <labelled-pane> ;
  37
  38 : <datastack-display> ( model -- gadget )
  39     [ data>> ] "Data stack" <stack-display> ;
  40
  41 : <retainstack-display> ( model -- gadget )
  42     [ retain>> ] "Retain stack" <stack-display> ;
  43
  44 TUPLE: traceback-gadget < track ;
  45
  46 M: traceback-gadget pref-dim* drop { 550 600 } ;
  47
  48 : <traceback-gadget> ( model -- gadget )
  49     [ vertical traceback-gadget new-track ] dip
  50     [ >>model ]
  51     [
  52         [ horizontal <track> ] dip
  53         [ <datastack-display> 1/2 track-add ]
  54         [ <retainstack-display> 1/2 track-add ] bi
  55         1/3 track-add
  56     ]
  57     [ <callstack-display> 2/3 track-add ] tri
  58     add-toolbar ;
  59
  60 : variables ( traceback -- )
  61     model>> [ dup [ name>> vars-in-scope ] when ] <filter> i:inspect-model ;
  62
  63 : traceback-window ( continuation -- )
  64     <model> <traceback-gadget> "Traceback" open-status-window ;
  65
  66 : inspect-continuation ( traceback -- )
  67     control-value i:inspector ;
  68
  69 traceback-gadget "toolbar" f {
  70     { T{ key-down f f "v" } variables }
  71     { T{ key-down f f "n" } inspect-continuation }
  72 } define-command-map