basis/xmode/loader/syntax/syntax.factor

   1 ! Copyright (C) 2007, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors xmode.tokens xmode.rules xmode.keyword-map
   4 xml.data xml.traversal xml assocs kernel combinators sequences
   5 math.parser namespaces make parser lexer xmode.utilities
   6 regexp io.files splitting arrays xml.syntax xml.syntax.private ;
   7 IN: xmode.loader.syntax
   8
   9 ! Rule tag parsing utilities
  10 : (parse-rule-tag) ( rule-set tag specs class -- )
  11     new swap init-from-tag swap add-rule ; inline
  12
  13 : RULE:
  14     scan scan-word scan-word [
  15         parse-definition { } make
  16         swap [ (parse-rule-tag) ] 2curry
  17     ] dip swap define-tag ; parsing
  18
  19 ! Attribute utilities
  20 : string>boolean ( string -- ? ) "TRUE" = ;
  21
  22 : string>match-type ( string -- obj )
  23     {
  24         { "RULE" [ f ] }
  25         { "CONTEXT" [ t ] }
  26         [ string>token ]
  27     } case ;
  28
  29 : string>rule-set-name ( string -- name ) "MAIN" or ;
  30
  31 ! PROP, PROPS
  32 : parse-prop-tag ( tag -- key value )
  33     [ "NAME" attr ] [ "VALUE" attr ] bi ;
  34
  35 : parse-props-tag ( tag -- assoc )
  36     children-tags
  37     [ parse-prop-tag ] H{ } map>assoc ;
  38
  39 : position-attrs ( tag -- at-line-start? at-whitespace-end? at-word-start? )
  40     ! XXX Wrong logic!
  41     { "AT_LINE_START" "AT_WHITESPACE_END" "AT_WORD_START" }
  42     [ attr string>boolean ] with map first3 ;
  43
  44 : parse-literal-matcher ( tag -- matcher )
  45     dup children>string
  46     rule-set get ignore-case?>> <string-matcher>
  47     swap position-attrs <matcher> ;
  48
  49 : parse-regexp-matcher ( tag -- matcher )
  50     dup children>string
  51     rule-set get ignore-case?>> <?insensitive-regexp>
  52     swap position-attrs <matcher> ;
  53
  54 : shared-tag-attrs ( -- )
  55     { "TYPE" string>token (>>body-token) } , ; inline
  56
  57 : parse-delegate ( string -- pair )
  58     "::" split1 [ rule-set get swap ] unless* 2array ;
  59
  60 : delegate-attr ( -- )
  61     { "DELEGATE" f (>>delegate) } , ;
  62
  63 : regexp-attr ( -- )
  64     { "HASH_CHAR" f (>>chars) } , ;
  65
  66 : match-type-attr ( -- )
  67     { "MATCH_TYPE" string>match-type (>>match-token) } , ;
  68
  69 : span-attrs ( -- )
  70     { "NO_LINE_BREAK" string>boolean (>>no-line-break?) } ,
  71     { "NO_WORD_BREAK" string>boolean (>>no-word-break?) } ,
  72     { "NO_ESCAPE" string>boolean (>>no-escape?) } , ;
  73
  74 : literal-start ( -- )
  75     [ parse-literal-matcher >>start drop ] , ;
  76
  77 : regexp-start ( -- )
  78     [ parse-regexp-matcher >>start drop ] , ;
  79
  80 : literal-end ( -- )
  81     [ parse-literal-matcher >>end drop ] , ;
  82
  83 ! SPAN's children
  84 TAGS: parse-begin/end-tag ( rule tag -- )
  85
  86 TAG: BEGIN parse-begin/end-tag
  87     ! XXX
  88     parse-literal-matcher >>start drop ;
  89
  90 TAG: END parse-begin/end-tag
  91     ! XXX
  92     parse-literal-matcher >>end drop ;
  93
  94 : parse-begin/end-tags ( -- )
  95     [
  96         ! XXX: handle position attrs on span tag itself
  97         children-tags [ parse-begin/end-tag ] with each
  98     ] , ;
  99
 100 : init-span-tag ( -- ) [ drop init-span ] , ;
 101
 102 : init-eol-span-tag ( -- ) [ drop init-eol-span ] , ;
 103
 104 : parse-keyword-tag ( tag keyword-map -- )
 105     [ dup main>> string>token swap children>string ] dip set-at ;