basis/xmode/catalog/catalog.factor

   1 USING: xmode.loader xmode.utilities xmode.rules namespaces
   2 strings splitting assocs sequences kernel io.files xml memoize
   3 words globs combinators io.encodings.utf8 sorting accessors xml.data ;
   4 IN: xmode.catalog
   5
   6 TUPLE: mode file file-name-glob first-line-glob ;
   7
   8 <TAGS: parse-mode-tag ( modes tag -- )
   9
  10 TAG: MODE
  11     dup "NAME" attr [
  12         mode new {
  13             { "FILE" f (>>file) }
  14             { "FILE_NAME_GLOB" f (>>file-name-glob) }
  15             { "FIRST_LINE_GLOB" f (>>first-line-glob) }
  16         } init-from-tag
  17     ] dip
  18     rot set-at ;
  19
  20 TAGS>
  21
  22 : parse-modes-tag ( tag -- modes )
  23     H{ } clone [
  24         swap child-tags [ parse-mode-tag ] with each
  25     ] keep ;
  26
  27 MEMO: modes ( -- modes )
  28     "vocab:xmode/modes/catalog"
  29     file>xml parse-modes-tag ;
  30
  31 MEMO: mode-names ( -- modes )
  32     modes keys natural-sort ;
  33
  34 : reset-catalog ( -- )
  35     \ modes reset-memoized ;
  36
  37 MEMO: (load-mode) ( name -- rule-sets )
  38     modes at [
  39         file>>
  40         "vocab:xmode/modes/" prepend
  41         utf8 <file-reader> parse-mode
  42     ] [
  43         "text" (load-mode)
  44     ] if* ;
  45
  46 SYMBOL: rule-sets
  47
  48 : no-such-rule-set ( name -- * )
  49     "No such rule set: " prepend throw ;
  50
  51 : get-rule-set ( name -- rule-sets rules )
  52     dup "::" split1 [ swap (load-mode) ] [ rule-sets get ] if*
  53     dup -roll at* [ nip ] [ drop no-such-rule-set ] if ;
  54
  55 DEFER: finalize-rule-set
  56
  57 : resolve-delegate ( rule -- )
  58     dup delegate>> dup string? [
  59         get-rule-set
  60         dup rule-set? [ "not a rule set" throw ] unless
  61         swap rule-sets [ dup finalize-rule-set ] with-variable
  62         >>delegate drop
  63     ] [ 2drop ] if ;
  64
  65 : each-rule ( rule-set quot -- )
  66     [ rules>> values concat ] dip each ; inline
  67
  68 : resolve-delegates ( ruleset -- )
  69     [ resolve-delegate ] each-rule ;
  70
  71 : ?update ( keyword-map/f keyword-map -- keyword-map )
  72     over [ dupd update ] [ nip clone ] if ;
  73
  74 : import-keywords ( parent child -- )
  75     over [ [ keywords>> ] bi@ ?update ] dip (>>keywords) ;
  76
  77 : import-rules ( parent child -- )
  78     swap [ add-rule ] curry each-rule ;
  79
  80 : resolve-imports ( ruleset -- )
  81     dup imports>> [
  82         get-rule-set swap rule-sets [
  83             [ nip resolve-delegates ]
  84             [ import-keywords ]
  85             [ import-rules ]
  86             2tri
  87         ] with-variable
  88     ] with each ;
  89
  90 ERROR: mutually-recursive-rulesets ruleset ;
  91
  92 : finalize-rule-set ( ruleset -- )
  93     dup finalized?>> [ drop ] [
  94         t >>finalized?
  95         [ resolve-imports ]
  96         [ resolve-delegates ]
  97         bi
  98     ] if ;
  99
 100 : finalize-mode ( rulesets -- )
 101     rule-sets [
 102         dup [ nip finalize-rule-set ] assoc-each
 103     ] with-variable ;
 104
 105 : load-mode ( name -- rule-sets )
 106     (load-mode) dup finalize-mode ;
 107
 108 : reset-modes ( -- )
 109     \ (load-mode) reset-memoized ;
 110
 111 : ?glob-matches ( string glob/f -- ? )
 112     dup [ glob-matches? ] [ 2drop f ] if ;
 113
 114 : suitable-mode? ( file-name first-line mode -- ? )
 115     tuck first-line-glob>> ?glob-matches
 116     [ 2drop t ] [ file-name-glob>> ?glob-matches ] if ;
 117
 118 : find-mode ( file-name first-line -- mode )
 119     modes
 120     [ nip [ 2dup ] dip suitable-mode? ] assoc-find
 121     2drop [ 2drop ] dip [ "text" ] unless* ;