basis/windows/com/com.factor

   1 USING: alien alien.c-types alien.destructors windows.com.syntax
   2 windows.ole32 windows.types continuations kernel alien.syntax
   3 libc destructors accessors alien.data classes.struct windows.kernel32 ;
   4 IN: windows.com
   5
   6 LIBRARY: ole32
   7
   8 COM-INTERFACE: IUnknown f {00000000-0000-0000-C000-000000000046}
   9     HRESULT QueryInterface ( REFGUID iid, void** ppvObject )
  10     ULONG AddRef ( )
  11     ULONG Release ( ) ;
  12
  13 C-TYPE: IAdviseSink
  14 C-TYPE: IEnumFORMATETC
  15 C-TYPE: IEnumSTATDATA
  16
  17 COM-INTERFACE: IDataObject IUnknown {0000010E-0000-0000-C000-000000000046}
  18     HRESULT GetData ( FORMATETC* pFormatetc, STGMEDIUM* pmedium )
  19     HRESULT GetDataHere ( FORMATETC* pFormatetc, STGMEDIUM* pmedium )
  20     HRESULT QueryGetData ( FORMATETC* pFormatetc )
  21     HRESULT GetCanonicalFormatEtc ( FORMATETC* pFormatetcIn, FORMATETC* pFormatetcOut )
  22     HRESULT SetData ( FORMATETC* pFormatetc, STGMEDIUM* pmedium, BOOL fRelease )
  23     HRESULT EnumFormatEtc ( DWORD dwDirection, IEnumFORMATETC** ppenumFormatetc )
  24     HRESULT DAdvise ( FORMATETC* pFormatetc, DWORD advf, IAdviseSink* pAdvSink, DWORD* pdwConnection )
  25     HRESULT DUnadvise ( DWORD pdwConnection )
  26     HRESULT EnumDAdvise ( IEnumSTATDATA** ppenumAdvise ) ;
  27
  28 COM-INTERFACE: IDropTarget IUnknown {00000122-0000-0000-C000-000000000046}
  29     HRESULT DragEnter ( IDataObject* pDataObject, DWORD grfKeyState, POINTL pt, DWORD* pdwEffect )
  30     HRESULT DragOver ( DWORD grfKeyState, POINTL pt, DWORD* pdwEffect )
  31     HRESULT DragLeave ( )
  32     HRESULT Drop ( IDataObject* pDataObject, DWORD grfKeyState, POINTL pt, DWORD* pdwEffect ) ;
  33
  34 COM-INTERFACE: ISequentialStream IUnknown {0C733A30-2A1C-11CE-ADE5-00AA0044773D}
  35     HRESULT Read ( void* pv, ULONG cb, ULONG* pcbRead )
  36     HRESULT Write ( void* pv, ULONG cb, ULONG* pcbWritten ) ;
  37
  38 STRUCT: STATSTG
  39     { pwcsName LPOLESTR }
  40     { type DWORD }
  41     { cbSize ULARGE_INTEGER }
  42     { mtime FILETIME }
  43     { ctime FILETIME }
  44     { atime FILETIME }
  45     { grfMode DWORD }
  46     { grfLocksSupported DWORD }
  47     { clsid CLSID }
  48     { grfStateBits DWORD }
  49     { reserved DWORD } ;
  50
  51 CONSTANT: STGTY_STORAGE   1
  52 CONSTANT: STGTY_STREAM    2
  53 CONSTANT: STGTY_LOCKBYTES 3
  54 CONSTANT: STGTY_PROPERTY  4
  55
  56 CONSTANT: STREAM_SEEK_SET 0
  57 CONSTANT: STREAM_SEEK_CUR 1
  58 CONSTANT: STREAM_SEEK_END 2
  59
  60 CONSTANT: LOCK_WRITE     1
  61 CONSTANT: LOCK_EXCLUSIVE 2
  62 CONSTANT: LOCK_ONLYONCE  4
  63
  64 COM-INTERFACE: IStream ISequentialStream {0000000C-0000-0000-C000-000000000046}
  65     HRESULT Seek ( LARGE_INTEGER dlibMove, DWORD dwOrigin, ULARGE_INTEGER* plibNewPosition )
  66     HRESULT SetSize ( ULARGE_INTEGER* libNewSize )
  67     HRESULT CopyTo ( IStream* pstm, ULARGE_INTEGER* cb, ULARGE_INTEGER* pcbRead, ULARGE_INTEGER* pcbWritten )
  68     HRESULT Commit ( DWORD grfCommitFlags )
  69     HRESULT Revert ( )
  70     HRESULT LockRegion ( ULARGE_INTEGER libOffset, ULARGE_INTEGER cb, DWORD dwLockType )
  71     HRESULT UnlockRegion ( ULARGE_INTEGER libOffset, ULARGE_INTEGER cb, DWORD dwLockType )
  72     HRESULT Stat ( STATSTG* pstatstg, DWORD grfStatFlag )
  73     HRESULT Clone ( IStream** ppstm ) ;
  74
  75 FUNCTION: HRESULT RegisterDragDrop ( HWND hWnd, IDropTarget* pDropTarget ) ;
  76 FUNCTION: HRESULT RevokeDragDrop ( HWND hWnd ) ;
  77 FUNCTION: void ReleaseStgMedium ( LPSTGMEDIUM pmedium ) ;
  78
  79 : com-query-interface ( interface iid -- interface' )
  80     [
  81         void* malloc-object &free
  82         [ IUnknown::QueryInterface ole32-error ] keep *void*
  83     ] with-destructors ;
  84
  85 : com-add-ref ( interface -- interface )
  86      [ IUnknown::AddRef drop ] keep ; inline
  87
  88 : com-release ( interface -- )
  89     IUnknown::Release drop ; inline
  90
  91 : with-com-interface ( interface quot -- )
  92     over [ com-release ] curry [ ] cleanup ; inline
  93
  94 DESTRUCTOR: com-release
  95
  96