basis/ui/ui.factor

   1 ! Copyright (C) 2006, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs boxes classes.tuple
   4 classes.tuple.parser combinators combinators.short-circuit
   5 concurrency.flags concurrency.promises continuations deques
   6 destructors dlists fry init kernel lexer make math namespaces
   7 parser sequences sets strings threads ui.backend ui.gadgets
   8 ui.gadgets.private ui.gadgets.worlds ui.gestures vocabs.parser
   9 words ;
  10 IN: ui
  11
  12 <PRIVATE
  13
  14 ! Assoc mapping aliens to gadgets
  15 SYMBOL: windows
  16
  17 : window ( handle -- world ) windows get-global at ;
  18
  19 : register-window ( world handle -- )
  20     #! Add the new window just below the topmost window. Why?
  21     #! So that if the new window doesn't actually receive focus
  22     #! (eg, we're using focus follows mouse and the mouse is not
  23     #! in the new window when it appears) Factor doesn't get
  24     #! confused and send workspace operations to the new window,
  25     #! etc.
  26     swap 2array windows get-global push
  27     windows get-global dup length 1 >
  28     [ [ length 1 - dup 1 - ] keep exchange ] [ drop ] if ;
  29
  30 : unregister-window ( handle -- )
  31     windows [ [ first = not ] with filter ] change-global ;
  32
  33 : raised-window ( world -- )
  34     windows get-global
  35     [ [ second eq? ] with find drop ] keep
  36     [ nth ] [ remove-nth! drop ] [ nip ] 2tri push ;
  37
  38 : focus-gestures ( new old -- )
  39     drop-prefix <reversed>
  40     lose-focus swap each-gesture
  41     gain-focus swap each-gesture ;
  42
  43 : ?grab-input ( world -- )
  44     dup grab-input?>> [ handle>> (grab-input) ] [ drop ] if ;
  45
  46 : ?ungrab-input ( world -- )
  47     dup grab-input?>> [ handle>> (ungrab-input) ] [ drop ] if ;
  48
  49 : focus-world ( world -- )
  50     t >>focused?
  51     [ ?grab-input ] [
  52         dup raised-window
  53         focus-path f focus-gestures
  54     ] bi ;
  55
  56 : unfocus-world ( world -- )
  57     f >>focused?
  58     [ ?ungrab-input ]
  59     [ focus-path f swap focus-gestures ] bi ;
  60
  61 : set-up-window ( world -- )
  62     {
  63         [ set-gl-context ]
  64         [ [ title>> ] keep set-title ]
  65         [ begin-world ]
  66         [ resize-world ]
  67         [ t >>active? drop ]
  68         [ request-focus ]
  69     } cleave ;
  70
  71 : clean-up-broken-window ( world -- )
  72     [
  73         dup { [ focused?>> ] [ grab-input?>> ] } 1&&
  74         [ handle>> (ungrab-input) ] [ drop ] if
  75     ] [ handle>> (close-window) ] bi ;
  76
  77 M: world graft*
  78     [ (open-window) ]
  79     [
  80         [ set-up-window ]
  81         [ [ clean-up-broken-window ] [ ui-error ] bi* ] recover
  82     ] bi ;
  83
  84 : dispose-window-resources ( world -- )
  85     [ <reversed> [ [ dispose ] when* ] each V{ } clone ] change-window-resources drop ;
  86
  87 M: world ungraft*
  88     {
  89         [ set-gl-context ]
  90         [ text-handle>> [ dispose ] when* ]
  91         [ images>> [ dispose ] when* ]
  92         [ hand-clicked close-global ]
  93         [ hand-gadget close-global ]
  94         [ end-world ]
  95         [ dispose-window-resources ]
  96         [ unfocus-world ]
  97         [ [ (close-window) f ] change-handle drop ]
  98         [ promise>> t swap fulfill ]
  99     } cleave ;
 100
 101 : init-ui ( -- )
 102     <box> drag-timer set-global
 103     f hand-gadget set-global
 104     f hand-clicked set-global
 105     f hand-world set-global
 106     f world set-global
 107     <dlist> \ graft-queue set-global
 108     <dlist> \ layout-queue set-global
 109     <dlist> \ gesture-queue set-global
 110     V{ } clone windows set-global ;
 111
 112 : update-hand ( world -- )
 113     dup hand-world get-global eq?
 114     [ hand-loc get-global swap move-hand ] [ drop ] if ;
 115
 116 : layout-queued ( -- seq )
 117     [
 118         in-layout? on
 119         layout-queue [
 120             dup layout find-world [ , ] when*
 121         ] slurp-deque
 122     ] { } make members ;
 123
 124 : redraw-worlds ( seq -- )
 125     [ dup update-hand draw-world ] each ;
 126
 127 : send-queued-gestures ( -- )
 128     gesture-queue [ send-queued-gesture notify-queued ] slurp-deque ;
 129
 130 : update-ui ( -- )
 131     notify-queued
 132     layout-queued
 133     redraw-worlds
 134     send-queued-gestures ;
 135
 136 SYMBOL: ui-thread
 137
 138 : ui-running ( quot -- )
 139     t \ ui-running set-global
 140     [ f \ ui-running set-global ] [ ] cleanup ; inline
 141
 142 PRIVATE>
 143
 144 : find-window ( quot -- world )
 145     [ windows get values ] dip
 146     '[ dup children>> [ ] [ nip first ] if-empty @ ]
 147     find-last nip ; inline
 148
 149 : ui-running? ( -- ? )
 150     \ ui-running get-global ;
 151
 152 <PRIVATE
 153
 154 : update-ui-loop ( -- )
 155     #! Note the logic: if update-ui fails, we open an error window
 156     #! and run one iteration of update-ui. If that also fails, well,
 157     #! the whole UI subsystem is broken so we exit out of the
 158     #! update-ui-loop.
 159     [ { [ ui-running? ] [ ui-thread get-global self eq? ] } 0&& ]
 160     [
 161         ui-notify-flag get lower-flag
 162         [ update-ui ] [ ui-error update-ui ] recover
 163     ] while ;
 164
 165 : start-ui-thread ( -- )
 166     [ self ui-thread set-global update-ui-loop ]
 167     "UI update" spawn drop ;
 168
 169 : start-ui ( quot -- )
 170     call( -- ) notify-ui-thread start-ui-thread ;
 171
 172 : ?attributes ( gadget title/attributes -- attributes )
 173     dup string? [ world-attributes new swap >>title ] [ clone ] if
 174     swap [ [ [ 1array ] [ f ] if* ] curry unless* ] curry change-gadgets ;
 175
 176 PRIVATE>
 177
 178 : open-world-window ( world -- )
 179     dup pref-dim >>dim dup relayout graft ;
 180
 181 : open-window* ( gadget title/attributes -- window )
 182     ?attributes <world> [ open-world-window ] keep ;
 183
 184 : open-window ( gadget title/attributes -- )
 185     open-window* drop ;
 186
 187 : set-fullscreen ( gadget ? -- )
 188     [ find-world ] dip (set-fullscreen) ;
 189
 190 : fullscreen? ( gadget -- ? )
 191     find-world (fullscreen?) ;
 192
 193 : toggle-fullscreen ( gadget -- )
 194     dup fullscreen? not set-fullscreen ;
 195
 196 : raise-window ( gadget -- )
 197     find-world raise-window* ;
 198
 199 : topmost-window ( -- world )
 200     windows get last second ;
 201
 202 HOOK: close-window ui-backend ( gadget -- )
 203
 204 M: object close-window
 205     find-world [ ungraft ] when* ;
 206
 207 [
 208     f \ ui-running set-global
 209     <flag> ui-notify-flag set-global
 210 ] "ui" add-startup-hook
 211
 212 : with-ui ( quot: ( -- ) -- )
 213     ui-running? [ call( -- ) ] [ '[ init-ui @ ] (with-ui) ] if ;
 214
 215 HOOK: beep ui-backend ( -- )
 216
 217 HOOK: system-alert ui-backend ( caption text -- )
 218
 219 : parse-main-window-attributes ( class -- attributes )
 220     "{" expect dup all-slots parse-tuple-literal-slots ;
 221
 222 : define-main-window ( word attributes quot -- )
 223     [
 224         '[ [ f _ clone @ open-window ] with-ui ] (( -- )) define-declared
 225     ] [ 2drop current-vocab main<< ] 3bi ;
 226
 227 SYNTAX: MAIN-WINDOW:
 228     CREATE
 229     world-attributes parse-main-window-attributes
 230     parse-definition
 231     define-main-window ;