]> gitweb.factorcode.org Git - factor.git/blob - basis/unix/groups/groups.factor
Merge branch 'master' of git://factorcode.org/git/factor
[factor.git] / basis / unix / groups / groups.factor
1 ! Copyright (C) 2008 Doug Coleman.
2 ! See http://factorcode.org/license.txt for BSD license.
3 USING: alien alien.c-types alien.strings io.encodings.utf8
4 io.unix.backend kernel math sequences splitting unix strings
5 combinators.short-circuit byte-arrays combinators qualified
6 accessors math.parser fry assocs namespaces continuations
7 unix.users ;
8 IN: unix.groups
9
10 QUALIFIED: grouping
11
12 TUPLE: group id name passwd members ;
13
14 SYMBOL: group-cache
15
16 GENERIC: group-struct ( obj -- group )
17
18 <PRIVATE
19
20 : group-members ( group-struct -- seq )
21     group-gr_mem
22     [ dup { [ ] [ *void* ] } 1&& ]
23     [
24         dup *void* utf8 alien>string
25         [ alien-address "char**" heap-size + <alien> ] dip
26     ] [ ] produce nip ;
27
28 : (group-struct) ( id -- group-struct id group-struct byte-array length void* )
29     "group" <c-object> tuck 1024
30     [ <byte-array> ] keep f <void*> ;
31
32 M: integer group-struct ( id -- group )
33     (group-struct) getgrgid_r io-error ;
34
35 M: string group-struct ( string -- group )
36     (group-struct) getgrnam_r 0 = [ (io-error) ] unless ;
37
38 : group-struct>group ( group-struct -- group )
39     [ \ group new ] dip
40     {
41         [ group-gr_name >>name ]
42         [ group-gr_passwd >>passwd ]
43         [ group-gr_gid >>id ]
44         [ group-members >>members ]
45     } cleave ;
46
47 PRIVATE>
48
49 : group-name ( id -- string )
50     dup group-cache get [
51         at
52     ] [
53         group-struct group-gr_name
54     ] if*
55     [ nip ] [ number>string ] if* ;
56
57 : group-id ( string -- id )
58     group-struct group-gr_gid ;
59
60 <PRIVATE
61
62 : >groups ( byte-array n -- groups )
63     [ 4 grouping:group ] dip head-slice [ *uint group-name ] map ;
64
65 : (user-groups) ( string -- seq )
66     #! first group is -1337, legacy unix code
67     -1337 NGROUPS_MAX [ 4 * <byte-array> ] keep
68     <int> [ getgrouplist io-error ] 2keep
69     [ 4 tail-slice ] [ *int 1- ] bi* >groups ;
70
71 PRIVATE>
72     
73 GENERIC: user-groups ( string/id -- seq )
74
75 M: string user-groups ( string -- seq )
76     (user-groups) ; 
77
78 M: integer user-groups ( id -- seq )
79     username (user-groups) ;
80     
81 : all-groups ( -- seq )
82     [ getgrent dup ] [ group-struct>group ] [ drop ] produce ;
83
84 : with-group-cache ( quot -- )
85     all-groups [ [ id>> ] keep ] H{ } map>assoc
86     group-cache rot with-variable ; inline
87
88 : real-group-id ( -- id )
89     getgid ; inline
90
91 : real-group-name ( -- string )
92     real-group-id group-name ; inline
93
94 : effective-group-id ( -- string )
95     getegid ; inline
96
97 : effective-group-name ( -- string )
98     effective-group-id group-name ; inline
99
100 GENERIC: set-real-group ( obj -- )
101
102 GENERIC: set-effective-group ( obj -- )
103
104 : with-real-group ( string/id quot -- )
105     '[ _ set-real-group @ ]
106     real-group-id '[ _ set-real-group ] [ ] cleanup ; inline
107
108 : with-effective-group ( string/id quot -- )
109     '[ _ set-effective-group @ ]
110     effective-group-id '[ _ set-effective-group ] [ ] cleanup ; inline
111
112 <PRIVATE
113
114 : (set-real-group) ( id -- )
115     setgid io-error ; inline
116
117 : (set-effective-group) ( id -- )
118     setegid io-error ; inline
119
120 PRIVATE>
121     
122 M: string set-real-group ( string -- )
123     group-id (set-real-group) ;
124
125 M: integer set-real-group ( id -- )
126     (set-real-group) ;
127
128 M: integer set-effective-group ( id -- )    
129     (set-effective-group) ;
130
131 M: string set-effective-group ( string -- )
132     group-id (set-effective-group) ;