basis/xmode/loader/syntax/syntax.factor

   1 ! Copyright (C) 2007, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs combinators kernel lexer make
   4 namespaces parser sequences splitting xml.data xml.syntax
   5 xml.syntax.private xml.traversal xml.traversal.private
   6 xmode.rules xmode.tokens xmode.utilities ;
   7 IN: xmode.loader.syntax
   8
   9 ! Rule tag parsing utilities
  10 : (parse-rule-tag) ( rule-set tag specs class -- )
  11     new swap init-from-tag swap add-rule ; inline
  12
  13 SYNTAX: RULE:
  14     scan-token scan-word scan-word [
  15         [ parse-definition call( -- ) ] { } make
  16         swap [ (parse-rule-tag) ] 2curry
  17     ] dip swap define-tag ;
  18
  19 ! Attribute utilities
  20 : string>boolean ( string -- ? ) "TRUE" = ;
  21
  22 : string>match-type ( string -- obj )
  23     {
  24         { "RULE" [ f ] }
  25         { "CONTEXT" [ t ] }
  26         [ string>token ]
  27     } case ;
  28
  29 : string>rule-set-name ( string -- name ) "MAIN" or ;
  30
  31 : cdata>string ( tag -- string )
  32     children>> [ dup cdata? [ text>> ] when ] map (children>string) ;
  33
  34 ! PROP, PROPS
  35 : parse-prop-tag ( tag -- key value )
  36     [ "NAME" attr ] [ "VALUE" attr ] bi ;
  37
  38 : parse-props-tag ( tag -- assoc )
  39     children-tags
  40     [ parse-prop-tag ] H{ } map>assoc ;
  41
  42 : position-attrs ( tag -- at-line-start? at-whitespace-end? at-word-start? )
  43     ! XXX Wrong logic!
  44     { "AT_LINE_START" "AT_WHITESPACE_END" "AT_WORD_START" }
  45     [ attr string>boolean ] with map first3 ;
  46
  47 : parse-literal-matcher ( tag -- matcher )
  48     dup cdata>string
  49     rule-set get ignore-case?>> <string-matcher>
  50     swap position-attrs <matcher> ;
  51
  52 : parse-regexp-matcher ( tag -- matcher )
  53     dup cdata>string
  54     rule-set get ignore-case?>> <?insensitive-regexp>
  55     swap position-attrs <matcher> ;
  56
  57 : shared-tag-attrs ( -- )
  58     { "TYPE" string>token body-token<< } , ; inline
  59
  60 : parse-delegate ( string -- pair )
  61     "::" split1 [ rule-set get swap ] unless* 2array ;
  62
  63 : delegate-attr ( -- )
  64     { "DELEGATE" f delegate<< } , ;
  65
  66 : regexp-attr ( -- )
  67     { "HASH_CHAR" f chars<< } , ;
  68
  69 : match-type-attr ( -- )
  70     { "MATCH_TYPE" string>match-type match-token<< } , ;
  71
  72 : span-attrs ( -- )
  73     { "NO_LINE_BREAK" string>boolean no-line-break?<< } ,
  74     { "NO_WORD_BREAK" string>boolean no-word-break?<< } ,
  75     { "NO_ESCAPE" string>boolean no-escape?<< } , ;
  76
  77 : literal-start ( -- )
  78     [ parse-literal-matcher >>start drop ] , ;
  79
  80 : regexp-start ( -- )
  81     [ parse-regexp-matcher >>start drop ] , ;
  82
  83 : literal-end ( -- )
  84     [ parse-literal-matcher >>end drop ] , ;
  85
  86 ! SPAN's children
  87 TAGS: parse-begin/end-tag ( rule tag -- )
  88
  89 TAG: BEGIN parse-begin/end-tag
  90     ! XXX
  91     parse-literal-matcher >>start drop ;
  92
  93 TAG: END parse-begin/end-tag
  94     ! XXX
  95     parse-literal-matcher >>end drop ;
  96
  97 : parse-begin/end-tags ( -- )
  98     [
  99         ! XXX: handle position attrs on span tag itself
 100         children-tags [ parse-begin/end-tag ] with each
 101     ] , ;
 102
 103 : init-span-tag ( -- ) [ drop init-span ] , ;
 104
 105 : init-eol-span-tag ( -- ) [ drop init-eol-span ] , ;
 106
 107 : parse-keyword-tag ( tag keyword-map -- )
 108     [ dup main>> string>token swap cdata>string ] dip set-at ;