basis/xmode/catalog/catalog.factor

   1 USING: xmode.loader xmode.utilities xmode.rules namespaces
   2 strings splitting assocs sequences kernel io.files xml memoize
   3 words globs combinators io.encodings.utf8 sorting accessors xml.data ;
   4 IN: xmode.catalog
   5
   6 TUPLE: mode file file-name-glob first-line-glob ;
   7
   8 <TAGS: parse-mode-tag ( modes tag -- )
   9
  10 TAG: MODE
  11     dup "NAME" attr [
  12         mode new {
  13             { "FILE" f (>>file) }
  14             { "FILE_NAME_GLOB" f (>>file-name-glob) }
  15             { "FIRST_LINE_GLOB" f (>>first-line-glob) }
  16         } init-from-tag
  17     ] dip
  18     rot set-at ;
  19
  20 TAGS>
  21
  22 : parse-modes-tag ( tag -- modes )
  23     H{ } clone [
  24         swap child-tags [ parse-mode-tag ] with each
  25     ] keep ;
  26
  27 MEMO: modes ( -- modes )
  28     "resource:basis/xmode/modes/catalog"
  29     file>xml parse-modes-tag ;
  30
  31 MEMO: mode-names ( -- modes )
  32     modes keys natural-sort ;
  33
  34 : reset-catalog ( -- )
  35     \ modes reset-memoized ;
  36
  37 MEMO: (load-mode) ( name -- rule-sets )
  38     modes at [
  39         file>>
  40         "resource:basis/xmode/modes/" prepend
  41         utf8 <file-reader> parse-mode
  42     ] [
  43         "text" (load-mode)
  44     ] if* ;
  45
  46 SYMBOL: rule-sets
  47
  48 : no-such-rule-set ( name -- * )
  49     "No such rule set: " prepend throw ;
  50
  51 : get-rule-set ( name -- rule-sets rules )
  52     dup "::" split1 [ swap (load-mode) ] [ rule-sets get ] if*
  53     dup -roll at* [ nip ] [ drop no-such-rule-set ] if ;
  54
  55 : resolve-delegate ( rule -- )
  56     dup delegate>> dup string?
  57     [ get-rule-set nip swap (>>delegate) ] [ 2drop ] if ;
  58
  59 : each-rule ( rule-set quot -- )
  60     [ rules>> values concat ] dip each ; inline
  61
  62 : resolve-delegates ( ruleset -- )
  63     [ resolve-delegate ] each-rule ;
  64
  65 : ?update ( keyword-map/f keyword-map -- keyword-map )
  66     over [ dupd update ] [ nip clone ] if ;
  67
  68 : import-keywords ( parent child -- )
  69     over [ [ keywords>> ] bi@ ?update ] dip (>>keywords) ;
  70
  71 : import-rules ( parent child -- )
  72     swap [ add-rule ] curry each-rule ;
  73
  74 : resolve-imports ( ruleset -- )
  75     dup imports>> [
  76         get-rule-set swap rule-sets [
  77             dup resolve-delegates
  78             2dup import-keywords
  79             import-rules
  80         ] with-variable
  81     ] with each ;
  82
  83 ERROR: mutually-recursive-rulesets ruleset ;
  84 : finalize-rule-set ( ruleset -- )
  85     dup finalized?>> {
  86         { f [
  87             {
  88                 [ 1 >>finalized? drop ]
  89                 [ resolve-imports ]
  90                 [ resolve-delegates ]
  91                 [ t >>finalized? drop ]
  92             } cleave
  93         ] }
  94         { t [ drop ] }
  95         { 1 [ mutually-recursive-rulesets ] }
  96     } case ;
  97
  98 : finalize-mode ( rulesets -- )
  99     rule-sets [
 100         dup [ nip finalize-rule-set ] assoc-each
 101     ] with-variable ;
 102
 103 : load-mode ( name -- rule-sets )
 104     (load-mode) dup finalize-mode ;
 105
 106 : reset-modes ( -- )
 107     \ (load-mode) reset-memoized ;
 108
 109 : ?glob-matches ( string glob/f -- ? )
 110     dup [ glob-matches? ] [ 2drop f ] if ;
 111
 112 : suitable-mode? ( file-name first-line mode -- ? )
 113     tuck first-line-glob>> ?glob-matches
 114     [ 2drop t ] [ file-name-glob>> ?glob-matches ] if ;
 115
 116 : find-mode ( file-name first-line -- mode )
 117     modes
 118     [ nip [ 2dup ] dip suitable-mode? ] assoc-find
 119     2drop [ 2drop ] dip [ "text" ] unless* ;