basis/windows/com/wrapper/wrapper.factor

   1 USING: alien alien.c-types alien.data alien.accessors
   2 windows.com.syntax init windows.com.syntax.private windows.com
   3 continuations kernel namespaces windows.ole32 libc vocabs
   4 assocs accessors arrays sequences quotations combinators math
   5 words compiler.units destructors fry math.parser generalizations
   6 sets specialized-arrays windows.kernel32 classes.struct ;
   7 SPECIALIZED-ARRAY: void*
   8 IN: windows.com.wrapper
   9
  10 TUPLE: com-wrapper < disposable callbacks vtbls ;
  11
  12 <PRIVATE
  13
  14 SYMBOL: +wrapped-objects+
  15 +wrapped-objects+ get-global
  16 [ H{ } +wrapped-objects+ set-global ]
  17 unless
  18
  19 SYMBOL: +live-wrappers+
  20 +live-wrappers+ get-global
  21 [ V{ } +live-wrappers+ set-global ]
  22 unless
  23
  24 SYMBOL: +vtbl-counter+
  25 +vtbl-counter+ get-global
  26 [ 0 +vtbl-counter+ set-global ]
  27 unless
  28
  29 "windows.com.wrapper.callbacks" create-vocab drop
  30
  31 : (next-vtbl-counter) ( -- n )
  32     +vtbl-counter+ [ 1 + dup ] change ;
  33
  34 : com-unwrap ( wrapped -- object )
  35     +wrapped-objects+ get-global at*
  36     [ "invalid COM wrapping pointer" throw ] unless ;
  37
  38 : (free-wrapped-object) ( wrapped -- )
  39     [ +wrapped-objects+ get-global delete-at ] keep
  40     free ;
  41
  42 : (query-interface-cases) ( interfaces -- cases )
  43     [
  44         [ find-com-interface-definition family-tree [ iid>> ] map ] dip
  45         1quotation [ 2array ] curry map
  46     ] map-index concat
  47     [ drop f ] suffix ;
  48
  49 : (make-query-interface) ( interfaces -- quot )
  50     (query-interface-cases)
  51     '[
  52         swap _ case
  53         [
  54             void* heap-size * rot <displaced-alien> com-add-ref
  55             swap 0 set-alien-cell S_OK
  56         ] [ nip f swap 0 set-alien-cell E_NOINTERFACE ] if*
  57     ] ;
  58
  59 : (make-add-ref) ( interfaces -- quot )
  60     length void* heap-size * '[
  61         _
  62         [ alien-unsigned-4 1 + dup ]
  63         [ set-alien-unsigned-4 ]
  64         2bi
  65     ] ;
  66
  67 : (make-release) ( interfaces -- quot )
  68     length void* heap-size * '[
  69         _
  70         [ drop ]
  71         [ alien-unsigned-4 1 - dup ]
  72         [ set-alien-unsigned-4 ]
  73         2tri
  74         dup 0 = [ swap (free-wrapped-object) ] [ nip ] if
  75     ] ;
  76
  77 : (make-iunknown-methods) ( interfaces -- quots )
  78     [ (make-query-interface) ]
  79     [ (make-add-ref) ]
  80     [ (make-release) ] tri
  81     3array ;
  82
  83 : (thunk) ( n -- quot )
  84     dup 0 =
  85     [ drop [ ] ]
  86     [ void* heap-size neg * '[ _ swap <displaced-alien> ] ]
  87     if ;
  88
  89 : (thunked-quots) ( quots iunknown-methods thunk -- {thunk,quot}s )
  90     [ '[ @ com-unwrap ] [ swap 2array ] curry map ]
  91     [                   [ swap 2array ] curry map ] bi-curry bi*
  92     prepend ;
  93
  94 : compile-alien-callback ( word return parameters abi quot -- word )
  95     '[ _ _ _ _ alien-callback ]
  96     [ [ (( -- alien )) define-declared ] pick [ call ] dip ]
  97     with-compilation-unit ;
  98
  99 : (callback-word) ( function-name interface counter -- word )
 100     [ name>> "::" rot 3append "-callback-" ] dip number>string 3append
 101     "windows.com.wrapper.callbacks" create ;
 102
 103 : (finish-thunk) ( param-count thunk quot -- thunked-quot )
 104     [ [ drop [ ] ] [ swap 1 - '[ _ _ ndip ] ] if-empty ]
 105     dip compose ;
 106
 107 : (make-interface-callbacks) ( interface quots iunknown-methods n -- words )
 108     (thunk) (thunked-quots)
 109     swap [ find-com-interface-definition family-tree-functions ]
 110     keep (next-vtbl-counter) '[
 111         swap [
 112             [ name>> _ _ (callback-word) ]
 113             [ return>> ] [ parameter-types>> dup length ] tri
 114         ] [
 115             first2 (finish-thunk)
 116         ] bi*
 117         stdcall swap compile-alien-callback
 118     ] 2map ;
 119
 120 : (make-callbacks) ( implementations -- sequence )
 121     dup [ first ] map (make-iunknown-methods)
 122     [ [ first2 ] 2dip swap (make-interface-callbacks) ]
 123     curry map-index ;
 124
 125 : (malloc-wrapped-object) ( wrapper -- wrapped-object )
 126     vtbls>> length void* heap-size *
 127     [ ulong heap-size + malloc ] keep
 128     [ [ 1 ] 2dip set-alien-unsigned-4 ] [ drop ] 2bi ;
 129
 130 : (callbacks>vtbl) ( callbacks -- vtbl )
 131     [ execute( -- callback ) ] void*-array{ } map-as malloc-byte-array ;
 132 : (callbacks>vtbls) ( callbacks -- vtbls )
 133     [ (callbacks>vtbl) ] map ;
 134
 135 : (allocate-wrapper) ( wrapper -- )
 136     dup callbacks>> (callbacks>vtbls) >>vtbls
 137     f >>disposed drop ;
 138
 139 : com-startup-hook ( -- )
 140     +live-wrappers+ get-global [ (allocate-wrapper) ] each
 141     H{ } +wrapped-objects+ set-global ;
 142
 143 [ com-startup-hook ] "windows.com.wrapper" add-startup-hook
 144
 145 PRIVATE>
 146
 147 : allocate-wrapper ( wrapper -- )
 148     [ (allocate-wrapper) ]
 149     [ +live-wrappers+ get adjoin ] bi ;
 150
 151 : <com-wrapper> ( implementations -- wrapper )
 152     com-wrapper new-disposable swap (make-callbacks) >>callbacks
 153     dup allocate-wrapper ;
 154
 155 M: com-wrapper dispose*
 156     [ [ free ] each f ] change-vtbls
 157     +live-wrappers+ get-global remove! drop ;
 158
 159 : com-wrap ( object wrapper -- wrapped-object )
 160     [ vtbls>> ] [ (malloc-wrapped-object) ] bi
 161     [ over length <direct-void*-array> 0 swap copy ] keep
 162     [ +wrapped-objects+ get-global set-at ] keep ;