basis/ui/ui.factor

   1 ! Copyright (C) 2006, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs boxes classes.tuple
   4 classes.tuple.parser combinators combinators.short-circuit
   5 concurrency.flags concurrency.promises continuations deques
   6 destructors dlists fry init kernel lexer make math namespaces
   7 parser sequences sets strings threads ui.backend ui.gadgets
   8 ui.gadgets.private ui.gadgets.worlds ui.gestures vocabs.parser
   9 words ;
  10 IN: ui
  11
  12 <PRIVATE
  13
  14 ! Assoc mapping aliens to gadgets
  15 SYMBOL: ui-windows
  16
  17 : window ( handle -- world ) ui-windows get-global at ;
  18
  19 : register-window ( world handle -- )
  20     ! Add the new window just below the topmost window. Why?
  21     ! So that if the new window doesn't actually receive focus
  22     ! (eg, we're using focus follows mouse and the mouse is not
  23     ! in the new window when it appears) Factor doesn't get
  24     ! confused and send workspace operations to the new window,
  25     ! etc.
  26     swap 2array ui-windows get-global push
  27     ui-windows get-global dup length 1 >
  28     [ [ length 1 - dup 1 - ] keep exchange ] [ drop ] if ;
  29
  30 : unregister-window ( handle -- )
  31     ui-windows [ [ first = ] with reject ] change-global ;
  32
  33 : raised-window ( world -- )
  34     ui-windows get-global
  35     [ [ second eq? ] with find drop ] keep
  36     [ nth ] [ remove-nth! drop ] [ nip ] 2tri push ;
  37
  38 : focus-gestures ( new old -- )
  39     drop-prefix <reversed>
  40     lose-focus swap each-gesture
  41     gain-focus swap each-gesture ;
  42
  43 : ?grab-input ( world -- )
  44     dup grab-input?>> [ handle>> (grab-input) ] [ drop ] if ;
  45
  46 : ?ungrab-input ( world -- )
  47     dup grab-input?>> [ handle>> (ungrab-input) ] [ drop ] if ;
  48
  49 : focus-world ( world -- )
  50     t >>focused?
  51     [ ?grab-input ] [
  52         dup raised-window
  53         focus-path f focus-gestures
  54     ] bi ;
  55
  56 : unfocus-world ( world -- )
  57     f >>focused?
  58     [ ?ungrab-input ]
  59     [ focus-path f swap focus-gestures ] bi ;
  60
  61 : set-up-window ( world -- )
  62     {
  63         [ set-gl-context ]
  64         [ [ title>> ] keep set-title ]
  65         [ begin-world ]
  66         [ resize-world ]
  67         [ t >>active? drop ]
  68         [ request-focus ]
  69     } cleave ;
  70
  71 : clean-up-broken-window ( world -- )
  72     [
  73         dup { [ focused?>> ] [ grab-input?>> ] } 1&&
  74         [ handle>> (ungrab-input) ] [ drop ] if
  75     ] [ handle>> (close-window) ] bi ;
  76
  77 M: world graft*
  78     [ (open-window) ]
  79     [
  80         [ set-up-window ]
  81         [ [ clean-up-broken-window ] [ ui-error ] bi* ] recover
  82     ] bi ;
  83
  84 : dispose-window-resources ( world -- )
  85     [ <reversed> [ [ dispose ] when* ] each V{ } clone ] change-window-resources drop ;
  86
  87 M: world ungraft*
  88     {
  89         [ set-gl-context ]
  90         [ text-handle>> [ dispose ] when* ]
  91         [ images>> [ dispose ] when* ]
  92         [ hand-clicked close-global ]
  93         [ hand-gadget close-global ]
  94         [ end-world ]
  95         [ dispose-window-resources ]
  96         [ unfocus-world ]
  97         [ [ (close-window) f ] change-handle drop ]
  98         [ promise>> t swap fulfill ]
  99     } cleave ;
 100
 101 : init-ui ( -- )
 102     <box> drag-timer set-global
 103     f hand-gadget set-global
 104     f hand-clicked set-global
 105     f hand-world set-global
 106     f world set-global
 107     <dlist> \ graft-queue set-global
 108     <dlist> \ layout-queue set-global
 109     <dlist> \ gesture-queue set-global
 110     V{ } clone ui-windows set-global ;
 111
 112 : update-hand ( world -- )
 113     dup hand-world get-global eq?
 114     [ hand-loc get-global swap move-hand ] [ drop ] if ;
 115
 116 : (layout-queued) ( deque -- seq )
 117     [
 118         in-layout? on
 119         [
 120             dup layout find-world [ , ] when*
 121         ] slurp-deque
 122     ] { } make members ; inline
 123
 124 : layout-queued ( -- seq )
 125     layout-queue dup deque-empty?
 126     [ drop { } ] [ (layout-queued) ] if ;
 127
 128 : redraw-worlds ( seq -- )
 129     [ dup update-hand draw-world ] each ;
 130
 131 : send-queued-gestures ( -- )
 132     gesture-queue [ send-queued-gesture notify-queued ] slurp-deque ;
 133
 134 : update-ui ( -- )
 135     notify-queued
 136     layout-queued
 137     redraw-worlds
 138     send-queued-gestures ;
 139
 140 SYMBOL: ui-thread
 141
 142 : ui-running ( quot -- )
 143     t \ ui-running set-global
 144     [ f \ ui-running set-global ] [ ] cleanup ; inline
 145
 146 PRIVATE>
 147
 148 : find-window ( quot: ( world -- ? ) -- world )
 149     [ ui-windows get-global values ] dip
 150     '[ dup children>> [ ] [ nip first ] if-empty @ ]
 151     find-last nip ; inline
 152
 153 : ui-running? ( -- ? )
 154     \ ui-running get-global ;
 155
 156 <PRIVATE
 157
 158 : update-ui-loop ( -- )
 159     ! Note the logic: if update-ui fails, we open an error window
 160     ! and run one iteration of update-ui. If that also fails, well,
 161     ! the whole UI subsystem is broken so we exit out of the
 162     ! update-ui-loop.
 163     [ { [ ui-running? ] [ ui-thread get-global self eq? ] } 0&& ]
 164     [
 165         ui-notify-flag get lower-flag
 166         [ update-ui ] [ ui-error update-ui ] recover
 167     ] while ;
 168
 169 : start-ui-thread ( -- )
 170     [ self ui-thread set-global update-ui-loop ]
 171     "UI update" spawn drop ;
 172
 173 : start-ui ( quot -- )
 174     call( -- ) notify-ui-thread start-ui-thread ;
 175
 176 : ?attributes ( gadget title/attributes -- attributes )
 177     dup string? [ <world-attributes> swap >>title ] [ clone ] if
 178     swap [ [ [ 1array ] [ f ] if* ] curry unless* ] curry change-gadgets ;
 179
 180 PRIVATE>
 181
 182 : open-world-window ( world -- )
 183     dup pref-dim >>dim dup relayout graft ;
 184
 185 : open-window* ( gadget title/attributes -- window )
 186     ?attributes <world> [ open-world-window ] keep ;
 187
 188 : open-window ( gadget title/attributes -- )
 189     open-window* drop ;
 190
 191 : set-fullscreen ( gadget ? -- )
 192     [ find-world ] dip (set-fullscreen) ;
 193
 194 : fullscreen? ( gadget -- ? )
 195     find-world (fullscreen?) ;
 196
 197 : toggle-fullscreen ( gadget -- )
 198     dup fullscreen? not set-fullscreen ;
 199
 200 : raise-window ( gadget -- )
 201     find-world raise-window* ;
 202
 203 : topmost-window ( -- world )
 204     ui-windows get-global last second ;
 205
 206 HOOK: close-window ui-backend ( gadget -- )
 207
 208 M: object close-window
 209     find-world [ ungraft ] when* ;
 210
 211 [
 212     f \ ui-running set-global
 213     <flag> ui-notify-flag set-global
 214 ] "ui" add-startup-hook
 215
 216 HOOK: resize-window ui-backend ( world dim -- )
 217 M: object resize-window 2drop ;
 218
 219 : relayout-window ( gadget -- )
 220     [ relayout ]
 221     [ find-world [ dup pref-dim resize-window ] when* ] bi ;
 222
 223 : with-ui ( quot: ( -- ) -- )
 224     ui-running? [ call( -- ) ] [ '[ init-ui @ ] (with-ui) ] if ;
 225
 226 HOOK: beep ui-backend ( -- )
 227
 228 HOOK: system-alert ui-backend ( caption text -- )
 229
 230 : parse-main-window-attributes ( class -- attributes )
 231     "{" expect dup all-slots parse-tuple-literal-slots ;
 232
 233 : define-main-window ( word attributes quot -- )
 234     [
 235         '[ [ f _ clone @ open-window ] with-ui ] ( -- ) define-declared
 236     ] [ 2drop current-vocab main<< ] 3bi ;
 237
 238 SYNTAX: MAIN-WINDOW:
 239     scan-new-word
 240     world-attributes parse-main-window-attributes
 241     parse-definition
 242     define-main-window ;