basis/xml/tokenize/tokenize.factor

   1 ! Copyright (C) 2005, 2006 Daniel Ehrenberg
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays ascii assocs combinators
   4 combinators.short-circuit fry io.encodings io.encodings.iana
   5 io.encodings.string io.encodings.utf16 io.encodings.utf8 kernel make
   6 math math.parser namespaces sequences sets splitting state-parser
   7 strings xml.char-classes xml.data xml.entities xml.errors ;
   8 IN: xml.tokenize
   9
  10 ! XML namespace processing: ns = namespace
  11
  12 ! A stack of hashtables
  13 SYMBOL: ns-stack
  14
  15 : attrs>ns ( attrs-alist -- hash )
  16     ! this should check to make sure URIs are valid
  17     [
  18         [
  19             swap dup space>> "xmlns" =
  20             [ main>> set ]
  21             [
  22                 T{ name f "" "xmlns" f } names-match?
  23                 [ "" set ] [ drop ] if
  24             ] if
  25         ] assoc-each
  26     ] { } make-assoc f like ;
  27
  28 : add-ns ( name -- )
  29     dup space>> dup ns-stack get assoc-stack
  30     [ nip ] [ nonexist-ns ] if* >>url drop ;
  31
  32 : push-ns ( hash -- )
  33     ns-stack get push ;
  34
  35 : pop-ns ( -- )
  36     ns-stack get pop* ;
  37
  38 : init-ns-stack ( -- )
  39     V{ H{
  40         { "xml" "http://www.w3.org/XML/1998/namespace" }
  41         { "xmlns" "http://www.w3.org/2000/xmlns" }
  42         { "" "" }
  43     } } clone
  44     ns-stack set ;
  45
  46 : tag-ns ( name attrs-alist -- name attrs )
  47     dup attrs>ns push-ns
  48     [ dup add-ns ] dip dup [ drop add-ns ] assoc-each <attrs> ;
  49
  50 ! Parsing names
  51
  52 : version=1.0? ( -- ? )
  53     prolog-data get version>> "1.0" = ;
  54
  55 ! version=1.0? is calculated once and passed around for efficiency
  56
  57 : assure-name ( str version=1.0? -- str )
  58     over {
  59         [ first name-start? ]
  60         [ rest-slice [ name-char? ] with all? ]
  61     } 2&& [ bad-name ] unless ;
  62
  63 : (parse-name) ( start -- str )
  64     version=1.0?
  65     [ [ get-char name-char? not ] curry take-until append ]
  66     [ assure-name ] bi ;
  67
  68 : parse-name-starting ( start -- name )
  69     (parse-name) get-char CHAR: : =
  70     [ next "" (parse-name) ] [ "" swap ] if f <name> ;
  71
  72 : parse-name ( -- name )
  73     "" parse-name-starting ;
  74
  75 !   -- Parsing strings
  76
  77 : (parse-entity) ( string -- )
  78     dup entities at [ , ] [
  79         prolog-data get standalone>>
  80         [ no-entity ] [
  81             dup extra-entities get at
  82             [ , ] [ no-entity ] ?if
  83         ] if
  84     ] ?if ;
  85
  86 : parse-entity ( -- )
  87     next CHAR: ; take-char next
  88     "#" ?head [
  89         "x" ?head 16 10 ? base> ,
  90     ] [ (parse-entity) ] if ;
  91
  92 : (parse-char) ( ch -- )
  93     get-char {
  94         { [ dup not ] [ 2drop ] }
  95         { [ 2dup = ] [ 2drop next ] }
  96         { [ dup CHAR: & = ] [ drop parse-entity (parse-char) ] }
  97         [ , next (parse-char) ]
  98     } cond ;
  99
 100 : parse-char ( ch -- string )
 101     [ (parse-char) ] "" make ;
 102
 103 : parse-quot ( ch -- string )
 104     parse-char get-char
 105     [ unclosed-quote ] unless ;
 106
 107 : parse-text ( -- string )
 108     CHAR: < parse-char ;
 109
 110 ! Parsing tags
 111
 112 : start-tag ( -- name ? )
 113     #! Outputs the name and whether this is a closing tag
 114     get-char CHAR: / = dup [ next ] when
 115     parse-name swap ;
 116
 117 : parse-attr-value ( -- seq )
 118     get-char dup "'\"" member?
 119     [ next parse-quot ] [ quoteless-attr ] if ;
 120
 121 : parse-attr ( -- )
 122     [ parse-name ] with-scope
 123     pass-blank CHAR: = expect pass-blank
 124     [ parse-attr-value ] with-scope
 125     2array , ;
 126
 127 : (middle-tag) ( -- )
 128     pass-blank version=1.0? get-char name-start?
 129     [ parse-attr (middle-tag) ] when ;
 130
 131 : middle-tag ( -- attrs-alist )
 132     ! f make will make a vector if it has any elements
 133     [ (middle-tag) ] f make pass-blank ;
 134
 135 : end-tag ( name attrs-alist -- tag )
 136     tag-ns pass-blank get-char CHAR: / =
 137     [ pop-ns <contained> next ] [ <opener> ] if ;
 138
 139 : take-comment ( -- comment )
 140     "--" expect-string
 141     "--" take-string
 142     <comment>
 143     CHAR: > expect ;
 144
 145 : take-cdata ( -- string )
 146     "[CDATA[" expect-string "]]>" take-string ;
 147
 148 : take-element-decl ( -- element-decl )
 149     pass-blank " " take-string pass-blank ">" take-string <element-decl> ;
 150
 151 : take-attlist-decl ( -- doctype-decl )
 152     pass-blank " " take-string pass-blank ">" take-string <attlist-decl> ;
 153
 154 : take-until-one-of ( seps -- str sep )
 155     '[ get-char _ member? ] take-until get-char ;
 156
 157 : only-blanks ( str -- )
 158     [ blank? ] all? [ bad-doctype-decl ] unless ;
 159
 160 : take-system-literal ( -- str )
 161     pass-blank get-char next {
 162         { CHAR: ' [ "'" take-string ] }
 163         { CHAR: " [ "\"" take-string ] }
 164     } case ;
 165
 166 : take-system-id ( -- system-id )
 167     take-system-literal <system-id>
 168     ">" take-string only-blanks ;
 169
 170 : take-public-id ( -- public-id )
 171     take-system-literal
 172     take-system-literal <public-id>
 173     ">" take-string only-blanks ;
 174
 175 DEFER: direct
 176
 177 : (take-internal-subset) ( -- )
 178     pass-blank get-char {
 179         { CHAR: ] [ next ] }
 180         [ drop "<!" expect-string direct , (take-internal-subset) ]
 181     } case ;
 182
 183 : take-internal-subset ( -- seq )
 184     [ (take-internal-subset) ] { } make ;
 185
 186 : (take-external-id) ( token -- external-id )
 187     pass-blank {
 188         { "SYSTEM" [ take-system-id ] }
 189         { "PUBLIC" [ take-public-id ] }
 190         [ bad-external-id ]
 191     } case ;
 192
 193 : take-external-id ( -- external-id )
 194     " " take-string (take-external-id) ;
 195
 196 : take-doctype-decl ( -- doctype-decl )
 197     pass-blank " >" take-until-one-of {
 198         { CHAR: \s [
 199             pass-blank get-char CHAR: [ = [
 200                 next take-internal-subset f swap
 201                 ">" take-string only-blanks
 202             ] [
 203                 " >" take-until-one-of {
 204                     { CHAR: \s [ (take-external-id) ] }
 205                     { CHAR: > [ only-blanks f ] }
 206                 } case f
 207             ] if
 208         ] }
 209         { CHAR: > [ f f ] }
 210     } case <doctype-decl> ;
 211
 212 : take-entity-def ( -- entity-name entity-def )
 213     " " take-string pass-blank get-char {
 214         { CHAR: ' [ take-system-literal ] }
 215         { CHAR: " [ take-system-literal ] }
 216         [ drop take-external-id ]
 217     } case ;
 218
 219 : take-entity-decl ( -- entity-decl )
 220     pass-blank get-char {
 221         { CHAR: % [ next pass-blank take-entity-def ] }
 222         [ drop take-entity-def ]
 223     } case
 224     ">" take-string only-blanks <entity-decl> ;
 225
 226 : take-directive ( -- directive )
 227     " " take-string {
 228         { "ELEMENT" [ take-element-decl ] }
 229         { "ATTLIST" [ take-attlist-decl ] }
 230         { "DOCTYPE" [ take-doctype-decl ] }
 231         { "ENTITY" [ take-entity-decl ] }
 232         [ bad-directive ]
 233     } case ;
 234
 235 : direct ( -- object )
 236     get-char {
 237         { CHAR: - [ take-comment ] }
 238         { CHAR: [ [ take-cdata ] }
 239         [ drop take-directive ]
 240     } case ;
 241
 242 : yes/no>bool ( string -- t/f )
 243     {
 244         { "yes" [ t ] }
 245         { "no" [ f ] }
 246         [ not-yes/no ]
 247     } case ;
 248
 249 : assure-no-extra ( seq -- )
 250     [ first ] map {
 251         T{ name f "" "version" f }
 252         T{ name f "" "encoding" f }
 253         T{ name f "" "standalone" f }
 254     } diff
 255     [ extra-attrs ] unless-empty ;
 256
 257 : good-version ( version -- version )
 258     dup { "1.0" "1.1" } member? [ bad-version ] unless ;
 259
 260 : prolog-attrs ( alist -- prolog )
 261     [ T{ name f "" "version" f } swap at
 262       [ good-version ] [ versionless-prolog ] if* ] keep
 263     [ T{ name f "" "encoding" f } swap at
 264       "UTF-8" or ] keep
 265     T{ name f "" "standalone" f } swap at
 266     [ yes/no>bool ] [ f ] if*
 267     <prolog> ;
 268
 269 SYMBOL: string-input?
 270 : decode-input-if ( encoding -- )
 271     string-input? get [ drop ] [ decode-input ] if ;
 272
 273 : parse-prolog ( -- prolog )
 274     pass-blank middle-tag "?>" expect-string
 275     dup assure-no-extra prolog-attrs
 276     dup encoding>> dup "UTF-16" =
 277     [ drop ] [ name>encoding [ decode-input-if ] when* ] if
 278     dup prolog-data set ;
 279
 280 : instruct ( -- instruction )
 281     "" (parse-name) dup "xml" =
 282     [ drop parse-prolog ] [
 283         dup >lower "xml" =
 284         [ capitalized-prolog ]
 285         [ "?>" take-string append <instruction> ] if
 286     ] if ;
 287
 288 : make-tag ( -- tag )
 289     {
 290         { [ get-char dup CHAR: ! = ] [ drop next direct ] }
 291         { [ CHAR: ? = ] [ next instruct ] }
 292         [
 293             start-tag [ dup add-ns pop-ns <closer> ]
 294             [ middle-tag end-tag ] if
 295             CHAR: > expect
 296         ]
 297     } cond ;
 298
 299 ! Autodetecting encodings
 300
 301 : continue-make-tag ( str -- tag )
 302     parse-name-starting middle-tag end-tag CHAR: > expect ;
 303
 304 : start-utf16le ( -- tag )
 305     utf16le decode-input-if
 306     CHAR: ? expect
 307     0 expect instruct ;
 308
 309 : 10xxxxxx? ( ch -- ? )
 310     -6 shift 3 bitand 2 = ;
 311
 312 : start<name ( ch -- tag )
 313     ascii?
 314     [ utf8 decode-input-if next make-tag ] [
 315         next
 316         [ get-next 10xxxxxx? not ] take-until
 317         get-char suffix utf8 decode
 318         utf8 decode-input-if next
 319         continue-make-tag
 320     ] if ;
 321
 322 : start< ( -- tag )
 323     get-next {
 324         { 0 [ next next start-utf16le ] }
 325         { CHAR: ? [ next next instruct ] } ! XML prolog parsing sets the encoding
 326         { CHAR: ! [ utf8 decode-input next next direct ] }
 327         [ start<name ]
 328     } case ;
 329
 330 : skip-utf8-bom ( -- tag )
 331     "\u0000bb\u0000bf" expect utf8 decode-input
 332     CHAR: < expect make-tag ;
 333
 334 : start-utf16be ( -- tag )
 335     utf16be decode-input-if
 336     next CHAR: < expect make-tag ;
 337
 338 : skip-utf16le-bom ( -- tag )
 339     utf16le decode-input-if
 340     next HEX: FE expect
 341     CHAR: < expect make-tag ;
 342
 343 : skip-utf16be-bom ( -- tag )
 344     utf16be decode-input-if
 345     next HEX: FF expect
 346     CHAR: < expect make-tag ;
 347
 348 : start-document ( -- tag )
 349     get-char {
 350         { CHAR: < [ start< ] }
 351         { 0 [ start-utf16be ] }
 352         { HEX: EF [ skip-utf8-bom ] }
 353         { HEX: FF [ skip-utf16le-bom ] }
 354         { HEX: FE [ skip-utf16be-bom ] }
 355         { f [ "" ] }
 356         [ dup blank?
 357           [ drop pass-blank utf8 decode-input-if CHAR: < expect make-tag ]
 358           [ 1string ] if ! Replace with proper error?
 359         ]
 360     } case ;