basis/xml/tokenize/tokenize.factor

   1 ! Copyright (C) 2005, 2006 Daniel Ehrenberg
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays ascii assocs combinators
   4 combinators.short-circuit fry io.encodings io.encodings.iana
   5 io.encodings.string io.encodings.utf16 io.encodings.utf8 kernel make
   6 math math.parser namespaces sequences sets splitting state-parser
   7 strings xml.char-classes xml.data xml.entities xml.errors ;
   8 IN: xml.tokenize
   9
  10 ! XML namespace processing: ns = namespace
  11
  12 ! A stack of hashtables
  13 SYMBOL: ns-stack
  14
  15 : attrs>ns ( attrs-alist -- hash )
  16     ! this should check to make sure URIs are valid
  17     [
  18         [
  19             swap dup space>> "xmlns" =
  20             [ main>> set ]
  21             [
  22                 T{ name f "" "xmlns" f } names-match?
  23                 [ "" set ] [ drop ] if
  24             ] if
  25         ] assoc-each
  26     ] { } make-assoc f like ;
  27
  28 : add-ns ( name -- )
  29     dup space>> dup ns-stack get assoc-stack
  30     [ nip ] [ nonexist-ns ] if* >>url drop ;
  31
  32 : push-ns ( hash -- )
  33     ns-stack get push ;
  34
  35 : pop-ns ( -- )
  36     ns-stack get pop* ;
  37
  38 : init-ns-stack ( -- )
  39     V{ H{
  40         { "xml" "http://www.w3.org/XML/1998/namespace" }
  41         { "xmlns" "http://www.w3.org/2000/xmlns" }
  42         { "" "" }
  43     } } clone
  44     ns-stack set ;
  45
  46 : tag-ns ( name attrs-alist -- name attrs )
  47     dup attrs>ns push-ns
  48     [ dup add-ns ] dip dup [ drop add-ns ] assoc-each <attrs> ;
  49
  50 ! Parsing names
  51
  52 : version=1.0? ( -- ? )
  53     prolog-data get version>> "1.0" = ;
  54
  55 ! version=1.0? is calculated once and passed around for efficiency
  56
  57 : assure-name ( str version=1.0? -- str )
  58     over {
  59         [ first name-start? ]
  60         [ rest-slice [ name-char? ] with all? ]
  61     } 2&& [ "Malformed name" xml-string-error ] unless ;
  62
  63 : (parse-name) ( start -- str )
  64     version=1.0?
  65     [ [ get-char name-char? not ] curry take-until append ]
  66     [ assure-name ] bi ;
  67
  68 : parse-name-starting ( start -- name )
  69     (parse-name) get-char CHAR: : =
  70     [ next "" (parse-name) ] [ "" swap ] if f <name> ;
  71
  72 : parse-name ( -- name )
  73     "" parse-name-starting ;
  74
  75 !   -- Parsing strings
  76
  77 : (parse-entity) ( string -- )
  78     dup entities at [ , ] [
  79         prolog-data get standalone>>
  80         [ no-entity ] [
  81             dup extra-entities get at
  82             [ , ] [ no-entity ] ?if
  83         ] if
  84     ] ?if ;
  85
  86 : parse-entity ( -- )
  87     next CHAR: ; take-char next
  88     "#" ?head [
  89         "x" ?head 16 10 ? base> ,
  90     ] [ (parse-entity) ] if ;
  91
  92 : (parse-char) ( ch -- )
  93     get-char {
  94         { [ dup not ] [ 2drop ] }
  95         { [ 2dup = ] [ 2drop next ] }
  96         { [ dup CHAR: & = ] [ drop parse-entity (parse-char) ] }
  97         [ , next (parse-char) ]
  98     } cond ;
  99
 100 : parse-char ( ch -- string )
 101     [ (parse-char) ] "" make ;
 102
 103 : parse-quot ( ch -- string )
 104     parse-char get-char
 105     [ "XML file ends in a quote" xml-string-error ] unless ;
 106
 107 : parse-text ( -- string )
 108     CHAR: < parse-char ;
 109
 110 ! Parsing tags
 111
 112 : start-tag ( -- name ? )
 113     #! Outputs the name and whether this is a closing tag
 114     get-char CHAR: / = dup [ next ] when
 115     parse-name swap ;
 116
 117 : parse-attr-value ( -- seq )
 118     get-char dup "'\"" member? [
 119         next parse-quot
 120     ] [
 121         "Attribute lacks quote" xml-string-error
 122     ] if ;
 123
 124 : parse-attr ( -- )
 125     [ parse-name ] with-scope
 126     pass-blank CHAR: = expect pass-blank
 127     [ parse-attr-value ] with-scope
 128     2array , ;
 129
 130 : (middle-tag) ( -- )
 131     pass-blank version=1.0? get-char name-start?
 132     [ parse-attr (middle-tag) ] when ;
 133
 134 : middle-tag ( -- attrs-alist )
 135     ! f make will make a vector if it has any elements
 136     [ (middle-tag) ] f make pass-blank ;
 137
 138 : end-tag ( name attrs-alist -- tag )
 139     tag-ns pass-blank get-char CHAR: / =
 140     [ pop-ns <contained> next ] [ <opener> ] if ;
 141
 142 : take-comment ( -- comment )
 143     "--" expect-string
 144     "--" take-string
 145     <comment>
 146     CHAR: > expect ;
 147
 148 : take-cdata ( -- string )
 149     "[CDATA[" expect-string "]]>" take-string ;
 150
 151 : take-element-decl ( -- element-decl )
 152     pass-blank " " take-string pass-blank ">" take-string <element-decl> ;
 153
 154 : take-attlist-decl ( -- doctype-decl )
 155     pass-blank " " take-string pass-blank ">" take-string <attlist-decl> ;
 156
 157 : take-until-one-of ( seps -- str sep )
 158     '[ get-char _ member? ] take-until get-char ;
 159
 160 : only-blanks ( str -- )
 161     [ blank? ] all? [ bad-doctype-decl ] unless ;
 162
 163 : take-system-literal ( -- str )
 164     pass-blank get-char next {
 165         { CHAR: ' [ "'" take-string ] }
 166         { CHAR: " [ "\"" take-string ] }
 167     } case ;
 168
 169 : take-system-id ( -- system-id )
 170     take-system-literal <system-id>
 171     ">" take-string only-blanks ;
 172
 173 : take-public-id ( -- public-id )
 174     take-system-literal
 175     take-system-literal <public-id>
 176     ">" take-string only-blanks ;
 177
 178 DEFER: direct
 179
 180 : (take-internal-subset) ( -- )
 181     pass-blank get-char {
 182         { CHAR: ] [ next ] }
 183         [ drop "<!" expect-string direct , (take-internal-subset) ]
 184     } case ;
 185
 186 : take-internal-subset ( -- seq )
 187     [ (take-internal-subset) ] { } make ;
 188
 189 : (take-external-id) ( token -- external-id )
 190     pass-blank {
 191         { "SYSTEM" [ take-system-id ] }
 192         { "PUBLIC" [ take-public-id ] }
 193         [ bad-external-id ]
 194     } case ;
 195
 196 : take-external-id ( -- external-id )
 197     " " take-string (take-external-id) ;
 198
 199 : take-doctype-decl ( -- doctype-decl )
 200     pass-blank " >" take-until-one-of {
 201         { CHAR: \s [
 202             pass-blank get-char CHAR: [ = [
 203                 next take-internal-subset f swap
 204                 ">" take-string only-blanks
 205             ] [
 206                 " >" take-until-one-of {
 207                     { CHAR: \s [ (take-external-id) ] }
 208                     { CHAR: > [ only-blanks f ] }
 209                 } case f
 210             ] if
 211         ] }
 212         { CHAR: > [ f f ] }
 213     } case <doctype-decl> ;
 214
 215 : take-entity-def ( -- entity-name entity-def )
 216     " " take-string pass-blank get-char {
 217         { CHAR: ' [ take-system-literal ] }
 218         { CHAR: " [ take-system-literal ] }
 219         [ drop take-external-id ]
 220     } case ;
 221
 222 : take-entity-decl ( -- entity-decl )
 223     pass-blank get-char {
 224         { CHAR: % [ next pass-blank take-entity-def ] }
 225         [ drop take-entity-def ]
 226     } case
 227     ">" take-string only-blanks <entity-decl> ;
 228
 229 : take-directive ( -- directive )
 230     " " take-string {
 231         { "ELEMENT" [ take-element-decl ] }
 232         { "ATTLIST" [ take-attlist-decl ] }
 233         { "DOCTYPE" [ take-doctype-decl ] }
 234         { "ENTITY" [ take-entity-decl ] }
 235         [ bad-directive ]
 236     } case ;
 237
 238 : direct ( -- object )
 239     get-char {
 240         { CHAR: - [ take-comment ] }
 241         { CHAR: [ [ take-cdata ] }
 242         [ drop take-directive ]
 243     } case ;
 244
 245 : yes/no>bool ( string -- t/f )
 246     {
 247         { "yes" [ t ] }
 248         { "no" [ f ] }
 249         [ not-yes/no ]
 250     } case ;
 251
 252 : assure-no-extra ( seq -- )
 253     [ first ] map {
 254         T{ name f "" "version" f }
 255         T{ name f "" "encoding" f }
 256         T{ name f "" "standalone" f }
 257     } diff
 258     [ extra-attrs ] unless-empty ;
 259
 260 : good-version ( version -- version )
 261     dup { "1.0" "1.1" } member? [ bad-version ] unless ;
 262
 263 : prolog-attrs ( alist -- prolog )
 264     [ T{ name f "" "version" f } swap at
 265       [ good-version ] [ versionless-prolog ] if* ] keep
 266     [ T{ name f "" "encoding" f } swap at
 267       "UTF-8" or ] keep
 268     T{ name f "" "standalone" f } swap at
 269     [ yes/no>bool ] [ f ] if*
 270     <prolog> ;
 271
 272 SYMBOL: string-input?
 273 : decode-input-if ( encoding -- )
 274     string-input? get [ drop ] [ decode-input ] if ;
 275
 276 : parse-prolog ( -- prolog )
 277     pass-blank middle-tag "?>" expect-string
 278     dup assure-no-extra prolog-attrs
 279     dup encoding>> dup "UTF-16" =
 280     [ drop ] [ name>encoding [ decode-input-if ] when* ] if
 281     dup prolog-data set ;
 282
 283 : instruct ( -- instruction )
 284     "" (parse-name) dup "xml" =
 285     [ drop parse-prolog ] [
 286         dup >lower "xml" =
 287         [ capitalized-prolog ]
 288         [ "?>" take-string append <instruction> ] if
 289     ] if ;
 290
 291 : make-tag ( -- tag )
 292     {
 293         { [ get-char dup CHAR: ! = ] [ drop next direct ] }
 294         { [ CHAR: ? = ] [ next instruct ] }
 295         [
 296             start-tag [ dup add-ns pop-ns <closer> ]
 297             [ middle-tag end-tag ] if
 298             CHAR: > expect
 299         ]
 300     } cond ;
 301
 302 ! Autodetecting encodings
 303
 304 : continue-make-tag ( str -- tag )
 305     parse-name-starting middle-tag end-tag CHAR: > expect ;
 306
 307 : start-utf16le ( -- tag )
 308     utf16le decode-input-if
 309     CHAR: ? expect
 310     0 expect instruct ;
 311
 312 : 10xxxxxx? ( ch -- ? )
 313     -6 shift 3 bitand 2 = ;
 314
 315 : start<name ( ch -- tag )
 316     ascii?
 317     [ utf8 decode-input-if next make-tag ] [
 318         next
 319         [ get-next 10xxxxxx? not ] take-until
 320         get-char suffix utf8 decode
 321         utf8 decode-input-if next
 322         continue-make-tag
 323     ] if ;
 324
 325 : start< ( -- tag )
 326     get-next {
 327         { 0 [ next next start-utf16le ] }
 328         { CHAR: ? [ next next instruct ] } ! XML prolog parsing sets the encoding
 329         { CHAR: ! [ utf8 decode-input next next direct ] }
 330         [ start<name ]
 331     } case ;
 332
 333 : skip-utf8-bom ( -- tag )
 334     "\u0000bb\u0000bf" expect utf8 decode-input
 335     CHAR: < expect make-tag ;
 336
 337 : start-utf16be ( -- tag )
 338     utf16be decode-input-if
 339     next CHAR: < expect make-tag ;
 340
 341 : skip-utf16le-bom ( -- tag )
 342     utf16le decode-input-if
 343     next HEX: FE expect
 344     CHAR: < expect make-tag ;
 345
 346 : skip-utf16be-bom ( -- tag )
 347     utf16be decode-input-if
 348     next HEX: FF expect
 349     CHAR: < expect make-tag ;
 350
 351 : start-document ( -- tag )
 352     get-char {
 353         { CHAR: < [ start< ] }
 354         { 0 [ start-utf16be ] }
 355         { HEX: EF [ skip-utf8-bom ] }
 356         { HEX: FF [ skip-utf16le-bom ] }
 357         { HEX: FE [ skip-utf16be-bom ] }
 358         { f [ "" ] }
 359         [ dup blank?
 360           [ drop pass-blank utf8 decode-input-if CHAR: < expect make-tag ]
 361           [ 1string ] if ! Replace with proper error
 362         ]
 363     } case ;