basis/ui/tools/traceback/traceback.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors continuations kernel models namespaces arrays
   4 fry prettyprint ui ui.commands ui.gadgets ui.gadgets.labelled assocs
   5 ui.gadgets.tracks ui.gadgets.buttons ui.gadgets.panes
   6 ui.gadgets.status-bar ui.gadgets.scrollers ui.gadgets.borders
   7 ui.gadgets.tables ui.gestures sequences inspector
   8 models.filter fonts ;
   9 QUALIFIED-WITH: ui.tools.inspector i
  10 IN: ui.tools.traceback
  11
  12 TUPLE: stack-entry object string ;
  13
  14 : <stack-entry> ( object -- stack-entry )
  15     dup unparse-short stack-entry boa ;
  16
  17 SINGLETON: stack-entry-renderer
  18
  19 M: stack-entry-renderer row-columns drop string>> 1array ;
  20
  21 M: stack-entry-renderer row-value drop object>> ;
  22
  23 : <stack-table> ( model -- table )
  24     [ [ <stack-entry> ] map ] <filter> <table>
  25         monospace-font >>font
  26         [ i:inspector ] >>action
  27         stack-entry-renderer >>renderer
  28         t >>single-click? ;
  29
  30 : <stack-display> ( model quot title -- gadget )
  31     [ '[ dup _ when ] <filter> <stack-table> <scroller> ] dip
  32     <labelled-gadget> ;
  33
  34 : <callstack-display> ( model -- gadget )
  35     [ [ call>> callstack. ] when* ]
  36     <pane-control> t >>scrolls? <scroller>
  37     "Call stack" <labelled-gadget> ;
  38
  39 : <datastack-display> ( model -- gadget )
  40     [ data>> ] "Data stack" <stack-display> ;
  41
  42 : <retainstack-display> ( model -- gadget )
  43     [ retain>> ] "Retain stack" <stack-display> ;
  44
  45 TUPLE: traceback-gadget < track ;
  46
  47 M: traceback-gadget pref-dim* drop { 550 600 } ;
  48
  49 : <traceback-gadget> ( model -- gadget )
  50     [
  51         vertical traceback-gadget new-track
  52         { 3 3 } >>gap
  53     ] dip
  54     [ >>model ]
  55     [
  56         [ vertical <track> { 3 3 } >>gap ] dip
  57         [
  58             [ horizontal <track> { 3 3 } >>gap ] dip
  59             [ <datastack-display> 1/2 track-add ]
  60             [ <retainstack-display> 1/2 track-add ] bi
  61             1/3 track-add
  62         ]
  63         [ <callstack-display> 2/3 track-add ] bi
  64         { 3 3 } <filled-border> 1 track-add
  65     ] bi
  66     add-toolbar ;
  67
  68 : variables ( traceback -- )
  69     model>> [ dup [ name>> vars-in-scope ] when ] <filter> i:inspect-model ;
  70
  71 : traceback-window ( continuation -- )
  72     <model> <traceback-gadget> "Traceback" open-status-window ;
  73
  74 : inspect-continuation ( traceback -- )
  75     control-value i:inspector ;
  76
  77 traceback-gadget "toolbar" f {
  78     { T{ key-down f f "v" } variables }
  79     { T{ key-down f f "n" } inspect-continuation }
  80 } define-command-map