basis/windows/dragdrop-listener/dragdrop-listener.factor

   1 ! Copyright (C) 2008, 2009 Joe Groff, Slava Pestov.
   2 ! Copyright (C) 2017-2018 Alexander Ilin.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: accessors alien.accessors classes.struct kernel
   5 namespaces sequences ui.backend.windows ui.gadgets.worlds
   6 ui.gestures windows.com windows.com.wrapper windows.dropfiles
   7 windows.kernel32 windows.ole32 windows.user32 ;
   8 IN: windows.dragdrop-listener
   9
  10 : handle-data-object ( handler:  ( hdrop -- x ) data-object -- filenames )
  11     FORMATETC new
  12         CF_HDROP         >>cfFormat
  13         f                >>ptd
  14         DVASPECT_CONTENT >>dwAspect
  15         -1               >>lindex
  16         TYMED_HGLOBAL    >>tymed
  17     STGMEDIUM new
  18     [ IDataObject::GetData ] keep swap succeeded? [
  19         dup data>>
  20         [ rot execute( hdrop -- x ) ] with-global-lock
  21         swap ReleaseStgMedium
  22     ] [ 2drop f ] if ;
  23
  24 : filenames-from-data-object ( data-object -- filenames )
  25     \ filenames-from-hdrop swap handle-data-object ;
  26
  27 : filecount-from-data-object ( data-object -- n )
  28     \ filecount-from-hdrop swap handle-data-object ;
  29
  30 TUPLE: listener-dragdrop world last-drop-effect ;
  31
  32 : <listener-dragdrop> ( world -- object )
  33     DROPEFFECT_NONE listener-dragdrop boa ;
  34
  35 <<
  36 SYMBOL: +listener-dragdrop-wrapper+
  37 >>
  38
  39 <<
  40 {
  41     { IDropTarget {
  42         [ ! HRESULT DragEnter ( IDataObject* pDataObject, DWORD grfKeyState, POINTL pt, DWORD* pdwEffect )
  43             DROPEFFECT_COPY swap 0 set-alien-unsigned-4 3drop
  44             DROPEFFECT_COPY >>last-drop-effect drop
  45             S_OK
  46         ] [ ! HRESULT DragOver ( DWORD grfKeyState, POINTL pt, DWORD* pdwEffect )
  47             [
  48                 2drop
  49                 [ world>> children>> first hand-gadget set-global ]
  50                 [ last-drop-effect>> ] bi
  51             ] dip 0 set-alien-unsigned-4
  52             S_OK
  53         ] [ ! HRESULT DragLeave ( )
  54             drop S_OK
  55         ] [ ! HRESULT Drop ( IDataObject* pDataObject, DWORD grfKeyState, POINTL pt, DWORD* pdwEffect )
  56             [
  57                 2drop nip
  58                 filenames-from-data-object dropped-files set-global
  59                 key-modifiers <file-drop> hand-gadget get-global propagate-gesture
  60                 DROPEFFECT_COPY
  61             ] dip 0 set-alien-unsigned-4
  62             S_OK
  63         ]
  64     } }
  65 } <com-wrapper> +listener-dragdrop-wrapper+ set-global
  66 >>
  67
  68 : dragdrop-listener-window ( -- )
  69     world get dup <listener-dragdrop>
  70     +listener-dragdrop-wrapper+ get-global com-wrap [
  71         [ handle>> hWnd>> ] dip
  72         2dup RegisterDragDrop dup E_OUTOFMEMORY =
  73         [ drop ole-initialize RegisterDragDrop ] [ 2nip ] if
  74         check-ole32-error
  75     ] with-com-interface ;