basis/xml-rpc/xml-rpc.factor

   1 ! Copyright (C) 2005, 2009 Daniel Ehrenberg
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs base64 calendar calendar.format
   4 combinators debugger generic hashtables http http.client
   5 http.client.private io io.encodings.string io.encodings.utf8
   6 kernel make math math.order math.parser namespaces sequences
   7 strings xml xml.data xml.syntax xml.traversal xml.writer ;
   8 IN: xml-rpc
   9
  10 ! * Sending RPC requests
  11 ! TODO: time
  12 ! The word for what this does is "serialization"! Wow!
  13
  14 GENERIC: item>xml ( object -- xml )
  15
  16 M: integer item>xml
  17     dup 31 2^ neg 31 2^ 1 - between?
  18     [ "Integers must fit in 32 bits" throw ] unless
  19     [XML <i4><-></i4> XML] ;
  20
  21 M: boolean item>xml
  22     "1" "0" ? [XML <boolean><-></boolean> XML] ;
  23
  24 M: float item>xml
  25     number>string [XML <double><-></double> XML] ;
  26
  27 M: string item>xml
  28     [XML <string><-></string> XML] ;
  29
  30 : struct-member ( name value -- tag )
  31     over string? [ "Struct member name must be string" throw ] unless
  32     item>xml
  33     [XML
  34         <member>
  35             <name><-></name>
  36             <value><-></value>
  37         </member>
  38     XML] ;
  39
  40 M: hashtable item>xml
  41     [ struct-member ] { } assoc>map
  42     [XML <struct><-></struct> XML] ;
  43
  44 M: array item>xml
  45     [ item>xml [XML <value><-></value> XML] ] map
  46     [XML <array><data><-></data></array> XML] ;
  47
  48 TUPLE: base64 string ;
  49
  50 C: <base64> base64
  51
  52 M: base64 item>xml
  53     string>> >base64
  54     [XML <base64><-></base64> XML] ;
  55
  56 : params ( seq -- xml )
  57     [ item>xml [XML <param><value><-></value></param> XML] ] map
  58     [XML <params><-></params> XML] ;
  59
  60 : method-call ( name seq -- xml )
  61     params
  62     <XML
  63         <methodCall>
  64             <methodName><-></methodName>
  65             <->
  66         </methodCall>
  67     XML> ;
  68
  69 : return-params ( seq -- xml )
  70     params <XML <methodResponse><-></methodResponse> XML> ;
  71
  72 : return-fault ( fault-code fault-string -- xml )
  73     [ "faultString" ,, "faultCode" ,, ] H{ } make item>xml
  74     <XML
  75         <methodResponse>
  76             <fault>
  77                 <value><-></value>
  78             </fault>
  79         </methodResponse>
  80     XML> ;
  81
  82 TUPLE: rpc-method name params ;
  83
  84 C: <rpc-method> rpc-method
  85
  86 TUPLE: rpc-response params ;
  87
  88 C: <rpc-response> rpc-response
  89
  90 TUPLE: rpc-fault code string ;
  91
  92 C: <rpc-fault> rpc-fault
  93
  94 GENERIC: send-rpc ( rpc -- xml )
  95 M: rpc-method send-rpc
  96     [ name>> ] [ params>> ] bi method-call ;
  97 M: rpc-response send-rpc
  98     params>> return-params ;
  99 M: rpc-fault send-rpc
 100     [ code>> ] [ string>> ] bi return-fault ;
 101
 102 ! * Recieving RPC requests
 103 ! this needs to have much better error checking
 104
 105 ERROR: server-error tag message ;
 106
 107 M: server-error error.
 108     "Error in XML supplied to server" print
 109     "Description: " write dup message>> print
 110     "Tag: " write tag>> xml>string print ;
 111
 112 TAGS: xml>item ( tag -- object )
 113
 114 TAG: string xml>item
 115     children>string ;
 116
 117 : children>number ( tag -- n )
 118     children>string string>number ;
 119
 120 TAG: i4 xml>item children>number ;
 121 TAG: int xml>item children>number ;
 122 TAG: double xml>item children>number ;
 123
 124 TAG: boolean xml>item
 125     children>string {
 126         { "1" [ t ] }
 127         { "0" [ f ] }
 128         [ "Bad boolean" server-error ]
 129     } case ;
 130
 131 : unstruct-member ( tag -- )
 132     children-tags first2
 133     first-child-tag xml>item
 134     [ children>string ] dip swap ,, ;
 135
 136 TAG: struct xml>item
 137     [
 138         children-tags [ unstruct-member ] each
 139     ] H{ } make ;
 140
 141 TAG: base64 xml>item
 142     children>string base64> <base64> ;
 143
 144 TAG: array xml>item
 145     first-child-tag children-tags
 146     [ first-child-tag xml>item ] map ;
 147
 148 : params>array ( tag -- array )
 149     children-tags
 150     [ first-child-tag first-child-tag xml>item ] map ;
 151
 152 : parse-rpc-response ( xml -- array )
 153     first-child-tag params>array ;
 154
 155 : parse-method ( xml -- string array )
 156     children-tags first2
 157     [ children>string ] [ params>array ] bi* ;
 158
 159 : parse-fault ( xml -- fault-code fault-string )
 160     first-child-tag first-child-tag first-child-tag
 161     xml>item [ "faultCode" get "faultString" get ] with-variables ;
 162
 163 : receive-rpc ( xml -- rpc )
 164     dup main>> dup "methodCall" =
 165     [ drop parse-method <rpc-method> ] [
 166         "methodResponse" = [
 167             dup first-child-tag main>> "fault" =
 168             [ parse-fault <rpc-fault> ]
 169             [ parse-rpc-response <rpc-response> ] if
 170         ] [ "Bad main tag name" server-error ] if
 171     ] if ;
 172
 173 <PRIVATE
 174
 175 : xml-post-data ( xml -- post-data )
 176     xml>string utf8 encode "text/xml" <post-data> swap >>data ;
 177
 178 : rpc-post-request ( xml url -- request )
 179     [ send-rpc xml-post-data ] [ "POST" <client-request> ] bi*
 180     swap >>post-data ;
 181
 182 PRIVATE>
 183
 184 : post-rpc ( rpc url -- rpc' )
 185     ! This needs to do something in the event of an error
 186     rpc-post-request http-request nip string>xml receive-rpc ;
 187
 188 : invoke-method ( params method url -- response )
 189     [ swap <rpc-method> ] dip post-rpc ;